如何在VBA中一次为数组的某些元素分配相同的值？

问题描述 投票：1回答：6

我有兴趣知道如何在VBA中同时为数组中的某些元素，行或列分配相同的值？例如，我有一个像这样的3x3数组（MyArray）

1   2   3
4   5   6
7   8   9

我需要将元素MyArray（1,1），MyArray（2,2），MyArray（1,3）和MyArray（3,2）的值更改为11或将行2的值更改为13.现在，如何通过一个声明来做这些事情？我想的是：

Union(MyArray(1,1), MyArray(2,2), MyArray(1,3), MyArray(3,2)) = 11

和

MyArray(2,1 : 2,3) = 13

会工作，但发生了错误。我处理这个问题的方法是将数组的数据放在一个未使用的工作表上，更改那里的值，然后将工作表中的值读回到像this method这样的数组中。使用上面的例子，我然后使用以下代码：

Range("A1:C3") = MyArray: Range("A1,B2,C1,B3") = 11: MyArray = Range("A1:C3")

和

Range("A1:C3") = MyArray: Range("A2:C2") = 13: MyArray = Range("A1:C3")

没有使用工作表或循环还有其他选择吗？

arrays excel vba excel-vba assign
6个回答
3
投票

VBA原样，不支持这样的东西。只有一个范围才有可能。

理论上....

你可以使用Evaluate以极其有限的方式做这样的事情。要显示一些仅更改一行/列或二维数组的特定值的示例：

Dim MyArray() As Variant

Public Function MyArrayOut() As Variant
  MyArrayOut = MyArray
End Function

Sub testing()
  'we are using a 5x4 (4 columns / 5 rows) array
  ReDim MyArray(0 To 4, 0 To 3) As Variant 'also 1 to 5 and 1 to 4 are possible.... doesn't matter

  Dim i As Long, j As Long 'input some numbers
  For i = 0 To 4
    For j = 0 To 3
      MyArray(i, j) = i + 5 * j + 1
    Next
  Next

  [A1:D5].Value2 = MyArray
  Stop ' check the sheet -> should be 1 to 20

  'lets add 11 to the second row
  MyArray = Evaluate("=IF({0;1;0;0;0},MyArrayOut()+11,MyArrayOut())")

  [A1:D5].Value2 = MyArray
  Stop ' check again. row 2 should be 13, 18, 23, 28

  'set only 1,1 ; 2,2 ; 4,2 and 5,4 to 0. just keep in mind that using math will fail if ANY value is not numeric (or empty)
  MyArray = Evaluate("=MyArrayOut()*{0,1,1,1;1,0,1,1;1,1,1,1;1,0,1,1;1,1,1,0}")

  [A1:D5].Value2 = MyArray
  Stop 'A1, B2, B4, D5 all should be 0

  'set column 3 to "abc"

  MyArray = Evaluate("=IF({0,0,1,0},""abc"",MyArrayOut())")

  [A1:D5].Value2 = MyArray
  Stop ' check again. column C should be just abc

End Sub

使用有效的IF语句可以做很多事情，但是你需要对它进行硬编码，或者是一个非常复杂的算法，这种算法“无法”杀死“不循环”的想法。

此外，这将需要更多的资源，并且总是比直接做得慢。您还需要一个额外的函数来将数组放入evaluate中。

还有一种情况可以用于我的眼睛：通过INDEX提取一行/列。请记住，输出仍然是一个二维数组，可以通过Application.Transpose-Trick进行验证。它可用的原因只是事实，没有必要知道数组的大小。这样你就可以通过extrVar = Evaluate("=INDEX(MyArrayOut(),2,)")直接提取。虽然2可以通过不同的变量设置。这样你就不需要ReDim这个新变量（在这种情况下是extrVar）。它只需要变体。也就是说，使用Application.Index你也可以在没有使用Evaluate的情况下实现这一目标。 （这也使用更少的资源，更快）

我希望你知道如何使用评估来完成这项工作。

尽管如此，VBA本身并没有提供任何方法来通过语法本身一步操作数组的多个内容。 （至少不是你可以用于这种情况的方式）

