无法在 Power BI 中比较两个版本报告

Question

我正在创建一个 powerbi 报告，我们可以在其中看到不同版本响应时间的比较。

为此，我应该能够在下拉列表中选择两个发行版本。

下图是架构图：

我想在下拉列表中选择新版本和旧版本，并据此比较版本的响应时间

我正在使用以下度量进行计算，我想从中删除常数

AVERAGEX(
    SUMMARIZE(
        FILTER(
            'public response_time',
            'public response_time'[release_id] = 23
        ),
        'public response_time'[sample_name],
        'public response_time'[average]
    ),
    [average]
)
NewReleasePct90 = 
    CALCULATE(
        AVERAGE('public response_time'[pct_90]),
        FILTER(
            'public response_time',
            'public response_time'[release_id] = 23
        )
    )
OldReleaseAverage = 
    AVERAGEX(
        SUMMARIZE(
            FILTER(
                'public response_time',
                RELATED('public release'[release_id]) = 22
            ),
            'public response_time'[sample_name],
            'public response_time'[average]
        ),
        [average]
    )
OldReleasePct90 = 
    CALCULATE(
        AVERAGE('public response_time'[pct_90]),
        FILTER(
            'public response_time',
            RELATED('public release'[release_id]) = 22
        )
    )

如下所示：

Answer 1

如果您想要两个切片器，那么您将需要第二个用于发布的表。

创建一个新的计算表（这将仅由新版本切片器使用）：

public release (new) = 'public release'

添加从

'public product'

到

'public release (new)'

的类似关系。您不需要（不要添加）从新表到

'public response_time'

表的关系。

然后更新您的措施：

OldReleaseAverage = 
  AVERAGEX(
    SUMMARIZE(
      'public response_time',
      'public response_time'[sample_name],
      'public response_time'[average]
    ),
    [average]
  )

OldReleasePct90 = 
  CALCULATE(
    AVERAGE('public response_time'[pct_90])
  )


NewReleaseAverage = 
  var newReleaseSlicer = MAX( 'public release (new)'[release_id] )
  return
    CALCULATE(
      [OldReleaseAverage],
      REMOVEFILTERS('public release'[release_id]),
      'public response_time'[release_id] = newReleaseSlicer 
    )

NewReleasePct90 = 
  var newReleaseSlicer = MAX( 'public release (new)'[release_id] )
  return
    CALCULATE(
      [OldReleasePct90],
      REMOVEFILTERS('public release'[release_id]),
      'public response_time'[release_id] = newReleaseSlicer 
    )