如何使用SPARQL查询查找资源的下一个最大值

Question

我无法解决以下问题：“构建一个图表，其中包含每个行星的远点以及下一个关于它与太阳距离的行星的参考。”

这是图表的转储：

:Saturn  
  skos:exactMatch dbr:Saturn;
  rdf:type dbo:Planet;
  v:orbits :Sun;
  v:apoapsis [rdf:value 9.0412; v:uom unit:AU] ;
  v:orbitalPeriod [rdf:value 29.45; v:uom unit:YR ];
  v:radius [rdf:value 60268; v:uom unit:KM] ;
  v:temperature 
    [rdf:value -139; 
      v:uom unit:Deg_C ];  
.

所以在图中是关于solarsystem的一些数据。所有行星（dbo：Planet）都具有v：apoapsis属性和一个告诉太阳距离的值。我已经想出如何找到所有更大的值，但我只想要下一个最大值。结果如下：

:Mars   v:apoapsis    1.666 ;
        v:nextPlanet  :Saturn , :Jupiter , :Uranus .

:Mercury  v:apoapsis  0.467 ;
        v:nextPlanet  :Saturn , :Jupiter , :Uranus , :Mars , :Earth , :Venus .

:Earth  v:apoapsis    1.017 ;
        v:nextPlanet  :Saturn , :Jupiter , :Uranus , :Mars .

:Venus  v:apoapsis    0.728 ;
        v:nextPlanet  :Saturn , :Jupiter , :Uranus , :Mars , :Earth .

:Jupiter  v:apoapsis  5.4588 ;
        v:nextPlanet  :Saturn , :Uranus .

:Saturn  v:apoapsis   9.0412 ;
        v:nextPlanet  :Uranus .

预期结果应如下所示：

:Mars v:apoapsis 1.666 ;
 v:nextPlanet :Jupiter .
:Mercury v:apoapsis 0.467 ;
 v:nextPlanet :Venus .
:Uranus v:apoapsis 20.11 ;
 v:nextPlanet :Neptune .

我是SPARQL的新手，并且想要迭代这些任务的元素。没有必要提供完整的解决方案我只想知道如何解决这个问题，我对一些想法感到高兴。谢谢。

我最突出的查询看起来像这样：

CONSTRUCT{?planet v:apoapsis ?AUdist;
    v:nextPlanet ?nextPlanet .}
WHERE {
  ?planet a dbo:Planet.
  ?planet v:apoapsis ?dist.
          ?dist v:uom unit:AU;
                rdf:value ?AUdist .

  FILTER(?AUdist > ?AUdist2)
  {
    SELECT ?nextPlanet ?AUdist2
        WHERE { 
        ?nextPlanet a dbo:Planet.
        ?nextPlanet v:apoapsis ?dist2.
          ?dist2 v:uom unit:AU;
            rdf:value ?AUdist2 .
        }   
  ORDER BY ASC(?AUdist2) 
  }
   {
  }
}ORDER BY ASC(?AUdist)

Answer 1

想法是在子查询中获取最小距离值，然后在外部查询中获取相应的行星：

CONSTRUCT {
    ?planet v:apoapsis ?dist;
    v:nextPlanet ?nextPlanet .
} WHERE {

    ?planet v:apoapsis ?dist ;
            v:nextPlanet ?nextPlanet .
    ?nextPlanet v:apoapsis ?nextDist
    BIND(abs(?dist - ?nextDist) as ?diff)
    FILTER(?diff = ?minDiff)

  # get planet and the minimum distance to its next planet 
  {
   SELECT ?planet (min(?diff) as ?minDiff) {
    ?planet v:apoapsis ?dist ;
            v:nextPlanet/v:apoapsis ?nextDist
    BIND(abs(?dist - ?nextDist) as ?diff)
  } GROUP BY ?planet
  }
}

请注意，此处的查询从您的中间结果开始。你没有分享整个数据，因此，我必须测试我从你那里得到的东西。

Answer 2

这种查询的一般方法是：

1. 获取value1和value2的所有组合
2. 仅保留value1小于value2的那些组合
3. 使用GROUP BY和MIN查找给定值1的最小值2

您已经完成了第1步和第2步。要稍微重写一下您的查询：

SELECT * {
    ?planet v:apoapsis/rdf:value ?dist.
    ?otherPlanet v:apoapsis/rdf:value ?otherDist.
    FILTER (?dist < ?otherDist)
}

现在在第3步中，我们想要通过?planet进行分组，并找到每组中最小的?otherDist：

SELECT ?planet (MIN(?otherDist) AS ?nextDist) {
    ?planet v:apoapsis/rdf:value ?dist.
    ?otherPlanet v:apoapsis/rdf:value ?otherDist.
    FILTER (?dist < ?otherDist)
}
GROUP BY ?planet

那是困难的部分。剩下的就是将上面的查询转换为CONSTRUCT查询中的子查询，该查询找到对应于?nextPlanet的?nextDist并构造目标图。