有没有一种方法可以批量指定多行字符串，类似于unix shell中的heredoc。类似的东西：
cat <<EOF > out.txt
bla
bla
..
EOF
我们的想法是从模板文件创建自定义文件。
不是我所知道的。
我最了解的是
> out.txt (
@echo.bla
@echo.bla
...
)
（@阻止命令shell本身打印它正在运行的命令，而echo.允许你用空格开始一行。）
@echo off
cls
title Drop Bomb
echo/
echo/ creating...
:: Creating a batchfile from within a batchfile.
echo @echo off > boom.bat
echo cls >> boom.bat
echo color F0 >> boom.bat
echo echo/ >> boom.bat
echo echo --- B-O-O-M !!! --- >> boom.bat
echo echo/ >> boom.bat
echo pause >> boom.bat
echo exit >> boom.bat
:: Now lets set it off
start boom.bat
title That hurt my ears.
cls
echo/
echo - now look what you've done!
pause
在Microsoft NMake makefile中，可以使用真正的UNIX heredoc，因为线程所有者请求它们。例如，这是创建文件Deploy.sed的明确规则：
Deploy.sed:
type << >$@
; -*-ini-generic-*-
;
; Deploy.sed -- Self-Extracting Directives
;
[Version]
Class=IEXPRESS
SEDVersion=3
.
.
[Strings]
InstallPrompt=Install $(NAME)-$(VERSION).xll to your personal XLSTART directory?
DisplayLicense=H:\prj\prog\XLL\$(NAME)\README.txt
.
.
<<
clean:
-erase /Q Deploy.sed
其中<<扩展为NMake在执行规则时动态创建的临时文件名。也就是说，当Deploy.sed不存在时。好的是NMake变量也被扩展（这里是变量NAME和VERSION）。将其保存为makefile。在makefile目录中打开一个DOS框并使用：
> nmake Deploy.sed
创建文件，并：
> nmake clean
删除它。 NMake是Visual Studio C ++所有版本的一部分，包括Express版本。
扩展到ephemient帖子，我认为是最好的，以下将做一个管道：
(
@echo.line1
@echo.line2 %time% %os%
@echo.
@echo.line4
) | more
在ephemient的帖子中，他在开头重定向，这是一个很好的风格，但你也可以在最后重定向：
(
@echo.line1
@echo.line2 %time% %os%
@echo.
@echo.line4
) >C:\Temp\test.txt
请注意“@echo”。从未包含在输出和“@echo”中。本身给出一个空白行。
这更容易，与cat << EOF> out.txt非常相似：
C：\> copy con out.txt 这是我的第一行文字。 这是我的最后一行文字。 ^ Z 已复制1个文件。
输出如下：
C：\>输入out.txt 这是我的第一行文字。 这是我的最后一行文字。
（复制con + out.txt，输入您的输入，然后按Ctrl-Z并复制文件）
COPY CON表示“从控制台复制”（接受用户输入）
OP想要的是非常具体的东西（用输出创建一个文本文件），并且接受的答案完美地做到了，但所提出的解决方案在特定的上下文之外并不能很好地工作。例如，如果我想将多行输入传递给命令，我就不能使用( echo )语法。这就是为我工作的结果。
给定一个名为“echolines.pl”的perl脚本，该脚本包含以下内容（用于模拟“真正的”程序）：
use strict;
use warnings;
while (<>) {
chomp;
print qq(<$_>\n);
}
以及一个名为“testme.bat”的批处理文件，其中包含：
@echo off
set FOO=foo
set BAR=bar
set BAZ=baz
echo %FOO%^
&echo %BAR%^
&echo %BAZ%|perl echolines.pl
运行它会产生预期的输出：
C:\>testme
<foo>
<bar>
<baz>
必须注意空白以确保一切正常，任何地方都没有杂散空间。具体来说：每个行尾应为插入符号（^）后跟换行符，后续行必须立即以符号（＆）开头，最后一行必须在最后一个要发送的项目后立即启动管道。如果不这样做，将导致参数之前和之后缺少参数或额外的空格。
试试这个代码。 （底部的JScript代码将“out.html”写入磁盘）
@if(0)==(0) echo on
cscript.exe //nologo //E:JScript "%~f0" source1 out.html
start out.html
goto :EOF
[source1]
<!DOCTYPE html>
<html>
<head>
title></title>
</head>
<body>
<svg width="900" height="600">
<text x="230"
y="150"
font-size="100"
fill="blue"
stroke="gray"
stroke-width="1">
Hello World
</text>
</svg>
</body>
</html>
[/source1]
@end
if (WScript.Arguments.length != 2) WScript.Quit();
var tagName = WScript.Arguments(0);
var path = WScript.Arguments(1);
var startTag = "[" + tagName + "]"
var endTag = "[/" + tagName + "]"
var fso = new ActiveXObject("Scripting.FileSystemObject");
var file1 = fso.OpenTextFile(WScript.ScriptFullName);
var txt = "";
var found = false;
while (!file1.AtEndOfStream) {
var line = file1.ReadLine();
if (!found) {
if (line.lastIndexOf(startTag, 0) === 0) found = true;
} else {
if (line.lastIndexOf(endTag, 0) === 0) break;
txt += line + "\n";
}
}
file1.Close();
var file2 = fso.CreateTextFile(path, true, false);
file2.Write(txt);
file2.Close();
这是ephemient优秀解决方案的变种。这允许您将多行传输到另一个程序，而无需实际创建文本文件并输入重定向到您的程序：
(@echo.bla
@echo.bla
) | yourprog.exe
有关快速，有效的示例，您可以使用yourprog.exe替换more：
(@echo.bla
@echo.bla
) | more
输出：
bla
bla
C:\>more >file.txt
This is line 1 of file
This is line 2 of file
^C
C:\>type file.txt
This is line 1 of file
This is line 2 of file
**它会在末尾添加一个空行，但只需使用copy con方法即可轻松解决：
C:\>copy con file.txt >nul
This is line 1 of file
This is line 2 of file^Z
C:\>type file.txt
This is line 1 of file
This is line 2 of file
注意在每种情况下键入^ C和^ Z的位置。
这是另一种方法。
@echo off
:: ######################################################
:: ## Heredoc syntax: ##
:: ## call :heredoc uniqueIDX [>outfile] && goto label ##
:: ## contents ##
:: ## contents ##
:: ## contents ##
:: ## etc. ##
:: ## :label ##
:: ## ##
:: ## Notes: ##
:: ## Variables to be evaluated within the heredoc ##
:: ## should be called in the delayed expansion style ##
:: ## (!var! rather than %var%, for instance). ##
:: ## ##
:: ## Literal exclamation marks (!) and carats (^) ##
:: ## must be escaped with a carat (^). ##
:: ######################################################
:--------------------------------------------
: calling heredoc with results sent to stdout
:--------------------------------------------
call :heredoc stickman && goto next1
\o/
| This is the "stickman" heredoc, echoed to stdout.
/ \
:next1
:-----------------------------------------------------------------
: calling heredoc containing vars with results sent to a text file
:-----------------------------------------------------------------
set bodyText=Hello world!
set lipsum=Lorem ipsum dolor sit amet, consectetur adipiscing elit.
call :heredoc html >out.txt && goto next2
<html lang="en">
<body>
<h3>!bodyText!</h3>
<p>!lipsum!</p>
</body>
</html>
Thus endeth the heredoc. :)
:next2
echo;
echo Does the redirect to a file work? Press any key to type out.txt and find out.
echo;
pause>NUL
type out.txt
del out.txt
:: End of main script
goto :EOF
:: ########################################
:: ## Here's the heredoc processing code ##
:: ########################################
:heredoc <uniqueIDX>
setlocal enabledelayedexpansion
set go=
for /f "delims=" %%A in ('findstr /n "^" "%~f0"') do (
set "line=%%A" && set "line=!line:*:=!"
if defined go (if #!line:~1!==#!go::=! (goto :EOF) else echo(!line!)
if "!line:~0,13!"=="call :heredoc" (
for /f "tokens=3 delims=>^ " %%i in ("!line!") do (
if #%%i==#%1 (
for /f "tokens=2 delims=&" %%I in ("!line!") do (
for /f "tokens=2" %%x in ("%%I") do set "go=%%x"
)
)
)
)
)
goto :EOF
示例输出：
C:\Users\oithelp\Desktop>heredoc
\o/
| This is the "stickman" heredoc, echoed to stdout.
/ \
Does the redirect to a file work? Press any key to type out.txt and find out.
<html lang="en">
<body>
<h3>Hello world!</h3>
<p>Lorem ipsum dolor sit amet, consectetur adipiscing elit.</p>
</body>
</html>
Thus endeth the heredoc. :)
是的，很有可能。 ^是文字转义字符，只需将它放在换行符之前。在这个例子中，我还添加了额外的换行符，以便在文件中正确打印：
@echo off
echo foo ^
this is ^
a multiline ^
echo > out.txt
输出：
E:\>type out.txt
foo
this is
a multiline
echo
E:\>
@echo off
for /f "delims=:" %%a in (
'findstr -n "^___" %0') do set "Line=%%a"
(for /f "skip=%Line% tokens=* eol=_" %%a in (
'type %0') do echo(%%a) > out.html
:: out.html
pause
goto: EOF
___DATA___
<!Doctype html>
<html>
<head>
title></title>
</head>
<body>
<svg width="900" height="600">
<text x="230"
y="150"
font-size="100"
fill="blue"
stroke="gray"
stroke-width="1">
Hello World
</text>
</svg>
</body>
</html>
在DosTips，西伯利亚男子以amazing behavior of an erroneous GOTO statement的形式发布了(goto) 2>nul的示范。然后Aacini和jeb记录了一些关于奇怪行为的其他有趣发现。它基本上表现得像EXIT /B，除了它允许CALLed例程中的连接命令在父调用者的上下文中执行。
这是一个简短的脚本，演示了大多数要点：
@echo off
setlocal enableDelayedExpansion
set "var=Parent Value"
(
call :test
echo This and the following line are not executed
exit /b
)
:break
echo How did I get here^^!^^!^^!^^!
exit /b
:test
setlocal disableDelayedExpansion
set "var=Child Value"
(goto) 2>nul & echo var=!var! & goto :break
echo This line is not executed
:break
echo This line is not executed
- 输出 -
var=Parent Value
How did I get here!!!!
这种惊人的行为使我能够编写一个优雅的批量模拟这里的文档，其中包含许多可用于unix的选项。我将PrintHere.bat实现为一个独立的实用程序，应该放在PATH中列出的文件夹中。然后，任何批处理脚本都可以轻松调用该实用程序以获取此处的doc功能。
以下是一般用法语法：
call PrintHere :Label
Here doc text goes here
:Label
怎么可能实现这个？...我的PrintHere实用程序使用(GOTO) 2>nul技巧两次。
(GOTO) 2>nul返回调用者，这样我就可以获得调用脚本的完整路径，以便PrintHere知道要读取的文件。然后我再次打印PrintHere！(GOTO) 2>nul返回调用者并转到终止标签，以便不执行此处的doc文本。注意 - 下面的脚本在选项卡的定义中包含一个制表符（0x09），位于:start标签的正下方。某些浏览器可能难以显示和复制选项卡。作为替代方案，您可以使用download PrintHere.bat.txt from my dropbox，并将其重命名为PrintHere.bat。
我最初发布了PrintHere.bat at DosTips，你可以在那里跟踪未来的发展。
PrintHere.bat
@echo off & setlocal disableDelayedExpansion & goto :start
::PrintHere.bat version 1.1 by Dave Benham
:::
:::call PrintHere [/E] [/- "TrimList"] :Label ["%~f0"]
:::call PrintHere [/E] [/- "TrimList"] :Label "%~f0" | someCommand & goto :Label
:::PrintHere /?
:::PrintHere /V
:::
::: PrintHere.bat provides functionality similar to the unix here doc feature.
::: It prints all content between the CALL PrintHere :Label line and the
::: terminating :Label. The :Label must be a valid label supported by GOTO, with
::: the additional constraint that it not contain *. Lines are printed verbatim,
::: with the following exceptions and limitations:
:::
::: - Lines are lmited to 1021 bytes long
::: - Trailing control characters are stripped from each line
:::
::: The code should look something like the following:
:::
::: call PrintHere :Label
::: Spacing and blank lines are preserved
:::
::: Special characters like & < > | ^ ! % are printed normally
::: :Label
:::
::: If the /E option is used, then variables between exclamation points are
::: expanded, and ! and ^ literals must be escaped as ^! and ^^. The limitations
::: are different when /E is used:
:::
::: - Lines are limited to ~8191 bytes long
::: - All characters are preserved, except !variables! are expanded and ^! and
::: ^^ are transformed into ! and ^
:::
::: Here is an example using /E:
:::
::: call PrintHere /E :SubstituteExample
::: Hello !username!^!
::: :SubstituteExample
:::
::: If the /- "TrimList" option is used, then leading "TrimList" characters
::: are trimmed from the output. The trim characters are case sensitive, and
::: cannot include a quote. If "TrimList" includes a space, then it must
::: be the last character in the list.
:::
::: Multiple PrintHere blocks may be defined within one script, but each
::: :Label must be unique within the file.
:::
::: PrintHere must not be used within a parenthesized code block.
:::
::: Scripts that use PrintHere must use \r\n for line termination, and all lines
::: output by PrintHere will be terminated by \r\n.
:::
::: All redirection associated with a PrintHere must appear at the end of the
::: command. Also, the CALL can include path information:
:::
::: call "c:\utilities\PrintHere.bat" :MyBlock>test.txt
::: This line is written to test.txt
::: :MyBlock
:::
::: PrintHere may be used with a pipe, but only on the left side, and only
::: if the source script is included as a 2nd argument, and the right side must
::: explicitly and unconditionally GOTO the terminating :Label.
:::
::: call PrintHere :PipedBlock "%~f0" | more & goto :PipedBlock
::: text goes here
::: :PipedBlock
:::
::: Commands concatenated after PrintHere are ignored. For example:
:::
::: call PrintHere :ignoreConcatenatedCommands & echo This ECHO is ignored
::: text goes here
::: :ignoreConcatenatedCommands
:::
::: PrintHere uses FINDSTR to locate the text block by looking for the
::: CALL PRINTHERE :LABEL line. The search string length is severely limited
::: on XP. To minimize the risk of PrintHere failure when running on XP, it is
::: recommended that PrintHere.bat be placed in a folder included within PATH
::: so that the utility can be called without path information.
:::
::: PrintHere /? prints out this documentation.
:::
::: PrintHere /V prints out the version information
:::
::: PrintHere.bat was written by Dave Benham. Devlopment history may be traced at:
::: http://www.dostips.com/forum/viewtopic.php?f=3&t=6537
:::
:start
set "tab= " NOTE: This value must be a single tab (0x09), not one or more spaces
set "sp=[ %tab%=,;]"
set "sp+=%sp%%sp%*"
set "opt="
set "/E="
set "/-="
:getOptions
if "%~1" equ "" call :exitErr Invalid call to PrintHere - Missing :Label argument
if "%~1" equ "/?" (
for /f "tokens=* delims=:" %%L in ('findstr "^:::" "%~f0"') do echo(%%L
exit /b 0
)
if /i "%~1" equ "/V" (
for /f "tokens=* delims=:" %%L in ('findstr /rc:"^::PrintHere\.bat version" "%~f0"') do echo(%%L
exit /b 0
)
if /i %1 equ /E (
set "/E=1"
set "opt=%sp+%.*"
shift /1
goto :getOptions
)
if /i %1 equ /- (
set "/-=%~2"
set "opt=%sp+%.*"
shift /1
shift /1
goto :getOptions
)
echo %1|findstr "^:[^:]" >nul || call :exitErr Invalid PrintHere :Label
if "%~2" equ "" (
(goto) 2>nul
setlocal enableDelayedExpansion
if "!!" equ "" (
endlocal
call %0 %* "%%~f0"
) else (
>&2 echo ERROR: PrintHere must be used within a batch script.
(call)
)
)
set ^"call=%0^"
set ^"label=%1^"
set "src=%~2"
setlocal enableDelayedExpansion
set "call=!call:\=[\\]!"
set "label=!label:\=[\\]!"
for %%C in (. [ $ ^^ ^") do (
set "call=!call:%%C=\%%C!"
set "label=!label:%%C=\%%C!"
)
set "search=!sp!*call!sp+!!call!!opt!!sp+!!label!"
set "cnt="
for /f "delims=:" %%N in ('findstr /brinc:"!search!$" /c:"!search![<>|&!sp:~1!" "!src!"') do if not defined skip set "skip=%%N"
if not defined skip call :exitErr Unable to locate CALL PrintHere %1
for /f "delims=:" %%N in ('findstr /brinc:"!sp!*!label!$" /c:"!sp!*!label!!sp!" "!src!"') do if %%N gtr %skip% if not defined cnt set /a cnt=%%N-skip-1
if not defined cnt call :exitErr PrintHere end label %1 not found
if defined /E (
for /f "skip=%skip% delims=" %%L in ('findstr /n "^^" "!src!"') do (
if !cnt! leq 0 goto :break
set "ln=%%L"
if not defined /- (echo(!ln:*:=!) else for /f "tokens=1* delims=%/-%" %%A in (^""%/-%!ln:*:=!") do (
setlocal disableDelayedExpansion
echo(%%B
endlocal
)
set /a cnt-=1
)
) else (
for /l %%N in (1 1 %skip%) do set /p "ln="
for /l %%N in (1 1 %cnt%) do (
set "ln="
set /p "ln="
if not defined /- (echo(!ln!) else for /f "tokens=1* delims=%/-%" %%A in (^""%/-%!ln!") do (
setlocal disableDelayedExpansion
echo(%%B
endlocal
)
)
) <"!src!"
:break
(goto) 2>nul & goto %~1
:exitErr
>&2 echo ERROR: %*
(goto) 2>nul & exit /b 1
完整文档嵌入在脚本中。以下是一些使用示例：
逐字输出
@echo off
call PrintHere :verbatim
Hello !username!^!
It is !time! on !date!.
:verbatim
- 输出 -
Hello !username!^!
It is !time! on !date!.
展开变量（不需要启用延迟扩展）
@echo off
call PrintHere /E :Expand
Hello !username!^!
It is !time! on !date!.
:Expand
--OUTPUT--
Hello Dave!
It is 20:08:15.35 on Fri 07/03/2015.
展开变量并修剪前导空格
@echo off
call PrintHere /E /- " " :Expand
Hello !username!^!
It is !time! on !date!.
:Expand
--OUTPUT--
Hello Dave!
It is 20:10:46.09 on Fri 07/03/2015.
输出可以重定向到文件
@echo off
call PrintHere :label >helloWorld.bat
@echo Hello world!
:label
输出不能重定向为输入，但可以通过管道输出！不幸的是，语法并不像both sides of a pipe are executed in a new CMD.EXE process那样优雅，所以(GOTO) 2>nul返回到子cmd进程，而不是主脚本。
@echo off
call PrintHere :label "%~f0" | findstr "^" & goto :label
Text content goes here
:label
使用macro with parameters允许以更简单的方式编写“heredoc”：
@echo off
rem Definition of heredoc macro
setlocal DisableDelayedExpansion
set LF=^
::Above 2 blank lines are required - do not remove
set ^"\n=^^^%LF%%LF%^%LF%%LF%^^"
set heredoc=for %%n in (1 2) do if %%n==2 (%\n%
for /F "tokens=1,2" %%a in ("!argv!") do (%\n%
if "%%b" equ "" (call :heredoc %%a) else call :heredoc %%a^>%%b%\n%
endlocal ^& goto %%a%\n%
)%\n%
) else setlocal EnableDelayedExpansion ^& set argv=
rem Heredoc syntax:
rem
rem %%heredoc%% :uniqueLabel [outfile]
rem contents
rem contents
rem ...
rem :uniqueLabel
rem
rem Same notes of rojo's answer apply
rem Example borrowed from rojo's answer:
set bodyText=Hello world!
set lipsum=Lorem ipsum dolor sit amet, consectetur adipiscing elit.
%heredoc% :endHtml out.txt
<html lang="en">
<body>
<h3>!bodyText!</h3>
<p>!lipsum!</p>
</body>
</html>
:endHtml
echo File created:
type out.txt
del out.txt
goto :EOF
rem Definition of heredoc subroutine
:heredoc label
set "skip="
for /F "delims=:" %%a in ('findstr /N "%1" "%~F0"') do (
if not defined skip (set skip=%%a) else set /A lines=%%a-skip-1
)
for /F "skip=%skip% delims=" %%a in ('findstr /N "^" "%~F0"') do (
set "line=%%a"
echo(!line:*:=!
set /A lines-=1
if !lines! == 0 exit /B
)
exit /B
@jeb
setlocal EnableDelayedExpansion
set LF=^
REM Two empty lines are required
另一个变种：
@echo off
:)
setlocal enabledelayedexpansion
>nul,(pause&set /p LF=&pause&set /p LF=)<%0
set LF=!LF:~0,1!
echo 1!LF!2!LF!3
pause
参考rojo在https://stackoverflow.com/a/15032476/3627676的帖子
当然，他的解决方案是我正在寻找的东西（当然，我可以尝试实现与此类似的东西，但懒惰移动进展:)）。我想补充一点是对原始代码的一个小改进。我认为如果重定向到文件是在行尾写的会更好。在这种情况下，heredoc起动器线可能更严格，分析更简单。
@echo off
set "hello=Hello world!"
set "lorem=Lorem ipsum dolor sit amet, consectetur adipiscing elit."
call :heredoc HTML & goto :HTML
<html>
<title>!hello!</title>
<body>
<p>Variables in heredoc should be surrounded by the exclamation mark (^!).</p>
<p>!lorem!</p>
<p>Exclamation mark (^!) and caret (^^) MUST be escaped with a caret (^^).</p>
</body>
</html>
:HTML
goto :EOF
:: https://stackoverflow.com/a/15032476/3627676
:heredoc LABEL
setlocal enabledelayedexpansion
set go=
for /f "delims=" %%A in ( '
findstr /n "^" "%~f0"
' ) do (
set "line=%%A"
set "line=!line:*:=!"
if defined go (
if /i "!line!" == "!go!" goto :EOF
echo:!line!
) else (
rem delims are ( ) > & | TAB , ; = SPACE
for /f "tokens=1-3 delims=()>&| ,;= " %%i in ( "!line!" ) do (
if /i "%%i %%j %%k" == "call :heredoc %1" (
set "go=%%k"
if not "!go:~0,1!" == ":" set "go=:!go!"
)
)
)
)
goto :EOF
我在这段代码中建议什么？我们考虑一下。
Rojo的代码非常严格：
call和:heredoc之间的字符串中不允许有多个空格字符call :heredoc粘在线的边缘（在行的开头没有任何空格）我建议的事情：
更新1：检查和执行heredoc开头的改进：
call :heredoc LABEL或call :heredoc :LABEL。因此，在打印heredoc内容后，可以跳转到另一个标签，脚本结束或运行exit /b。更新2：
for的分隔符是( ) > & | TAB , ; = SPACE/I添加到if更新3：
通过以下链接，您可以找到独立脚本的完整版本（可以在脚本中嵌入）https://github.com/ildar-shaimordanov/tea-set/blob/master/bin/heredoc.bat
您可以使用FOR / F循环创建带引号的文本块，因此您不需要像<>|&那样转义特殊字符，只需要转义%。
这有时像创建html输出一样有用。
@echo off
setlocal EnableDelayedExpansion
set LF=^
REM Two empty lines are required
set ^"NL=^^^%LF%%LF%^%LF%%LF%^^"
for /F "tokens=* delims=_" %%a in (^"%NL%
___"One<>&|"%NL%
___"two 100%%"%NL%
___%NL%
___"three "quoted" "%NL%
___"four"%NL%
") DO (
@echo(%%~a
)
产量
One<>&|
two 100%
three "quoted"
four
我试着解释代码。 LF变量包含一个换行符，NL变量包含^<LF><LF>^。
这可以与百分比扩展一起使用，以在行末端放置一个换行符和一个插入符号。
通常，FOR / F将带引号的文本拆分为多个令牌，但仅限一次。 当我插入换行符时，FOR循环也会分成多行。 第一行和最后一行的引用只是为FOR循环创建正确的语法。
在任何一行的前面是_，因为第一个字符将从前一行的多行插入符中转义，如果引号是第一个字符，则它将失去转义能力。
使用_ delims，因为空格或逗号导致XP出现问题（否则XP-Bug伪造尝试访问垃圾文件名）。
线端的插入符号也只是针对XP-Bug。
当引用的文本包含不带引号的,;=<space>字符时，XP-Bug生效
for /f "tokens=*" %%a in ("a","b","c") do echo %%a