vim - 昏暗的非活动拆分窗格

Question

如果你熟悉 iTerm2 应用程序，你就会知道你可以像 vim 一样拆分视图，并且不活动的视图会“变暗”。

我通常在 vim 中使用三个垂直拆分视图，例如，通过将背景颜色设置为较暗的色调来调暗不活动的视图会很好。

有没有办法做到这一点？

Answer 1

我提出了以下解决方案（使用“colorcolumn”并取消设置“cursorline”）：

" Dim inactive windows using 'colorcolumn' setting
" This tends to slow down redrawing, but is very useful.
" Based on https://groups.google.com/d/msg/vim_use/IJU-Vk-QLJE/xz4hjPjCRBUJ
" XXX: this will only work with lines containing text (i.e. not '~')
function! s:DimInactiveWindows()
  for i in range(1, tabpagewinnr(tabpagenr(), '$'))
    let l:range = ""
    if i != winnr()
      if &wrap
        " HACK: when wrapping lines is enabled, we use the maximum number
        " of columns getting highlighted. This might get calculated by
        " looking for the longest visible line and using a multiple of
        " winwidth().
        let l:width=256 " max
      else
        let l:width=winwidth(i)
      endif
      let l:range = join(range(1, l:width), ',')
    endif
    call setwinvar(i, '&colorcolumn', l:range)
  endfor
endfunction
augroup DimInactiveWindows
  au!
  au WinEnter * call s:DimInactiveWindows()
  au WinEnter * set cursorline
  au WinLeave * set nocursorline
augroup END

在我的（当前）点文件中查看它：https://github.com/blueyed/dotfiles/blob/master/vimrc#L351

更新 我用它创建了一个插件：https://github.com/blueyed/vim-diminactive

Answer 2

把这个作为一个新的答案扔出去。 https://github.com/TaDaa/vimade 淡化非活动缓冲区，保留语法高亮显示，还可以淡化符号。我是作者，但我认为这可能对某些人有用，作为一种较新的选择。支持 nvim 和 vim8，256 色终端，termguicolors 和 gui。

Answer 3

在 neovim(v0.2.1) 中，以下配置将使非活动窗格变暗：

hi ActiveWindow ctermbg=16 | hi InactiveWindow ctermbg=233
set winhighlight=Normal:ActiveWindow,NormalNC:InactiveWindow

Answer 4

按照您的描述更改背景颜色需要为不同的 Vim 窗口使用不同的颜色方案。据我所知这是不可能的，因为它是一个全局设置（请参阅几天前的this answer）。

作为活动窗口的视觉辅助，我发现状态行通常就足够了。活动窗口 (

hi StatusLine

) 和任何非活动窗口 (

hi StatusLineNC

) 的突出显示组是不同的。您可以选择一个在它们之间具有非常鲜明对比的配色方案，或者编辑您最喜欢的配色方案。

Answer 5

我创建了一个 colorscheme walh 来处理这个问题。

它没有做很多花哨的事情，它只是使用终端颜色来做高光和调光。这很好，因为如果您使用

tmux

调光将匹配。

看起来像这样

nvim|nvim(focus)|tmux

：

Answer 6

到 2023 年，

wincolor

可能就是您所要求的。它为窗口设置背景颜色（真正的背景颜色，不是

hl-Normal

）。

只需将这些行添加到您的 vimrc

" dim inactive window
hi WindowInactive ctermbg=243  # or ctermbg=grey, in case you're not using an 256 color terminal
au VimEnter,WinNew,WinEnter   * set wincolor=
au WinLeave * set wincolor=WindowInactive

结果看起来像