如何在Coq中明确使用归纳原理？

Question

我试图在Coq中明确证明命题主体与归纳原理的对称性，但是不能像在agda中那样用归纳原理做到这一点。我不知道如何在Coq中局部声明变量，也不知道如何展开定义，如下所示。如何获得类似于下面的agda的证明？

Inductive Id (A : Type) (x : A) : A -> Type :=
  | refl : Id A x x.

(* trivial with induction *)
Theorem symId {A} {x y} : Id A x y -> Id A y x.
Proof.
  intros.
  induction H.
  apply refl.
Qed.

Check Id_ind.
(* Id_ind *)
(*      : forall (A : Type) (x : A) (P : forall a : A, Id A x a -> Prop), *)
(*        P x (refl A x) -> forall (y : A) (i : Id A x y), P y i *)

Theorem D {A} (x y : A) : Id A x y -> Prop.
Proof.
  intros.
  apply (Id A y x).
Qed.

Theorem d {A} (x : A) : D x x (refl A x).
Proof.
  apply refl.
Admitted.

此操作失败，我如何展开D以便断言反身性？

Theorem symId' {A} {x y} : Id A x y -> Id A y x.
Proof.
  intros.

我如何适用于正确的论点？我如何才能通过战术在本地断言D和d（是否存在where或（让a = b进入）战术？）套用（Id_ind A x（for all：A，Id A x a-> Prop））。

这是我要模拟的agda代码

data I (A : Set) (a : A) : A → Set where
r : I A a a

J2 : {A : Set} → (D : (x y : A) → (I A x y) →  Set)
  →  (d : (a : A) → (D a a r )) → (x y : A) → (p : I A x y) → D x y p
J2 D d x .x r = d x

refl-I : {A : Set} → (x : A) → I A x x
refl-I x = r

symm-I : {A : Set} → (x y : A) → I A x y → I A y x
symm-I {A} x y p = J2 D d x y p
  where
    D : (x y : A) → I A x y → Set
    D x y p = I A y x
    d : (a : A) → D a a r
    d a = r

尽管coq和agda J不相等，但它们大概是可导数的。

Answer 1

以Qed.结尾的证明会使证明变得不透明。有时这就是您想要的，但是如果您想要证明的计算内容，则应该以Defined.结尾。

这应该起作用，因为现在可以展开D。

Inductive Id (A : Type) (x : A) : A -> Type :=
  | refl : Id A x x.

(* trivial with induction *)
Theorem symId {A} {x y} : Id A x y -> Id A y x.
Proof.
  intros.
  induction H.
  apply refl.
Qed.

Check Id_ind.
(* Id_ind *)
(*      : forall (A : Type) (x : A) (P : forall a : A, Id A x a -> Prop), *)
(*        P x (refl A x) -> forall (y : A) (i : Id A x y), P y i *)

Theorem D {A} (x y : A) : Id A x y -> Prop.
Proof.
  intros.
  apply (Id A y x).
Defined.

Theorem d {A} (x : A) : D x x (refl A x).
Proof.
  apply refl.
Qed.

---

关于您的其他问题。您可以通过两种方式显式使用归纳法。一种是使用Id_rect，Id_rec或Id_ind（在定义Id时会自动声明）。例如，

Definition Id_sym {A: Type} {x y: A}: Id A x y -> Id A y x :=
Id_ind A x (fun y' _ => Id A y' x) (refl A x) y.

（（使用一些隐式参数可能使它更易于阅读）。

最终，这将转换为match语句，因此您也可以使用它。

Definition Id_sym' {A: Type} {x y: A} (p: Id A x y): Id A y x :=
  match p with
  | refl _ _ => refl _ _
  end.

---

要在定义中声明局部变量，可以使用let var := term in term形式。例如，上面的Id_sym可以重写为

Definition Id_sym'' {A: Type} {x y: A}: Id A x y -> Id A y x :=
let P := (fun y' _ => Id A y' x) in
Id_ind A x P (refl A x) y.