如何使用ObjectDBX使用AutoLISP从所有块中删除所有属性

Question

我想使用AutoLISP ObjectDBX方法删除图形内块的所有属性。

下面的程序运行良好：它删除了图形中所有块的属性，但是当我在块编辑器中编辑该块时，我看到所有属性仍然存在。

我想我需要从块的定义中删除此属性。

;[dwgin]--input drawing file
;[dwgout]-- Output drawing fath with name
;function 'LM:GetDocumentObject' lee mac function to open drawing in ObjectDBX method
(defun DBXAttDelete ( dwgin dwgout / doc flg val )
    (if (setq doc (LM:GetDocumentObject dwgin))
        (progn
            (vlax-for lyt (vla-get-layouts doc)
                (vlax-for obj (vla-get-block lyt)
                    (if (and (= "AcDbBlockReference" (vla-get-objectname obj))
                             (= :vlax-true (vla-get-hasattributes obj))
                        )
                        (foreach att (vlax-invoke obj 'getattributes)              

                    (if (vl-catch-all-error-p (setq err (vl-catch-all-apply 'vla-delete (list att))))
                      (princ (strcat "\nERROR: " (vl-catch-all-error-message err)))

                    )
                        )
                    )
                )
            )
           (vla-saveas doc dwgout)
            (vlax-release-object doc)
            flg
        )
        (prompt (strcat "\nThe drawing \"" dwgin "\" was not found or could not be accessed."))
    )
)

您能帮我找到需要改进/纠正此程序的地方吗。

Answer 1

[考虑到块定义本质上是该块的“蓝图”，并且每个块引用都是一个实例，该实例显示在块定义中找到的对象，在图形中的特定位置，比例，旋转和方向。

属性在块定义中也具有Attribute Definitions，并且对应的Attribute References附加到每个块参考。然后，此类属性引用可以为插入到图形中的每个块引用保留不同的文本内容。

此外，有趣的是，属性引用也可以独立于块定义而以编程方式附加到块引用，但是，当使用标准的即用型前端操作AutoCAD时，这是不允许的。

同样，要从图形中删除所有属性，您需要删除与所有块引用关联的属性引用，并从相应的块定义中删除属性定义。

您可能还想在执行删除操作之前解锁锁定的层，并在此操作之后重新锁定先前锁定的层。

由于布局仅是块的一种，因此对块集合进行迭代就足以处理所有布局，块和嵌套块（不包括外部参照）：

(defun DBXAttDelete ( dwgin dwgout / doc lck )
    (if (setq doc (LM:GetDocumentObject dwgin))
        (progn
            (vlax-for lay (vla-get-layers doc)
                (if (= :vlax-true (vla-get-lock lay))
                    (progn
                        (setq lck (cons lay lck))
                        (vla-put-lock lay :vlax-false)
                    )
                )
            )
            (vlax-for blk (vla-get-blocks doc)
                (if (= :vlax-false (vla-get-isxref blk))
                    (vlax-for obj blk
                        (cond
                            (   (= "AcDbBlockReference" (vla-get-objectname obj))
                                (if (= :vlax-true (vla-get-hasattributes obj))
                                    (foreach att (vlax-invoke obj 'getattributes)
                                        (vla-delete att)
                                    )
                                )
                            )
                            (   (= "AcDbAttributeDefinition" (vla-get-objectname obj))
                                (vla-delete obj)
                            )
                        )
                    )
                )
            )
            (foreach lay lck
                (vla-put-lock lay :vlax-true)
            )
            (vla-saveas doc dwgout)
            (vlax-release-object doc)
            t
        )
        (prompt (strcat "\nThe drawing \"" dwgin "\" was not found or could not be accessed."))
    )
)