存储过程在asp.net web api中返回错误的值

问题描述 投票:0回答:1

我写了一些程序代码,它成功运行时返回值1

但它总是返回-1(失败的价值),当它在ASP.NET Web API顺利。

我在SSMS用这种情况进行了测试。

USE [MY_DATABASE]
GO

DECLARE @return_value int

EXEC    @return_value = [dbo].[API_TO_WEB_CREATE_RESOURCE]
        @RES_Size = 3019,
        @RES_ContentType = N'image/jpeg',
        @RES_OriginalName = N'evolving_google_identity_share.jpg',
        @RES_GUID = N'b98bd7ee-cb19-49c8-a8dc-3b92b3210b91',
        @RES_Path = N'~/Content/resources\\b98bd7ee-cb19-49c8-a8dc-3b92b3210b91',
        @RES_Upload_USR_Index = NULL

SELECT  'Return Value' = @return_value

GO

这将返回1


ASP.NET Web API中的相同代码。

int result = context.API_TO_WEB_CREATE_RESOURCE(
                            3019,
                            "image/jpeg",
                            "evolving_google_identity_share.jpg",
                            "b98bd7ee-cb19-49c8-a8dc-3b92b3210b91",
                            "~/Content/resources\\b98bd7ee-cb19-49c8-a8dc-3b92b3210b91",
                            null
                            );

这将返回-1

这是我的程序。

USE [MY_DATABASE]
GO

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
-- =============================================
-- Author:  
-- Create date: 
-- Description: 
-- =============================================
ALTER PROCEDURE [dbo].[API_TO_WEB_CREATE_RESOURCE]
    -- Add the parameters for the stored procedure here
    @RES_Size int = 0,
    @RES_ContentType nvarchar(100) = NULL,
    @RES_OriginalName nvarchar(300),
    @RES_GUID nvarchar(50),
    @RES_Path nvarchar(500),
    @RES_Upload_USR_Index int = NULL
AS
BEGIN
    DECLARE @RES_RegisteredDatetime datetime = GETDATE()
    -- SET NOCOUNT ON added to prevent extra result sets from
    -- interfering with SELECT statements.
    SET NOCOUNT ON;

    BEGIN TRY
        BEGIN TRAN

            INSERT INTO 
                dbo.NS_Resource (RES_Size, RES_ContentType, RES_OriginalName, RES_GUID, RES_Path, RES_Upload_USR_Index) 
            VALUES (@RES_Size, @RES_ContentType, @RES_OriginalName, @RES_GUID, @RES_Path, @RES_Upload_USR_Index);

            PRINT '리소스 추가됨'
        COMMIT TRAN

        RETURN(1); 
    END TRY
    BEGIN CATCH
        ROLLBACK TRAN
        DECLARE @ERROR_Msg nvarchar = error_message()
        RAISERROR('리소스 추가 중 문제 발생됨 %s', 16, 1, @ERROR_Msg)
        RETURN (-1)
    END CATCH
END

摘要

Expected

返回值1并成功插入新值。

Actual

  • 在SSMS中

返回值1并成功插入新值。

  • 在ASP.NET Web API中(这是问题)

返回值-1并成功插入新值。

sql-server asp.net-web-api stored-procedures
1个回答
1
投票

在代码模块中使用多个return语句绝不是一个好主意,而SQL也不例外。尝试按如下方式重写您的过程,看看它是否有帮助:

ALTER PROCEDURE [dbo].[API_TO_WEB_CREATE_RESOURCE]
    -- Add the parameters for the stored procedure here
    @RES_Size int = 0,
    @RES_ContentType nvarchar(100) = NULL,
    @RES_OriginalName nvarchar(300),
    @RES_GUID nvarchar(50),
    @RES_Path nvarchar(500),
    @RES_Upload_USR_Index int = NULL
AS

DECLARE @RES_RegisteredDatetime datetime = GETDATE();
-- SET NOCOUNT ON added to prevent extra result sets from
-- interfering with SELECT statements.
SET NOCOUNT ON;

declare @Ret int = -1; -- Failure by default

BEGIN TRY
    BEGIN TRAN

        INSERT INTO 
            dbo.NS_Resource (RES_Size, RES_ContentType, RES_OriginalName, RES_GUID, RES_Path, RES_Upload_USR_Index) 
        VALUES (@RES_Size, @RES_ContentType, @RES_OriginalName, @RES_GUID, @RES_Path, @RES_Upload_USR_Index);

        PRINT '리소스 추가됨';
    COMMIT TRAN

    set @Ret = 1; -- Success
END TRY
BEGIN CATCH
    if @@trancount > 0
        ROLLBACK TRAN;

    DECLARE @ERROR_Msg nvarchar(2048) = error_message();
    RAISERROR('리소스 추가 중 문제 발생됨 %s', 16, 1, @ERROR_Msg);
END CATCH;

return @Ret;
go

但是,对我来说整件事看起来有点麻烦。如果你从catch块中向客户端抛出错误,这应该就足够了。它将转换为C#中的SQLException,因此返回值变得无关紧要。

就个人而言,我不使用返回值;相反,我通常创建2个输出参数,int为数字,nvarchar(2048)为错误消息,并在catch块中分配它们的值而不重新投掷。执行完成后,我只需检查@ErrorNumber输出参数的值,如果它既不是零也不是NULL,我在客户端处理错误。

© www.soinside.com 2019 - 2024. All rights reserved.