榆树如何使自定义事件解码器在鼠标滚轮移动时获得鼠标x / y位置

Question

我试图在Elm 0.19编程语言的鼠标滚轮移动事件中获取鼠标的x和y坐标。我尝试用这个包。请参阅“高级用法”：https://package.elm-lang.org/packages/mpizenberg/elm-pointer-events/3.1.0/Html-Events-Extra-Wheel

包本身没有描述一个明确的例子，所以我在类似的包中寻找一个例子。请参阅此页面中“高级用法”下的示例：https://package.elm-lang.org/packages/mpizenberg/elm-pointer-events/3.1.0/Html-Events-Extra-Mouse

这个例子和我需要的非常类似，但我也无法让它工作。得到完全相同的问题。

这是我的代码改编自适合鼠标滚轮的示例：

module WheelDecoder exposing(..)

import Html exposing (div, text)
import Html.Events.Extra.Wheel as Wheel
import Json.Decode as Decode


type alias WheelEventWithOffsetXY =
  { wheelEvent : Wheel.Event
  , offsetXY : {x: Float, y: Float}
  }

decodeWeelWithOffsetXY : Decode.Decoder WheelEventWithOffsetXY
decodeWeelWithOffsetXY =
  Decode.map2 WheelEventWithOffsetXY
    Wheel.eventDecoder
    offsetXYDecoder

offsetXYDecoder : Decode.Decoder {x: Float, y: Float}
offsetXYDecoder =
  Decode.map2 (\a b -> {x=a,y=b})
    (Decode.field "offsetY" Decode.float)
    (Decode.field "offsetY" Decode.float)

type Msg
  = WheelOffsetXY {x: Float, y: Float}

view = 
  div
    [ (onWheelOffsetXY (\wheelEvent -> WheelOffsetXY (wheelEvent.offsetXY))) ]
    [ (text "mousewheel here") ]


onWheelOffsetXY : (WheelEventWithOffsetXY -> msg) -> Html.Attribute msg
onWheelOffsetXY tag =
  let
    options = { stopPropagation = True, preventDefault = True }
    func = Decode.map tag decodeWeelWithOffsetXY
    attribute = Wheel.onWithOptions options func
  in
    attribute

当我尝试使用“elm make”进行编译时，我收到以下错误：

-- TYPE MISMATCH -------------------------------------- src/Map/WheelDecoder.elm

The 2nd argument to `onWithOptions` is not what I expect:

39|     attribute = Wheel.onWithOptions options func
                                                ^^^^
This `func` value is a:

    Decode.Decoder msg

But `onWithOptions` needs the 2nd argument to be:

    Wheel.Event -> msg

Hint: I always figure out the argument types from left to right. If an argument
is acceptable, I assume it is “correct” and move on. So the problem may actually
be in one of the previous arguments!

这个错误信息是有道理的，因为我可以看到存在类型不匹配，但我不知道如何解决它。

Answer 1

似乎Wheel.eventDecoder意味着与Html.Events.on或Html.Events.onWithOptions而不是Wheel.onWithOptions合作。然而，这些在0.19中被移除，有利于Html.Events.custom，这略有不同。用这个取代onWheelOffsetXY似乎有效：

onWheelOffsetXY : (WheelEventWithOffsetXY -> msg) -> Html.Attribute msg
onWheelOffsetXY tag =
  let
    options message =
        { message = message
        , stopPropagation = True
        , preventDefault = True
        }
    decoder =
        decodeWeelWithOffsetXY
        |> Decode.map tag 
        |> Decode.map options
  in
  Html.Events.custom "wheel" decoder

PS：在decodeWeelWithOffsetXY有一个错字，顺便说一句。我已经把错字留在了原地。

PPS：另外，您正在查看过时的文档。 Here's the documentation for the latest version。