找到最小值并打印相应的列值

Question

我有一个数据集，如下所示。

35.7412  342  
35.7598  341  
35.7796  340  
35.8008  339   
35.8233  338   
35.8471  337   
35.8721  336   
35.8984  335  
35.9259  334   
35.9546  333   
35.9843  332 

现在，我需要找到几个文件的最小值，我做了以下工作：

awk 'FNR==1 {
   if (min)
      print min
   min = ""
   fn = FILENAME
}
$1+0 == $1 && (min=="" || $1 < min) {
   min=$1
}
END {
   print min
}' *.txt

并得到:

35.7412

但是，我想打印相应的值，即。

35.7412 342 

任何建议，如何打印列2美元的值吗？ 谢谢

Answer 1

awk '
    FNR == 1 {
        if (NR > 1) {
            print rec
        }
        min = $1
    }
    $1 <= min {
        min = $1
        rec = $0
    }
    END {
        print rec
    }
' *.txt

在进行minmax计算时，不要将minmax初始化为某个任意值，只要总是将minmax初始化为读取的第一个值，那么无论你的文件中包含什么值，即使它们都是负值，它都会工作。

Answer 2

请你试试下面的方法（在GNU中编写并测试过了 awk).

awk '
FNR==1{
  delete val
  min=""
}
{
  min = (min<$1 ? (min ? min : $1) : $1)
  val[$1]=$0
}
ENDFILE{
  print val[min]
}
' *.txt

解释。 为上述代码添加详细解释。

awk '                                     ##Starting awk program from here.
FNR==1{                                   ##Checking condition if line is first line then do following.
  delete val                              ##Delete array named val here.
  min=""                                  ##Nullifying min variable value here.
}
{
  min = (min<$1 ? (min ? min : $1) : $1)  ##Creating variable min whose value we are checking is lesser than current $1 or not.
  val[$1]=$0
}
ENDFILE{                                  ##Using ENDFILE section for each Input_file here.
  print val[min]                          ##Printing array val value with variable min as index here.
}
' *.txt                                   ##Mentioning all .txt files here.

Answer 3

使用bash

for file in *txt;do sort -t" " -nr -k1 ${file} |  head -1; done;

上方的尝试

awk 'FNR==1 {
   if (min)
      print rec
   min = ""
   fn = FILENAME
}
$1+0 == $1 && (min=="" || $1 < min) {
   min=$1; rec=$0;
}
END {
   print rec
}' *.txt