编辑 我差点忘了：要将变量中的所有值设置为相同的值，像MyArray = Evaluate("=IF(MyArrayOut()="""",5,5)")这样的东西会将所有内容设置为5或MyArray = Evaluate("=IF(MyArrayOut()="""",""abc"",""abc"")")只包含“abc”。要清空它，你可以使用MyArray = Evaluate("=IF(MyArrayOut()="""","""","""")")，但没有ReDim的简单Preserve也可以在一行中完成。

编辑2

对于你的Range("A1:C3") = MyArray: Range("A1,B2,C1,B3") = 11: MyArray = Range("A1:C3")示例，你可以使用它作为自己的函数的基础，如：

Public Sub multiSetSame(ByRef arr As Variant, ByVal val As Variant, ParamArray str() As Variant)
  Dim runner As Variant
  For Each runner In str
    arr(Split(runner, ",")(0), Split(runner, ",")(1)) = val
  Next
End Sub

Sub test()
  Dim MyArray(1 To 3, 1 To 4) As Long

  multiSetSame MyArray, 11, "1,1", "2,2", "1,3", "3,2"

  [A1:D3].Value2 = MyArray
End Sub

但是对于这个例子，虽然我不知道如何评估要更改哪些值，但是在评估它们时要么直接更改它要么更好，或者如果它们总是相同，那么只需编写一个执行该工作的子服务器所有的价值观。任何“解决方法”都会减慢整个过程。

如果您还有任何疑问，请询问;）

1
投票

我不完全理解你的问题，所以我专注于问题的标题

如何在VBA中一次为数组的某些元素分配相同的值？

我不使用VBA所以我不确定但在Ruby之前我经常使用VbScript，这里有一个如何在VbScript中执行此操作的示例。我从来没有越过一个没有在VBA中运行的VbScript代码（相反我做过），但谁知道..

MyArray = array(_
array(1, 2, 3),_
array(4, 5, 6),_
array(7, 8, 9)_
)

Wscript.echo MyArray(0)(0) '1'
Wscript.echo MyArray(2)(2) '9'

编辑：正如Dirk所说：这个解决方案是一个单维数组，其中包含其他数组，但正如我的解决方案显示它通常更通用，它不需要初始化，例如..

1
投票

为了避免每次需要以定义的模式分配值时编写for循环，正如我所理解的那样，你必须像这样实现一个Sub：

SetArray(MyArray, patternStr, value)

patternStr是将被解析的字符串，并告诉Sub将值放在何处。一些可能性是：

“r1” - 值将转到第1行中的所有列

“c2” - 值将转到第2列中的所有行

“全部” - 价值归于所有元素

“3,2 1,1” - 值转到（3,2）和（1,1）...如果是3x3矩阵，也许你会想要省略模式中的逗号

您将不得不使用一些VBA代码实现此功能，至少一次，然后可以多次调用它并且非常容易理解调用代码。

您可能希望以与空格连接的字符串（如“r1 c2”）的方式实现解析器，执行所有单个分发。

然后，您的示例变为：

SetArray(MyArray, "1,1 2,2 1,3 3,2", 11)

EDIT1

也可以将数组包装在自定义类实例中，以便调用变得更短：

Set aw = New MyArrayWrapper
MyArrayWrapper.array = MyArray

aw.SetArray("1,1 2,2 1,3 3,2", 11)
aw.SetArray("r1 c2", 12)

我会编辑，如果它不清楚你。希望能帮助到你！

1
投票

我从来没有见过一种可以用矩形数组做到这一点的语言，但是对于数组数组来说它可以更容易一些：

MyArray = Array( [{1, 2, 3}], [{4, 5, 6}], [{7, 8, 9}] )
MyArray(0)(1) = 11 
MyArray(1) = [Column(A1:A3)*0+13]   ' changes a whole "row" to 13
MyArray(2) = MyArray(1)             ' copies one row to another

锯齿状阵列的缺点（或优点）是每个阵列可以具有不同的大小（元素的数量）或甚至是Nothing。

1
投票

VBA不提供在单个语句中分配多维数组的任何方法，因此您需要声明数组然后分配每个值：

Dim MyArray(2,2)

MyArray(0,0) = 1
MyArray(0,1) = 2
MyArray(0,2) = 3
MyArray(1,0) = 4
MyArray(1,1) = 5
MyArray(1,2) = 6
MyArray(2,0) = 7
MyArray(2,1) = 8
MyArray(2,2) = 9

编辑Slai的早期版本的答案有一个部分解决方案，我已经充实了一个避免使用锯齿状数组的解决方案。

事实证明，您可以在单个语句中分配2D数组，但该数组必须是Variant且基于1，并且它仅适用于Excel。

您可以分配单个元素，并且可以使用CopyMemory技巧分配整个“列”（但仅指定第一列）。如果您需要分配整个“行”或“列”，那么使用锯齿状数组可能会更好。

Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" ( _
    lpvDest As Any, _
    lpvSource As Any, _
    ByVal cbCopy As Long)

Sub test()
    'assign a 2D array using the [] shorthand syntax for Eval
    myArray = [{1,2,3;4,5,6;7,8,9}]

    'Change an individual value
    myArray(1, 2) = 11

    'Change the entire first row (this ONLY works for the first row)
    'Using a 1-based array assigned with []/Eval
    colarray = [{14,15,16}]
    CopyMemory myArray(1, 1), colarray(1), (UBound(colarray, 1) - LBound(colarray, 1) + 1) * 16 ' changes a whole "column"

    'Change the entire first row (this ONLY works for the first row)
    'Using a 0-based array assigned with Array()
    colarray = Array(17, 18, 19)
    CopyMemory myArray(1, 1), colarray(LBound(colarray, 1)), (UBound(colarray, 1) - LBound(colarray, 1) + 1) * 16 ' changes a whole "column"

End Sub
-2
投票

使用for循环为多个变量分配相同的值：

myArray[valueOne, valueTwe, valueThree];

for(var i = 0; i < myArray.length; i++) {           
    myArray[i] = true;          
}
最新问题
© www.soinside.com 2019 - 2024. All rights reserved.