ASP Classic应用程序中的Multipart / form-data和UTF-8

问题描述 投票：6回答：3

我有一个我真的不明白的问题。我试图在asp经典应用程序中上传文件，而不使用外部组件。我还想发布一些将存储在DB中的文本。文件上传完美，我正在使用此代码：Upload Files Without COM v3 by Lewis E. Moten III

问题是其他形式的输入字段。我使用的是UTF-8，但它们最终并不是UTF-8。如果我使用Response.Write将它们打印出来，则瑞典字符åä和ö显示为问号。

我已经将文件保存为UTF-8（带有BOM），我已经添加了元标记来告诉页面它是UTF-8。我设置了Response.CharSet =“UTF-8”。

从二进制转换为字符串的函数看起来像这样（这是我唯一能想到的可能是错误的地方，因为注释说它会拉出ANSI字符，但我认为它应该拉出Unicode字符）：

Private Function CStrU(ByRef pstrANSI)

    ' Converts an ANSI string to Unicode
    ' Best used for small strings

    Dim llngLength ' Length of ANSI string
    Dim llngIndex ' Current position

    ' determine length
    llngLength = LenB(pstrANSI)

    ' Loop through each character
    For llngIndex = 1 To llngLength

        ' Pull out ANSI character
        ' Get Ascii value of ANSI character
        ' Get Unicode Character from Ascii
        ' Append character to results
        CStrU = CStrU & Chr(AscB(MidB(pstrANSI, llngIndex, 1)))

    Next

End Function

我已经创建了一个测试asp页面（multiparttest.asp）来复制它，来自Lewis E. Moten的上传内容需要使它工作（我已经在一个名为upload的子目录中添加了他的文件）。

<%Response.CharSet = "UTF-8" %>
<!--#INCLUDE FILE="upload/clsUpload.asp"-->
<html>
    <head>
        <title>Test</title>
        <meta http-equiv="Content-Type" content="text/html; charset=UTF-8" />
    </head>
    <body>
        <%
        Set objUpload = New clsUpload
        Response.Write( objUpload.Fields("testInput").Value )
        %>
        <form method="post" enctype="multipart/form-data" action="multiparttest.asp">
            <input type="text" name="testInput" />
            <input type="submit" value="submit" />
        </form>

    </body>
</html>

我在Firefox中使用LiveHTTP Headers捕获了请求，并将其保存为UTF-8文件，瑞典字符看起来应该是这样（他们在LiveHTTP头GUI中看起来不行，但我猜它是GUI它self不使用正确的编码）。这是POST请求的样子：

http://localhost/testsite/multiparttest.asp

POST /testsite/multiparttest.asp HTTP/1.1
Host: localhost
User-Agent: Mozilla/5.0 (Windows; U; Windows NT 6.0; en-US; rv:1.9.1.5) Gecko/20091102 Firefox/3.5.5 (.NET CLR 3.5.30729)
Accept: text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8
Accept-Language: en-us,en;q=0.5
Accept-Encoding: gzip,deflate
Accept-Charset: ISO-8859-1,utf-8;q=0.7,*;q=0.7
Keep-Alive: 300
Connection: keep-alive
Referer: http://localhost/testsite/multiparttest.asp
Cookie: ASPSESSIONIDASBBRBTT=GLDJDBJALAMJFBFBDCCIONHF; ASPSESSIONIDAQABQBTT=DIPHILKAIICKJOIAIMILAMGE; ASPSESSIONIDCSABTCQS=KMHBLBLABKHCBGPNLMCIPPNJ
Content-Type: multipart/form-data; boundary=---------------------------7391102023625
Content-Length: 150
-----------------------------7391102023625
Content-Disposition: form-data; name="testInput"

åäö
-----------------------------7391102023625--

HTTP/1.x 200 OK
Cache-Control: private
Content-Length: 548
Content-Type: text/html; Charset=UTF-8
Server: Microsoft-IIS/7.0
X-Powered-By: ASP.NET
Date: Tue, 10 Nov 2009 14:20:17 GMT
----------------------------------------------------------

