我的Clojure规范看起来像:
(spec/def ::global-id string?)
(spec/def ::part-of string?)
(spec/def ::type string?)
(spec/def ::value string?)
(spec/def ::name string?)
(spec/def ::text string?)
(spec/def ::date (spec/nilable (spec/and string? #(re-matches #"^\d{4}-\d{2}-\d{2}$" %))))
(spec/def ::interaction-name string?)
(spec/def ::center (spec/coll-of string? :kind vector? :count 2))
(spec/def ::context- (spec/keys :req [::global-id ::type]
:opt [::part-of ::center]))
(spec/def ::contexts (spec/coll-of ::context-))
(spec/def ::datasource string?)
(spec/def ::datasource- (spec/nilable (spec/keys :req [::global-id ::name])))
(spec/def ::datasources (spec/coll-of ::datasource-))
(spec/def ::location string?)
(spec/def ::location-meaning- (spec/keys :req [::global-id ::location ::contexts ::type]))
(spec/def ::location-meanings (spec/coll-of ::location-meaning-))
(spec/def ::context string?)
(spec/def ::context-association-type string?)
(spec/def ::context-association-name string?)
(spec/def ::priority string?)
(spec/def ::has-context- (spec/keys :req [::context ::context-association-type ::context-association-name ::priority]))
(spec/def ::has-contexts (spec/coll-of ::has-context-))
(spec/def ::fact- (spec/keys :req [::global-id ::type ::name ::value]))
(spec/def ::facts (spec/coll-of ::fact-))
(spec/def ::attribute- (spec/keys :req [::name ::type ::value]))
(spec/def ::attributes (spec/coll-of ::attribute-))
(spec/def ::fulltext (spec/keys :req [::global-id ::text]))
(spec/def ::feature- (spec/keys :req [::global-id ::date ::location-meanings ::has-contexts ::facts ::attributes ::interaction-name]
:opt [::fulltext]))
(spec/def ::features (spec/coll-of ::feature-))
(spec/def ::attribute- (spec/keys :req [::name ::type ::value]))
(spec/def ::attributes (spec/coll-of ::attribute-))
(spec/def ::ioi-slice string?)
(spec/def ::ioi- (spec/keys :req [::global-id ::type ::datasource ::features ::attributes ::ioi-slice]))
(spec/def ::iois (spec/coll-of ::ioi-))
(spec/def ::data (spec/keys :req [::contexts ::datasources ::iois]))
(spec/def ::data- ::data)
但它无法生成以下样本:
(spec/fdef data->graph
:args (spec/cat :data ::xml-spec/data-))
(println (stest/check `data->graph))
然后它将无法生成异常:Couldn't satisfy such-that predicate after 100 tries.
使用stest/check
自动生成规范非常方便但是如何旁边的规格也有生成器?
当您从规范生成数据时看到错误Couldn't satisfy such-that predicate after 100 tries.
,一个常见原因是s/and
规范,因为spec仅根据第一个内部规范为s/and
规范构建生成器。
这个规范似乎最有可能导致这种情况,因为s/and
中的第一个内部规范/谓词是string?
,而下面的谓词是正则表达式:
(s/def ::date (s/nilable (s/and string? #(re-matches #"^\d{4}-\d{2}-\d{2}$" %))))
如果您对string?
生成器进行采样,您将看到它生成的内容不太可能与您的正则表达式匹配:
(gen/sample (s/gen string?))
=> ("" "" "X" "" "" "hT9" "7x97" "S" "9" "1Z")
test.check将尝试(默认为100次)以获得满足such-that
条件的值,然后抛出您看到的异常(如果不是)。
您可以通过多种方式为此规范实现自定义生成器。这是一个test.check生成器,它将创建ISO本地日期字符串:
(def gen-local-date-str
(let [day-range (.range (ChronoField/EPOCH_DAY))
day-min (.getMinimum day-range)
day-max (.getMaximum day-range)]
(gen/fmap #(str (LocalDate/ofEpochDay %))
(gen/large-integer* {:min day-min :max day-max}))))
这种方法获得有效纪元日的范围,使用它来控制large-integer*
发生器的范围,然后使用fmap
s LocalDate/ofEpochDay
生成的整数。
(def gen-local-date-str
(gen/fmap #(-> (Instant/ofEpochMilli %)
(LocalDateTime/ofInstant ZoneOffset/UTC)
(.toLocalDate)
(str))
gen/large-integer))
这从默认的large-integer
生成器开始,并使用fmap
提供一个函数,该函数从生成的整数创建java.time.Instant
,将其转换为java.time.LocalDate
,并将其转换为恰好与您的日期字符串格式匹配的字符串。 (这在Java 9及更高版本上使用java.time.LocalDate/ofInstant
稍微简单。)
另一种方法可能使用test.chuck的regex-based string generator,或不同的日期类/格式化程序。请注意,我的两个示例都会生成在-9999 / + 9999之前/之后的年份,这与您的\d{4}
年正则表达式不匹配,但生成器应该经常产生令人满意的值,这对于您的用例可能无关紧要。有很多方法可以生成日期值!
(gen/sample gen-local-date-str)
=>
("1969-12-31"
"1970-01-01"
"1970-01-01"
...)
然后,您可以使用s/with-gen
将此生成器与您的规范相关联:
(s/def ::date
(s/nilable
(s/with-gen
(s/and string? #(re-matches #"^\d{4}-\d{2}-\d{2}$" %))
(constantly gen-local-date-str))))
(gen/sample (s/gen ::date))
=>
("1969-12-31"
nil ;; note that it also makes nils b/c it's wrapped in s/nilable
"1970-01-01"
...)
如果您不想将自定义生成器直接绑定到规范定义,您还可以为采用覆盖映射的某些规范函数提供“独立”自定义生成器:
(gen/sample (s/gen ::data {::date (constantly gen-local-date-str)}))
使用此规范和生成器,我能够生成更大的::data
规范,尽管由于某些收集规范,输出非常大。您还可以使用规范中的:gen-max
选项控制生成期间的大小。