Sparql查找具有dbo类型的实体并按计数对它们进行排序

问题描述 投票:1回答:1

我必须对dbpedia端点执行sparql查询,该查询需要:

  1. label查找包含“维也纳”的所有实体,在abstract找到“城市”
  2. 过滤它们只保留至少有一个dbo rdf:type
  3. dbo类型的计数对结果进行排序(例如,如果一个实体有5个dbo rdf:type,它必须在具有4个dbo rdf:type的实体之前显示)

我做了几次尝试,最接近结果是:

select distinct (str(?s) as ?s) count(?t) as ?total where {{ ?s rdfs:label "vienna"@en. ?s rdf:type ?t.} 
UNION { ?s rdfs:label ?l. ?s rdf:type ?t . ?l <bif:contains> '("vienna")'
. FILTER EXISTS { ?s dbo:abstract ?cc. ?cc <bif:contains> '("city")'. FILTER(lang(?cc) = "en").}} 
FILTER (!strstarts(str(?s), str("http://dbpedia.org/resource/Category:")))
. FILTER (!strstarts(str(?s), str("http://dbpedia.org/property/")))
. FILTER (!strstarts(str(?s), str("http://dbpedia.org/ontology/")))
. FILTER (strstarts(str(?t), str("http://dbpedia.org/ontology/"))).} 
LIMIT 50

在实际过滤之前,哪个(错误地)计算rdf:type。我不想数rdf:type不是dbo(本体论)。

sparql dbpedia
1个回答
1
投票

我们的想法是使用一个子查询,在其中搜索实体并在外部查询中进行计数:

PREFIX  dbo:  <http://dbpedia.org/ontology/>
PREFIX  rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX  rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT  ?s (count(*) AS ?cnt)
WHERE
  { { SELECT DISTINCT  ?s
      WHERE
        { ?s  rdfs:label      ?l .
          ?l  <bif:contains>  '"vienna"'
          FILTER langMatches(lang(?l), "en")
          FILTER EXISTS { ?s   dbo:abstract    ?cc .
                          ?cc  <bif:contains>  '"city"'
                          FILTER langMatches(lang(?cc), "en")
                        }
          ?s  rdf:type  ?t
          FILTER ( ! strstarts(str(?s), str("http://dbpedia.org/resource/Category:")) )
          FILTER ( ! strstarts(str(?s), str("http://dbpedia.org/property/")) )
          FILTER ( ! strstarts(str(?s), str(dbo:)) )
          FILTER strstarts(str(?t), str(dbo:))
        }
    }
    ?s  ?p  ?o
    FILTER strstarts(str(?p), str(dbo:))
  }
GROUP BY ?s
ORDER BY DESC(?cnt)
© www.soinside.com 2019 - 2024. All rights reserved.