在 Perl 中，如何限制小数点后的位数，但没有尾数为零？

Question

这个问题类似于 "从浮点数中删除尾部的'.0'"但对于Perl来说，小数点后的数字数量是最多的。

我正在寻找一种将数字转换为字符串格式的方法，去掉任何多余的'0'，包括小数点后的数字。 并且仍然有一个最大的数字数量，例如3。

输入的数据是浮点数。希望输出。

0         -> 0
0.1       -> 0.1
0.11      -> 0.11
0.111     -> 0.111
0.1111111 -> 0.111

Answer 1

你也可以使用 Math::round 来做这件事。

$ perl -MMath::Round=nearest -e 'print nearest(.001, 0.1), "\n"'
0.1
$ perl -MMath::Round=nearest -e 'print nearest(.001, 0.11111), "\n"'
0.111

Answer 2

直接使用下面的程序

my $s = sprintf('%.3f', $f);
$s =~ s/\.?0*$//;

print $s

...或者定义一个子程序来做更多的事情:

sub fstr {
  my ($value,$precision) = @_;
  $precision ||= 3;
  my $s = sprintf("%.${precision}f", $value);
  $s =~ s/\.?0*$//;
  $s
}

print fstr(0) . "\n";
print fstr(1) . "\n";
print fstr(1.1) . "\n";
print fstr(1.12) . "\n";
print fstr(1.123) . "\n";
print fstr(1.12345) . "\n";
print fstr(1.12345, 2) . "\n";
print fstr(1.12345, 10) . "\n";

Prints:

0
1
1.1
1.12
1.123
1.123
1.12
1.12345

Answer 3

你可以使用 sprintf 结合 eval.

my $num = eval sprintf('%.3f', $raw_num);

例如：

#!/usr/bin/perl 

my @num_array = (
    0, 1, 1.0, 0.1, 0.10, 0.11, 0.111, 0.1110, 0.1111111
);


for my $raw_num (@num_array) {
    my $num = eval sprintf('%.3f', $raw_num);
    print $num . "\n";
}

outputs:

0
1
1
0.1
0.1
0.11
0.111
0.111
0.111

Answer 4

这将给你提供你想要的输出。

sub dropTraillingZeros{
$_ = shift;
s/(\d*\.\d{3})(.*)/$1/;
s/(\d*\.\d)(00)/$1/;
s/(\d*\.\d{2})(0)/$1/;
print "$_\n";
}
dropTraillingZeros(0);
dropTraillingZeros(0.1);
dropTraillingZeros(0.11);
dropTraillingZeros(0.111);
dropTraillingZeros(0.11111111);