如何检测Vim缓冲区是否包含折叠？

Question

寻找如何以编程方式检测当前 Vim 缓冲区是否包含至少一个定义的折叠的建议？无论折叠是打开还是关闭。

如果当前缓冲区中定义了折叠，则尝试调用

mkview

only：

autocmd BufWrite ?* if fold_defined() | mkview | endif

function fold_defined()
  ???
endfunction

Answer 1

func! CurrentWindowHasFolds()
    let view = winsaveview()
    for move in ['zj', 'zk']
        sil! exec 'keepjumps norm!' move
        if foldlevel('.') > 0
            call winrestview(view)
            return 1
        endif
    endfor
    return 0
endfunc

Answer 2

根据perreal的建议，我确实为我的问题写了一个可能的解决方案：

" Detect presence of fold definition in the current buffer
function FoldDefined()
  let result = 0
  let save_cursor = getpos('.')
  call cursor(1,1)
  let scanline = line('.') 
  let lastline = line('$')

  while scanline <= lastline
    if foldlevel(scanline) > 0
      let result = 1
      break
    endif
    let scanline = scanline + 1
  endwhile

  call setpos('.', save_cursor)

  return result
endfunction

Answer 3

function! FoldDefined()
   return len(filter(range(1, line('$')), 'foldlevel(v:val)>1'))>0
endfunction