使用带有闭包映射的failFast打破了“并行”步骤

Question

不确定这是我对 Groovy 的有限了解还是 Pipeline

parallel

步骤中的一个怪癖。如果我使用映射而不是单独传递每个闭包，我无法让它接受

failFast

：

def map = [:]
map['spam'] = {
    node {
        echo 'spam'
    }
}
map['eggs'] = {
    node {
        echo 'eggs'
    }
}
parallel map // Works.
parallel spam: map['spam'], eggs: map['eggs'], failFast: true // Works.
parallel map, failFast: true // Fails with exception.

failFast

的例外是：

java.lang.IllegalArgumentException: Expected named arguments but got [{failFast=true}, {spam=org.jenkinsci.plugins.workflow.cps.CpsClosure2@51a382ad, eggs=org.jenkinsci.plugins.workflow.cps.CpsClosure2@718cb50d}]
    at org.jenkinsci.plugins.workflow.cps.DSL.parseArgs(DSL.java:276)
    at org.jenkinsci.plugins.workflow.cps.DSL.invokeMethod(DSL.java:111)

Answer 1

map.failFast = true
parallel map

Answer 2

如果添加可选语法，会有一点帮助。第二个选项是传递新的

Map

，而第三个选项是传递原始

Map

和一个附加的命名参数。老实说，我不确定它认为发生了什么。

parallel(map)
parallel([
    spam: map['spam'],
    eggs: map['eggs'],
    failFast: true
])
parallel map, failFast: true

无论如何，我认为最简单的事情就是这样：

def map = [
    spam: {
        node {
            echo 'spam'
        }
    },
    eggs: {
        node {
            echo 'eggs'
        }
    },
    failFast: true
]
parallel map

或者...

parallel ([
    spam: {
        node {
            echo 'spam'
        }
    },
    eggs: {
        node {
            echo 'eggs'
        }
    },
    failFast: true
])

Answer 3

除了 Jesse Glick 的 answer。

即使您使用 for 循环创建并行阶段，您也可以使用相同的代码 -

map.failFast = true
parallel map

Answer 4

所有答案都提供了解决方案，但没有一个解释您遇到异常的原因。

要理解这一点，阅读 Groovy 的命名参数会很有帮助。

在 Groovy 中，要创建可以接受命名参数的函数，您必须将其声明为接受单个

Map

参数的函数。示例：

void copy(Map params) {
    println params.src
    println params.dest
}
// The next two lines are equivalent:
copy([ src: '/etc/config', dest: '/home/john' ])
copy src: '/etc/config', dest: '/home/john' 

但是，这是错误的：

final map = [ src: '/etc/config' ]
// The next two lines are equivalent, and will throw an exception:
copy(map, [ dest: '/home/john' ])
copy map, dest: '/home/john'

因此，您尝试调用一个需要单个映射的函数，但您向其传递了两个映射。

要亲自查看，请尝试在本地执行此测试 Groovy 代码，无需 Jenkins

def printArgs(...args) {
    println args.length
    println args.collect{ it.toString() }.join(', ')
}
            
def map = [ spam: 10, eggs: 20 ]
printArgs map // Single map
printArgs spam: map['spam'], eggs: map['eggs'], failFast: true // Single map
printArgs map, failFast: true // Two maps

最后，有几个替代解决方案可以在不修改原始版本的情况下工作

map

：

// The next two lines are equivalent:
parallel map + [ failFast: true ]
parallel map.plus(failFast: true)