ALV 编辑后不刷新。为什么？

Question

我知道我的问题已被问过数百次。 但我还是找不到适合我的解决方案

1. 我有一个下拉列表，每次我更改下拉列表中的数据时，它都会根据下拉数据加载新数据
2. 从第一步开始，我刷新可编辑的ALV
3. 可编辑 ALV 中的任何更改都将被保存（另一个保存操作）

我的问题是，保存后，我无法刷新我的 ALV。

但是如果我没有按保存按钮也没有问题

注意： 在SAP论坛，他们告诉我将刷新功能移至PBO，我尝试了但仍然失败。

所附代码是此代码中的步骤1是“when SET_P”

PBO

    MODULE pbo_1000 OUTPUT.
       IF flag = 0.
         SET PF-STATUS '1000'.
         SET TITLEBAR  '1000'.
         PERFORM create_toolbar.
         PERFORM create_catalog.
         PERFORM select_data.
     
         CREATE OBJECT ob_custom
           EXPORTING
             container_name = 'CCTRL'.
         CREATE OBJECT ob_grid
           EXPORTING
             i_parent      = ob_custom
             i_appl_events = 'X'.
     
         PERFORM create_dropbox.
         CALL METHOD ob_grid->set_table_for_first_display
           EXPORTING
             i_structure_name     = 'TYPE'
             it_toolbar_excluding = lt_toolbar
             is_layout            = lyt
           CHANGING
             it_fieldcatalog      = fld[]
             it_outtab            = itab[].
     
         CALL METHOD ob_grid->set_ready_for_input
           EXPORTING
             i_ready_for_input = 1.
         CALL METHOD ob_grid->register_edit_event
           EXPORTING
             i_event_id = cl_gui_alv_grid=>mc_evt_enter.
       ENDIF.
    ENDMODULE.   

派

    MODULE user_command_1000 INPUT .
       DATA: v_perio(6) TYPE c.

       CASE sy-ucomm.
         WHEN 'BACK' OR 'EXIT' OR 'CANCEL'.
           LEAVE TO SCREEN 0.
         WHEN 'SAVE'.
           PERFORM save_data.
           PERFORM send_email.
     
         WHEN 'SET_S'.
           flag = 1.
           PERFORM set_status.
           CALL METHOD ob_grid->refresh_table_display
             EXPORTING
               is_stable = stbl.
    
         WHEN 'SET_P'.
           flag = 1.
           PERFORM select_data.
           CALL METHOD ob_grid->refresh_table_display
             EXPORTING
               is_stable      = stbl.
       ENDCASE.
    ENDMODULE. 

Answer 1

我想您需要在 PAI 中首先调用 CHECK_CHANGED_DATA 方法，这将触发事件 DATA_CHANGED 和 DATA_CHANGED_FINISHED。

但最重要的是，它会将 OLE 对象与实例后端同步，然后当您调用 REFRESH_TABLE_DISPLAY 时，它会正确刷新您的 ALV。我目前没有任何示例，但我也许可以在下周访问系统时尝试。

顺便说一下，在 PBO 中，您不需要变量 flag 您可以使用检查 ALV 对象是否已初始化，并根据此您可以创建/刷新 alv。像这样的东西：

if alvGridRef is NOT bound .
  data(container) = new cl_gui_custom_container( ) .
  data(alvGridRef) = new cl_gui_alv_grid( ) .
else .
  alvGridRef->refresh_table_display( ) .
endif .

Answer 2

我在一个应用程序中做了类似的事情，需要在保存时刷新，因为一些计算必须在屏幕中更改。我在命令形式中为“REUSE_ALV_GRID_DISPLAY”功能模块设置了以下部分代码。

form user_command using r_ucomm     like sy-ucomm
                        rs_selfield type slis_selfield.
  data: ref_grid type ref to cl_gui_alv_grid, l_valid type c.

  if ref_grid is initial.
    call function 'GET_GLOBALS_FROM_SLVC_FULLSCR'
      importing
        e_grid = ref_grid.
  endif.

  if not ref_grid is initial.
    call method ref_grid->check_changed_data
      importing
        e_valid = l_valid.
  endif.
  rs_selfield-refresh = 'X'.

  ...

  if not ref_grid is initial.
    call method ref_grid->refresh_table_display( ) .
  endif.

endform.

希望有帮助

Answer 3

您可以通过手动触发 PBO 来实现此目的。你说编辑已保存，所以你可以再次在PBO中显示ALV：

CALL FUNCTION 'SAPGUI_SET_FUNCTIONCODE'
           EXPORTING
             functioncode           = 'REFRESH'
           EXCEPTIONS
             function_not_supported = 1 
             OTHERS                 = 2.

此操作后，PBO 中的

sy-ucomm

的值为

REFRESH

。

Answer 4

在向尚未实现的 ALV OO 报告添加刷新按钮时，我遇到了类似的情况。该报告从客户（KNA1、KNVV 和 KNVP）获取数据并在运行时进行一些计算。

当用户单击刷新按钮时，程序将再次获取数据（确保在选择之前清除所有相关的内部表），然后使用 is_stable 运行方法

REFRESH_TABLE_DISPLAY

以保持光标位置。

    METHOD handle_user_command.
      DATA: ls_istable TYPE lvc_s_stbl.

      CASE e_ucomm.
        WHEN 'REFRESH'.
          PERFORM get_data.
            
          ls_istable-row = 'X'.
          ls_istable-col = 'X'.
    
          CALL METHOD gv_grid->refresh_table_display
            EXPORTING
              is_stable = ls_istable
            EXCEPTIONS
              finished  = 1
              OTHERS    = 2.
      ENDCASE.
    ENDMETHOD.

示例程序

BCALV_GRID_05

可以帮助了解整个结构。