CMake JNI错误

Question

我编写了一个从C ++调用java的绑定C ++类。我正在尝试使用CMake编译绑定类（因为将使用绑定类的工具使用CMake）。

但是我收到以下错误：

CMakeFiles/JNIWrapper.dir/JNIWrapper.cpp.o: In function `createVM(JavaVM_**)':
JNIWrapper.cpp:(.text+0x52): undefined reference to `JNI_CreateJavaVM'
collect2: ld returned 1 exit status
make[2]: *** [JNIWrapper] Error 1
make[1]: *** [CMakeFiles/JNIWrapper.dir/all] Error 2
make: *** [all] Error 2

这是我的CMakeLists.txt：

cmake_minimum_required(VERSION 2.8.6)

project(AProject)

FIND_PACKAGE(JNI REQUIRED)

SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -I/usr/lib/jvm/java-6-openjdk-amd64/include -I/usr/lib/jvm/java-6-openjdk-amd64/include/linux -L/usr/lib/jvm/java-6-openjdk-amd64/jre/lib/amd64/server")

SET(CMAKE_EXE_LINKER_FLAGS "-ljvm")

# add the binary tree directory to the search path for include files
include_directories(${CMAKE_CURRENT_SOURCE_DIR})
include_directories(${JNI_INCLUDE_DIRS})

# add the executable
add_executable (JNIWrapper JNIWrapper.cpp)

任何建议表示赞赏。

PS：我试图用传统的方式编写它并编写一个makefile。我按照那个例子编写了上面的CMakeLists.txt脚本。

Answer 1

以下CMakeLists.txt概述了使用CMake构建示例JNI项目所需的步骤：

cmake_minimum_required (VERSION 3.0)

find_package(Java REQUIRED)
find_package(JNI REQUIRED)
include(UseJava)

enable_testing()
project (JNIFoo)

# compile JNIFoo.java to class file
set(CMAKE_JAVA_COMPILE_FLAGS "-source" "1.6" "-target" "1.6")
add_jar(JNIFoo JNIFoo.java)
get_target_property(_jarFile JNIFoo JAR_FILE)
get_target_property(_classDir JNIFoo CLASSDIR)

# generate JNIFoo.h stub
set (_stubDir "${CMAKE_CURRENT_BINARY_DIR}")
add_custom_command(
    OUTPUT JNIFoo.h
    COMMAND ${Java_JAVAH_EXECUTABLE} -verbose
        -classpath ${_classDir}
        -d ${_stubDir}
        -jni JNIFoo
    DEPENDS JNIFoo
    )

# generate libfoo.jnilib
include_directories(${JNI_INCLUDE_DIRS} ${_classDir} ${_stubDir})
add_library(foo MODULE foo.c JNIFoo.h)
set_target_properties(foo PROPERTIES SUFFIX ".jnilib")
target_link_libraries(foo ${JNI_LIBRARIES})

# add test to run JNIFoo
add_test(NAME TestJNIFoo
    COMMAND ${Java_JAVA_EXECUTABLE}
    -Djava.library.path=${CMAKE_CURRENT_BINARY_DIR}
    -cp ${_jarFile} JNIFoo)

文件JNIFoo.java包含一个Java类，它在foo.c中声明一个函数作为本机方法nativeFoo。 foo.c包含方法nativeFoo的C实现。

CMake函数add_jar将Java类编译为jar文件，并且作为副作用，创建一个类文件，该文件需要作为javah C存根文件生成器可执行文件的输入传递。自定义命令用于调用javah以生成存根头JNIFoo.h作为输出文件。

因为Java使用System.loadLibrary在运行时加载JNI库，所以必须使用CMake命令MODULE将JNI库生成为add_library库。将JNIFoo.h添加为源文件可确保在编译库之前创建JNIFoo.h。编译的JNI库需要与变量JNI_LIBRARIES中包含的JDK JNI库链接。 JNI_INCLUDE_DIRS包含JNI包括使用的dirs。

最后，添加一个测试以使用JVM运行类JNIFoo。必须将系统属性java.library.path设置为包含生成的JNI库libfoo.jnilib的目录。