在 Delphi 中使用 ADOConnection 查看“打印”语句的输出

Question

我的一些 MS SQL 存储过程使用“print”命令生成消息。在我的 Delphi 2007 应用程序中，使用 TADOConnection 连接到 MS SQL，我如何查看这些“打印”命令的输出？

关键要求： 1）我不能多次运行查询；它可能正在更新一些东西。 2）即使返回数据集，我也需要查看“打印”结果。

Answer 1

这很有趣......
ADOConnection 中的

OnInfoMessage

事件有效，但细节决定成败！

要点：

• 使用

  CursorLocation = clUseServer

  代替默认的

  clUseClient

  。
• 在 ADOStoredProc 中使用

  Open

  而不是

  ExecProc

  。
• 使用当前的

  NextRecordset

  来获取以下内容，但请务必检查您是否已打开一个。
• 在存储过程中使用

  SET NOCOUNT = ON

  。

SQL 端： 您的存储过程

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
IF  EXISTS (SELECT * FROM sys.objects WHERE object_id = OBJECT_ID(N'[dbo].[FG_TEST]') AND type in (N'P', N'PC'))
  DROP PROCEDURE [dbo].[FG_TEST]
GO
-- =============================================
-- Author:      François
-- Description: test multi ADO with info
-- =============================================
CREATE PROCEDURE FG_TEST
AS
BEGIN
    -- SET NOCOUNT ON absolutely NEEDED
    SET NOCOUNT ON;

    PRINT '*** start ***'

    SELECT 'one' as Set1Field1

    PRINT '*** done once ***'

    SELECT 'two' as Set2Field2

    PRINT '*** done again ***'

    SELECT 'three' as Set3Field3

    PRINT '***finish ***'
END
GO

德尔福方面：
创建一个新的 VCL 表单应用程序。
在您的表单中添加备忘录和按钮。
复制以下文本，更改

Catalog

和

Data Source

并将其粘贴到您的表单中。

object ADOConnection1: TADOConnection
  ConnectionString = 
    'Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security In' +
    'fo=False;Initial Catalog=xxxYOURxxxDBxxx;Data Source=xxxYOURxxxSERVERxxx'
  CursorLocation = clUseServer
  LoginPrompt = False
  Provider = 'SQLOLEDB.1'
  OnInfoMessage = ADOConnection1InfoMessage
  Left = 24
  Top = 216
end
object ADOStoredProc1: TADOStoredProc
  Connection = ADOConnection1
  CursorLocation = clUseServer
  ProcedureName = 'FG_TEST;1'
  Parameters = <>
  Left = 24
  Top = 264
end

在 ADOConnection 的

OnInfoMessage

中输入：

Memo1.Lines.Add(Error.Description);

对于

ButtonClick

，请粘贴以下代码：

procedure TForm1.Button1Click(Sender: TObject);
const
  adStateOpen = $00000001; // or defined in ADOInt
var
  I: Integer;
  ARecordSet: _Recordset;
begin
  Memo1.Lines.Add('==========================');

  ADOStoredProc1.Open; // not ExecProc !!!!!

  ARecordSet := ADOStoredProc1.Recordset;
  while Assigned(ARecordSet) do
  begin
    // do whatever with current RecordSet
    while not ADOStoredProc1.Eof do
    begin
      Memo1.Lines.Add(ADOStoredProc1.Fields[0].FieldName + ': ' + ADOStoredProc1.Fields[0].Value);
      ADOStoredProc1.Next;
    end;
    // switch to subsequent RecordSet if any
    ARecordSet := ADOStoredProc1.NextRecordset(I);
    if Assigned(ARecordSet) and ((ARecordSet.State and adStateOpen) <> 0) then
      ADOStoredProc1.Recordset := ARecordSet
    else
      Break;
  end;

  ADOStoredProc1.Close;
end;

Answer 2

.net 的连接类中有一个名为 InfoMessage 的事件。在此事件的处理程序中，您可以从事件参数中检索 InfoMessage（打印语句）。

我相信 Delphi 有一个类似的事件，名为“OnInfoMessage”，可以帮助您。

Answer 3

我认为这是不可能的。 您可以使用临时表来转储打印语句并将其与结果一起返回。

Answer 4

对 Francois 代码进行了一些增强（使用 DXE2 进行了测试），以满足多个打印语句和可变数量选择的结果。变化是微妙的。

procedure TForm1.ADOConnection1InfoMessage(Connection: TADOConnection;
  const Error: Error; var EventStatus: TEventStatus);
var
  i: integer;
begin
  // show ALL print statements
  for i := 0 to AdoConnection1.Errors.Count - 1 do
  begin
    // was: cxMemo1.Lines.Add(Error.Description);
    cxMemo1.Lines.Add(
      ADOConnection1.Errors.Item[i].Description);
  end;
end;

procedure TForm1.cxButton1Click(Sender: TObject);
const
  adStateOpen = $00000001; // or uses ADOInt
var
  records: Integer;
  ARecordSet: _RecordSet;
begin
  cxMemo1.Lines.Add('==========================');

  ADOStoredProc1.Open;

  try
    ARecordSet := ADOStoredProc1.RecordSet; // initial fetch
    while Assigned(ARecordSet) do
    begin
      // assign the recordset to a DataSets recordset to traverse
      AdoDataSet1.Recordset := ARecordSet;
      // do whatever with current ARecordSet
      while not ADODataSet1.eof do
      begin
        cxMemo1.Lines.Add(ADODataSet1.Fields[0].FieldName + 
          ': ' + ADODataSet1.Fields[0].Value);
        AdoDataSet1.Next;
      end;
      // fetch next recordset if there is one
      ARecordSet := ADOStoredProc1.NextRecordSet(records);
      if Assigned(ARecordSet) and ((ARecordSet.State and adStateOpen) <> 0) then
        ADOStoredProc1.Recordset := ARecordSet
      else
        Break;
    end;
  finally
    ADOStoredProc1.Close;
  end;

end;