如何获取动态创建的选择列表组件的选定值

问题描述 投票:0回答:2

我不确定这是否可行,但我试图在VisualForce Apex控制器类中获取动态创建的选择列表的值。

我正在使用下面的代码为特定对象(例如Contact)中的每个字段动态创建一个选择列表,但现在我不知道如何获取所选值。我已经尝试在构造函数和单独的行中设置每个的值(不在下面的代码示例中),但这似乎不起作用。

VisualForce页面:

<apex:dynamicComponent componentValue="{!contactPageBlockSection}" />

Apex控制器:

public Component.Apex.PageBlockSection GetContactPageBlockSection(string objectName)   
{
    Map<string, Schema.SObjectField> FieldMap;
    FieldMap = Schema.SObjectType.Contact.fields.getMap();
    Set<string> FieldSet = FieldMap.keySet();
    List<string> FieldList = new List<string>();
    FieldList.addAll(FieldSet);
    FieldList.sort();
    Component.Apex.PageBlockSection pbs = new Component.Apex.PageBlockSection(columns = 2);

    for (string fieldName : FieldList)
    {
        Component.Apex.PageBlockSectionItem pbsi = new Component.Apex.PageBlockSectionItem();
        Schema.DescribeFieldResult field = (FieldMap.get(fieldName)).getDescribe();

        if (field.isUpdateable() && field.IsAccessible())
        {
            Schema.DisplayType dt = field.getType();
            Component.Apex.OutputLabel lblText = new Component.Apex.OutputLabel(escape = false);
            lblText.value = field.getLabel();
            pbsi.childComponents.add(lblText);

            Component.Apex.SelectList selList = new Component.Apex.SelectList(id = field.getName(), multiselect = false, size = 1, style = 'width:200px;');

            if (dt == Schema.DisplayType.Integer || dt == Schema.DisplayType.Double || dt == Schema.DisplayType.Currency || dt == Schema.DisplayType.Percent)
            {
                AddSelectOption(selList, 'Keep highest value');
                AddSelectOption(selList, 'Keep lowest value');
                AddSelectOption(selList, 'Keep master value');
                pbsi.childComponents.add(selList);
                pbs.childComponents.add(pbsi);
            }
        }
    }

    return pbs;
}

private void AddSelectOption(Component.Apex.SelectList selList, string option)
{
     Component.Apex.SelectOption selOption = new Component.Apex.SelectOption();
     selOption.itemLabel = option;
     selOption.itemValue = option;
     selList.childComponents.add(selOption);
}

提前谢谢了

dynamic controller salesforce apex-code visualforce
2个回答
0
投票

只需使用表达式语法将动态创建的选择列表的value属性绑定到字符串属性:

String selectedValue {get; set;}
...
setList.expressions.value = '{!selectedValue}';

然后,属性应该存储选定的值,就像在选择列表的静态声明性定义中一样。


0
投票

您可以尝试使用动态视觉力绑定。 I.E.

map<String,String> FieldToString {get; set;}
...
selList.expressions.value = '{!FieldToString[\'' + fieldname + '\']}';

但是,我从未在动态视觉力量中使用动态视觉力绑定,因此需要注意。

© www.soinside.com 2019 - 2024. All rights reserved.