具有量化约束的Ord（forall a。Ord a => Ord（f a））

Question

有了量化约束，我可以得出Eq (A f)很好吗？但是，当我尝试导出Ord（A f）时会失败。当约束类具有超类时，我不理解如何使用量化约束。如何导出Ord (A f)和其他具有超类的类？

> newtype A f = A (f Int)
> deriving instance (forall a. Eq a => Eq (f a)) => Eq (A f)
> deriving instance (forall a. Ord a => Ord (f a)) => Ord (A f)
<interactive>:3:1: error:
    • Could not deduce (Ord a)
        arising from the superclasses of an instance declaration
      from the context: forall a. Ord a => Ord (f a)
        bound by the instance declaration at <interactive>:3:1-61
      or from: Eq a bound by a quantified context at <interactive>:1:1
      Possible fix: add (Ord a) to the context of a quantified context
    • In the instance declaration for 'Ord (A f)'

PS。我还检查了ghc proposals 0109-quantified-constraints。使用ghc 8.6.5

Answer 1

问题是Eq是Ord的超类，并且约束(forall a. Ord a => Ord (f a))并不意味着声明Eq (A f)实例所需的超类约束Ord (A f)。

• 我们有(forall a. Ord a => Ord (f a))

• 我们需要Eq (A f)，即(forall a. Eq a => Eq (f a))，我们所拥有的并不隐含。

解决方案：将(forall a. Eq a => Eq (f a))添加到Ord实例。

（（我实际上不理解GHC给出的错误消息与问题之间的关系。）

{-# LANGUAGE QuantifiedConstraints, StandaloneDeriving, UndecidableInstances, FlexibleContexts #-}

newtype A f = A (f Int)
deriving instance (forall a. Eq a => Eq (f a)) => Eq (A f)
deriving instance (forall a. Eq a => Eq (f a), forall a. Ord a => Ord (f a)) => Ord (A f)

或更整洁：

{-# LANGUAGE ConstraintKinds, RankNTypes, KindSignatures, QuantifiedConstraints, StandaloneDeriving, UndecidableInstances, FlexibleContexts #-}

import Data.Kind (Constraint)

type Eq1 f = (forall a. Eq a => Eq (f a) :: Constraint)
type Ord1 f = (forall a. Ord a => Ord (f a) :: Constraint)  -- I also wanted to put Eq1 in here but was getting some impredicativity errors...

-----

newtype A f = A (f Int)
deriving instance Eq1 f => Eq (A f)
deriving instance (Eq1 f, Ord1 f) => Ord (A f)