FIBO C代码到MIPS

Question

嗨伙计们，我正在尝试将我的斐波那契c代码转换为MIPS汇编代码，但是，当我将MIPS代码运行到我的MIPS模拟器时，它似乎并没有结束。

C代码：

int fibo(int n)
{
    if(n<2) return 1;
    else f(n-1)+f(n-2);
}

int main()
{
    fibo(5);
}

汇编代码：

main: addi $sp, $sp, -4
sw $ra, 0($sp)

addi $a0, $zero, 5
jal fibo; 

lw $ra, 0($sp)
addi $sp, $sp, 4

fibo: addi $sp, $sp, -12
sw $s0, 0($sp)
sw $s1, 4($sp)
sw $ra, 8($sp)

slti $t0, $a0, 2
beq $t0, $zero, ELSE

addi $v0, $zero, 1
jr $ra

ELSE: addi $s0, $a0, 0
addi $a0, $a0, -1
jal fibo;

addi $s1, $v0, 0
addi $a0, $s0, -2
jal fibo

add $s1, $s1, $v0
j EXIT

EXIT: lw $s0, 0($sp)
lw $s1, 4($sp)
lw $ra, 8($sp)
addi $sp, $sp, 12

jr $ra

Answer 1

这里有几个问题。

首先，你的main功能缺少它的终止jr $ra，这意味着main被执行后落入fibo。

其次，在你的if声明中，你返回1，你直接调用jr $ra，这意味着堆栈没有恢复。我打电话给j EXIT换掉了这个。

最后，在你的其他结束时，你将f(n-1)和f(n-2)添加到$s1。该寄存器应该是$v0，因为您打算返回此结果。

修复后的代码如下：

main: 
    addi $sp, $sp, -4
    sw $ra, 0($sp)

    addi $a0, $zero, 5
    jal fibo

    move $a0 $v0
    li $v0 1
    syscall

    lw $ra, 0($sp)
    addi $sp, $sp, 4

    jr $ra

fibo: 
    addi $sp, $sp, -12
    sw $s0, 0($sp)
    sw $s1, 4($sp)
    sw $ra, 8($sp)


    slti $t0, $a0, 2
    beq $t0, $zero, ELSE

    addi $v0, $zero, 1
    j EXIT

    ELSE: 
        addi $s0, $a0, 0
        addi $a0, $a0, -1
        jal fibo

        addi $s1, $v0, 0
        addi $a0, $s0, -2
        jal fibo

        add $v0, $s1, $v0

    EXIT: 
    lw $s0, 0($sp)
    lw $s1, 4($sp)
    lw $ra, 8($sp)
    addi $sp, $sp, 12

    jr $ra 

Answer 2

这是我的相同代码，但它是用RISC-V编写的

.text

#x5 me n hai
#x7 me output
li x5 7
li x6 2
jal x1 FIB
j EXIT

FIB:
    bge x5 x6 REC 
    addi x7 x5 0
    jalr x0 0(x1)
    #Handled Base Case

REC:
    # Handling Rec. Case

    addi sp sp -12
    sw x1 0(sp)
    sw x5 4(sp)

    addi x5 x5 -1
    jal x1 FIB


    sw x7 8(sp)
    lw x5 4(sp)
    addi x5 x5 -2
    jal x1 FIB 

    lw x13 8(sp)
    add x7 x13 x7


    lw x1 0(sp)
    addi sp sp 12
    jalr x0 0(x1)

EXIT:

Answer 3

除了Konrad（https://stackoverflow.com/a/23185991/3729904）的答案之外，我注意到你的算法中存在错误。如果n <2，则fib算法应返回n而不是1。

这可以修改改变线：

addi $v0, $zero, 1

成：

add $v0, $zero, $a0