对此事的任何帮助表示赞赏！

EDIT 10/11:

我试图将所有这些添加到asp文件的顶部，因为我在其他地方发现了这个问题的不同建议，没有不同的结果..

<%@Language=VBScript codepage=65001 %>
<%Response.ContentType="text/html"%>
<%Response.Charset="UTF-8"%>
<%Session.CodePage=65001%>

EDIT 11/11:

这个问题似乎有关，UTF-8 text is garbled when form is posted as multipart/form-data。但他们不使用ASP或IIS。是否可以在IIS中为multipart / form-data设置某种字符编码？我正在使用IIS7。也许我的请求确实有错误的编码？ （我现在真的迷失在角色编码世界）

iis-7 asp-classic character-encoding html-form multipartform-data
3个回答
5
投票

您对CStrU的分析是正确的。它假定客户端发送单字节ANSI字符。它还假定运行VBScript的客户端和语言环境使用的代码页是相同的。

当使用UTF-8时，CStrU做出的假设总是不正确的。据我所知，还没有一个65001作为其代码页的语言环境（我认为有一两个使用65000但又有所不同）。

这是一个替换函数，假设文本是UTF-8： - 

 Private Function CStrU(ByRef pstrANSI)

  Dim llngLength '' # Length of ANSI string
  Dim llngIndex '' # Current position
  Dim bytVal
  Dim intChar

  '' # determine length
  llngLength = LenB(pstrANSI)

  '' # Loop through each character
  llngIndex = 1
  Do While llngIndex <= llngLength

   bytVal = AscB(MidB(pstrANSI, llngIndex, 1))
   llngIndex = llngIndex + 1

   If bytVal < &h80 Then
    intChar = bytVal
   ElseIf bytVal < &hE0 Then

    intChar = (bytVal And &h1F) * &h40

    bytVal =  AscB(MidB(pstrANSI, llngIndex, 1))
    llngIndex = llngIndex + 1

    intChar = intChar + (bytVal And &h3f)

   ElseIf bytVal < &hF0 Then

    intChar = (bytVal And &hF) * &h1000

    bytVal =  AscB(MidB(pstrANSI, llngIndex, 1))
    llngIndex = llngIndex + 1

    intChar = intChar + (bytVal And &h3F) * &h40

    bytVal =  AscB(MidB(pstrANSI, llngIndex, 1))
    llngIndex = llngIndex + 1

    intChar = intChar + (bytVal And &h3F)

   Else
    intChar = &hBF
   End If

   CStrU = CStrU & ChrW(intChar)
  Loop

 End Function

请注意，当CStrU针对UTF-8进行更正时，示例页面的输出现在看起来是错误的。将文件的代码页设置为65001的建议也是必需的。由于您将发送到客户端的CharSet设置为“UTF-8”，因此在编码使用Response.Write编写的文本时，还需要告诉ASP使用UTF-8代码页。

1
投票

我不知道这是否会有任何帮助，但我使用了一些classic ASP代码来使用SWFUpload实用程序（允许批量上传多个文件的Flash插件）。

ASP示例代码包含一些全面的代码，可以对字节/ Unicode解码进行分类，看起来类似于你提到的关于chr的内容（AscB（MidB）...... - 或许看到第二个例子可能会解释你的问题。

1
投票

“回到白天”，我用过ASPUpload。购买比花时间与表格数据打架更便宜。有点像ASP.NET，它使常规字段和上传文件可用于查询，但它确实（IIRC）打破旧的Form对象 - 即，一旦从ASPUpload读取，输入流将被消耗，并尝试使用常规表单输入将失败。

您可以在同一个应用中使用这两种方法 - 在同一页面请求期间不能同时使用这两种方法基本上选择一个或另一个（通常基于传入的MIME）。

最新问题
© www.soinside.com 2019 - 2024. All rights reserved.