如何将GStrv (string[])类型的GLib.Value转换为GLib.Variant？

Question

在下面的例子中，有一个类属性的类型是 Gstrv.随着 ObjectClass.list_properties() 可以查询 Paramspec 的所有属性，并与 get_property() 所有物业都可以要求为 GLib.Value. 我如何访问类型为 GStrv 并将其转换为 GLib.Variant?

我的GLib版本略显过时，所以我没有这个功能。GLib.Value.to_variant() 函数尚未可用 :( .

public class Foo: GLib.Object {
    public GLib.HashTable<string, int32> bar;

    public Foo() {

        bar = new GLib.HashTable<string, int32>(str_hash, str_equal);

    }

    public string[] bar_keys { owned get { return bar.get_keys_as_array(); } }
}

int main() {
    var foo = new Foo();
    Type type = foo.get_type();
    ObjectClass ocl = (ObjectClass) type.class_ref ();
    foreach (ParamSpec spec in ocl.list_properties ()) {
        print ("%s\n", spec.get_name ());
        Value property_value = Value(spec.value_type);
        print ("%s\n", property_value.type_name ());
        foo.get_property(spec.name, ref property_value);
        // next: convert GLib.Value -> GLib.Variant :(
    }
    foo.bar.set("baz", 42);
    return 0;
}

输出。

bar-keys
GStrv

Answer 1

使用 GLib.Value.get_boxed() 似乎在工作。

例子:

// compile simply with: valac valacode.vala
public class Foo: GLib.Object {
    public GLib.HashTable<string, int32> bar;

    public Foo() {

        bar = new GLib.HashTable<string, int32>(str_hash, str_equal);

    }

    public string[] bar_keys { owned get { return bar.get_keys_as_array(); } }
}

public Variant first_gstrv_property_as_variant(Object obj)
{
        Type class_type = obj.get_type();
        ObjectClass ocl = (ObjectClass) class_type.class_ref ();
        foreach (ParamSpec spec in ocl.list_properties ()) {
                print ("%s\n", spec.get_name ());
                Value property_value = Value(spec.value_type);
                print ("%s\n", property_value.type_name ());
                obj.get_property(spec.name, ref property_value);
                // next: convert GLib.Value -> GLib.Variant
                if(property_value.type_name () == "GStrv") {
                        return new GLib.Variant.strv((string[])property_value.get_boxed());
                }
        }
        return new GLib.Variant("s", "No property of type GStrv found");

}

int main() {
        var foo = new Foo();
        print("%s\n", first_gstrv_property_as_variant(foo).print(true));

        foo.bar.set("baz", 42);
        print("%s\n", first_gstrv_property_as_variant(foo).print(true));

        foo.bar.set("zot", 3);
        print("%s\n", first_gstrv_property_as_variant(foo).print(true));
        return 0;
}

输出。

bar-keys
GStrv
@as []
bar-keys
GStrv
['baz']
bar-keys
GStrv
['baz', 'zot']

在生成的c代码中，它看起来如下。

_tmp18_ = g_value_get_boxed (&property_value);
_tmp19_ = g_variant_new_strv ((gchar**) _tmp18_, -1);

将-1作为长度传递给 g_variant_new_strv() 意味着字符串数组被认为是空结束的。在 g_variant_new_strv() 的 g_strv_length() 函数是用来确定长度的。

希望有一天能对别人有用。:-)