如何在 vba 中将双引号放入字符串中？

Question

我想通过包含双引号的 vba 在单元格中插入一个 if 语句。

这是我的代码：

Worksheets("Sheet1").Range("A1").Value = "=IF(Sheet1!B1=0,"",Sheet1!B1)"

由于双引号，我在插入字符串时遇到问题。我如何处理双引号？

Answer 1

我发现最简单的方法是加倍报价来处理报价。

Worksheets("Sheet1").Range("A1").Formula = "IF(Sheet1!A1=0,"""",Sheet1!A1)" 

有些人喜欢用 CHR(34)*:

Worksheets("Sheet1").Range("A1").Formula = "IF(Sheet1!A1=0," & CHR(34) & CHR(34) & ",Sheet1!A1)" 

*注意：CHAR() 用作 Excel 单元格公式，例如在单元格中写入“=CHAR(34)”，但对于 VBA 代码，您使用 CHR() 函数。

Answer 2

另一个解决方法是构造一个带有临时替换字符的字符串。然后您可以使用 REPLACE 将每个临时字符更改为双引号。我使用代字号作为临时替代字符。

这是我一直在做的一个项目的例子。这是一个小的实用例程，用于修复一个非常复杂的公式，如果/当细胞被意外踩到时。进入单元格是一个困难的公式，但这个小实用程序会立即修复它。

Sub RepairFormula()
Dim FormulaString As String

FormulaString = "=MID(CELL(~filename~,$A$1),FIND(~[~,CELL(~filename~,$A$1))+1,FIND(~]~, CELL(~filename~,$A$1))-FIND(~[~,CELL(~filename~,$A$1))-1)"
FormulaString = Replace(FormulaString, Chr(126), Chr(34)) 'this replaces every instance of the tilde with a double quote.
Range("WorkbookFileName").Formula = FormulaString

这实际上只是一个简单的编程技巧，但它使在 VBA 代码中输入公式变得非常容易。

Answer 3

双引号内的所有双引号都必须更改为双引号。例如，我有一个 json 文件字符串：“交付”：“标准”， 在 Vba 编辑器中，我将其更改为 """delivery"": ""Standard""," 一切正常。如果你必须插入很多相似的字符串，我的建议是先将它们全部插入 "" 之间，然后用 VBA 编辑器将 " inside 替换为 ""。如果你犯错了，VBA 编辑器会将这一行显示为红色，你会更正这个错误。

Answer 4

我写了一个小例程，将公式从单元格复制到剪贴板，可以轻松粘贴到 Visual Basic 编辑器中。

    Public Sub CopyExcelFormulaInVBAFormat()
        Dim strFormula As String
        Dim objDataObj As Object

        '\Check that single cell is selected!
       If Selection.Cells.Count > 1 Then
            MsgBox "Select single cell only!", vbCritical
            Exit Sub
        End If

        'Check if we are not on a blank cell!
       If Len(ActiveCell.Formula) = 0 Then
            MsgBox "No Formula To Copy!", vbCritical
            Exit Sub
        End If

        'Add quotes as required in VBE
       strFormula = Chr(34) & Replace(ActiveCell.Formula, Chr(34), Chr(34) & Chr(34)) & Chr(34)

        'This is ClsID of MSFORMS Data Object
       Set objDataObj = CreateObject("New:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}")
        objDataObj.SetText strFormula, 1
        objDataObj.PutInClipboard
        MsgBox "VBA Format formula copied to Clipboard!", vbInformation

        Set objDataObj = Nothing

    End Sub

它最初发布在 Chandoo.org 论坛的 Vault 部分。

Answer 5

万一gicalle的评论死了：

我更喜欢创建一个全局变量：

Public Const vbDoubleQuote As String = """" 'represents 1 double quote (")
Public Const vbSingleQuote As String = "'" 'represents 1 single quote (') 

像这样使用它：

Shell "explorer.exe " & vbDoubleQuote & sPath & vbDoubleQuote, vbNormalFocus