使用Haxe读取PNG图像

Question

使用Haxe编程语言，是否有任何跨平台的方式来读取PNG图像，并从图像中获取像素数据？

我有一个名为stuff.png的文件，我想从图像中获取RGB值数组（作为整数数组）。

Answer 1

以下是Haxe格式库用于读取PNG文件的示例用法。你需要在编译器args / build.hxml中使用-lib format：

function readPixels(file:String):{data:Bytes, width:Int, height:Int} {
    var handle = sys.io.File.read(file, true);
    var d = new format.png.Reader(handle).read();
    var hdr = format.png.Tools.getHeader(d);
    var ret = {
        data:format.png.Tools.extract32(d),
        width:hdr.width,
        height:hdr.height
    };
    handle.close();
    return ret;
}

以下是如何从上面获取ARGB像素数据的示例：

public static function main() {
  if (Sys.args().length == 0) {
    trace('usage: PNGReader <filename>');
    Sys.exit(1);
  }
  var filename = Sys.args()[0];
  var pixels = readPixels(filename);
  for (y in 0...pixels.height) {
    for (x in 0...pixels.width) {
      var p = pixels.data.getInt32(4*(x+y*pixels.width));
      // ARGB, each 0-255
      var a:Int = p>>>24;
      var r:Int = (p>>>16)&0xff;
      var g:Int = (p>>>8)&0xff;
      var b:Int = (p)&0xff;
      // Or, AARRGGBB in hex:
      var hex:String = StringTools.hex(p,8);
      trace('${ x },${ y }: ${ a },${ r },${ g },${ b } - ${ StringTools.hex(p,8) }');
    }
  }

Answer 2

您始终可以使用BitmapData.getPixels / BitmapData.setPixels访问像素数据。

如果您使用的是haXe NME，则可以使用Assets.getBitmapData（）来加载资产图像文件。

如果你想从网络加载图像，那么你可以使用Loader类，它可以异步加载远程图像，但在flash中请注意跨域问题。

对于更通用的ByteArray - > BitmapData转换，请使用以下代码：

var ldr = new Loader();
ldr.loadBytes(cast(byteArray)); // bytearray contains raw image data
var dp: DisplayObject = ldr.content; // actually ontent should be of Bitmap class
var bitmapData = new BitmapData(Std.int(dp.width), Std.int(dp.height), true, 0);
bitmapData.draw(dp);