我希望有人能给我一些想法!
我有以下3张桌子。它们是相关的:
CREATE TABLE [MemberDetails] (
[MemberID] int identity (1000,1) NOT NULL UNIQUE,
[MName] varchar(100) NOT NULL,
[MSurname] varchar(100) NOT NULL,
[MPhone] varchar(20) NOT NULL UNIQUE,
[MEmail] varchar(200) NOT NULL UNIQUE,
[MAddress] varchar(250) NOT NULL,
[MActive] char (1) NOT NULL CHECK (MActive IN ('Y','N')) DEFAULT 'Y',
[MUpdateDate] Date NOT NULL DEFAULT GETDATE(),
[MPhoto] Image NOT NULL,
[MDid] int NULL UNIQUE,
[MTid] int NULL UNIQUE,
PRIMARY KEY ([MemberID]),
FOREIGN KEY (MDid) REFERENCES [MembershipDetails] ([MDid]) ON DELETE SET NULL
ON UPDATE CASCADE,
FOREIGN KEY (MTid) REFERENCES [MarketingTarget] ([MTid]) ON DELETE SET NULL
ON UPDATE CASCADE
);
CREATE TABLE [MarketingTarget] (
[MTid] int identity (5000,1) NOT NULL UNIQUE,
[MDOB] date NOT NULL,
[MSex] char NOT NULL CHECK (MSex IN ('M','F')) DEFAULT 'M',
PRIMARY KEY ([MTid]),
);
CREATE TABLE [MembershipDetails] (
[MDid] int identity (2000,1) NOT NULL UNIQUE,
[MType] varchar(10) NOT NULL CHECK (MType IN ('Monthly','Quaterly','Yearly')) DEFAULT 'Monthly',
[JoinDate] Date NOT NULL DEFAULT GETDATE(),
[ExpiryDate] Date NULL,
[MsUpdateDate] Date DEFAULT GETDATE(),
PRIMARY KEY ([MDid])
);
我想知道是否可以从其他两个表中自动将FK插入MemberDetails表中?我正在尝试编写存储过程。
我正在检查Scope_Identity,它可以获取生成的最后一个身份,但是我不确定如何正确使用它。
任何建议都将不胜感激!
谢谢,
这里是一个示例(表已缩短):由于两个IDENTITY值都是必需的,因此我将它们保存到变量中,然后一起插入MemberDetail中。我建议为此事务进行交易。并看看TRY..CATCH。根据您的情况,您可能需要检查XACT_STATE()。
CREATE TABLE [_TEST_MemberDetails] (
[MemberID] int identity (1000,1) NOT NULL UNIQUE,
[MDid] int NULL UNIQUE,
[MTid] int NULL UNIQUE,
PRIMARY KEY ([MemberID]),
FOREIGN KEY (MDid) REFERENCES [_TEST_MembershipDetails] ([MDid]) ON DELETE SET NULL
ON UPDATE CASCADE,
FOREIGN KEY (MTid) REFERENCES [_TEST_MarketingTarget] ([MTid]) ON DELETE SET NULL
ON UPDATE CASCADE
);
CREATE TABLE [_TEST_MarketingTarget] (
[MTid] int identity (5000,1) NOT NULL UNIQUE,
[MDOB] date NOT NULL,
[MSex] char NOT NULL CHECK (MSex IN ('M','F')) DEFAULT 'M',
PRIMARY KEY ([MTid]),
);
CREATE TABLE [_TEST_MembershipDetails] (
[MDid] int identity (2000,1) NOT NULL UNIQUE,
[MType] varchar(10) NOT NULL CHECK (MType IN ('Monthly','Quaterly','Yearly')) DEFAULT 'Monthly',
[JoinDate] Date NOT NULL DEFAULT GETDATE(),
[ExpiryDate] Date NULL,
[MsUpdateDate] Date DEFAULT GETDATE(),
PRIMARY KEY ([MDid])
);
-- SP CODE START HERE
SET XACT_ABORT ON;
BEGIN TRY
BEGIN TRANSACTION
DECLARE @MTID int = 0, @MDID int = 0
INSERT INTO _TEST_MarketingTarget ([MDOB], [MSex])
VALUES ('Jan 1, 2020', 'M')
SELECT @MTID = SCOPE_IDENTITY()
INSERT INTO [_TEST_MembershipDetails] ([MType], [JoinDate], [ExpiryDate], [MsUpdateDate])
VALUES (DEFAULT, DEFAULT, 'Jan 1, 2020', DEFAULT)
SELECT @MDID = SCOPE_IDENTITY()
INSERT INTO [_TEST_MemberDetails] (Mdid, MTid)
SELECT @MDID, @MTID
COMMIT TRANSACTION
END TRY
BEGIN CATCH
IF @@TRANCOUNT <> 0 ROLLBACK TRANSACTION
END CATCH
go