具有Data.Aeson.Lens的转换

Question

使用aeson-lens，我编写了此程序，使我非常接近想要实现的目标：

{-# LANGUAGE OverloadedStrings #-}

import Network.HTTP.Conduit ( simpleHttp )
import Data.Aeson           ( decode
                            , Value
                            )
import Data.Maybe           ( fromJust )
import Control.Lens         ( (^.) )
import Data.Aeson.Lens      ( key, nth )

main :: IO ()
main = do
  pageContents <- simpleHttp "http://127.0.0.1:28017/baseball/team/"
  let v = decode pageContents :: Maybe Value
  let totalRowsVal = v ^. key "total_rows" :: Maybe Int
      oidVal       = v ^. key "rows" . nth 0 ^. key "_id" ^. key "$oid" :: Maybe String
  print totalRowsVal
  print oidVal
  return ()

JSON内容是：

{
  "total_rows": 2,
  "rows": [
    {
      "_id": { "$oid": "5548ed2671eab385baadf0a7" },
      "abc": 123
    },
    {
      "_id": { "$oid": "5548ed5171eab385baadf0a8" },
      "def": 456
    }
  ],
  "query": {},
  "offset": 0,
  "millis": 0
}

输出为：

Just 2
Just "5548ed2671eab385baadf0a7"

我想说到输出是：

Just 2
Just [("abc",123),("def",456)]

换句话说，我想从rows键下的值中提取有用的内容，而无需事先知道该JSON数组的元素中的键是什么。我还希望程序向用户发送信号，即query键下的值是一个空的JSON对象。

Answer 1

首先使用lens-aeson而不是aeson-lens。 aeson-lens已有一段时间没有更新，我认为它的所有镜头都不守法。由于它们都共享Data.Aeson.Lens，因此您必须运行ghc-pkg unregister aeson-lens（如果您使用cabal sandbox hc-pkg unregister aeson-lens，正在使用沙箱）。

您尚未确切描述您如何知道“有用内容”，所以我假设它是不被称为"_id"的任何东西，并且指向整数。在aeson-lens中，数组的每个对象都是HashMap，因此我们首先遍历这些对象：

rows :: Traversal' Value (HM.HashMap Text Value)
rows = key "rows" . _Array . each . _Object
-- or  key "rows" . values

对于行值，我们可以使用索引遍历，其中索引是Text的HashMap。然后，我们可以通过检查索引不是ifiltered来使用"_id"过滤内容。我们还使用_Integer仅使内容指向Integer。

nonIds :: IndexedTraversal' Text (HM.HashMap Text Value)  Integer
nonIds = itraversed . ifiltered (\i _ -> i /= "_id") . _Integer
-- or    members . ifiltered (\i _ -> i /= "_id") . _Integer

从这里很容易获得想要的列表：

> v ^@.. rows . nonIds
[("abc",123),("def",456)]

（[^@..）返回索引遍历的列表及其索引。

要检查“查询”是一个空对象，可以使用nullOf：

emptyQuery = nullOf (key "query" . _Object . each) v

这是一个可行的示例（我将json文件保存到“ json.json”：

{-# LANGUAGE OverloadedStrings #-}

import Data.Aeson
import Data.Aeson.Lens
import qualified Data.ByteString.Lazy as LB
import Control.Lens

main :: IO ()
main = do
  contents <- LB.readFile "json.json"
  let Just v = decode contents :: Maybe Value
  let totalRows  = v ^? key "total_rows" . _Integer
      rows       = key "rows" . values
      nonIds     = members . ifiltered (\i _ -> i /= "_id") . _Integer
      vals       = v ^@.. rows . nonIds
      emptyQuery = nullOf (key "query" . members) v
  print totalRows
  print vals
  print emptyQuery

给出输出

Just 2
[("abc",123),("def",456)]
True

---

（（您可以等效地使用traverse或traversed而不是each，它们都遍历Vector；我只是认为each读起来更好。）