如何构造一个完全匹配DataScript中refs向量的查询？

Question

设置考虑以下DataScript数据库的电影和演员，数据从learndatalogtoday.org被盗：以下代码可以在JVM / Clojure REPL或ClojureScript REPL中执行，只要project.clj包含[datascript "0.15.0"]作为依赖项。

(ns user
  (:require [datascript.core :as d]))

(def data 
  [["First Blood" ["Sylvester Stallone" "Brian Dennehy" "Richard Crenna"]]
   ["Terminator 2: Judgment Day" ["Linda Hamilton" "Arnold Schwarzenegger" "Edward Furlong" "Robert Patrick"]]
   ["The Terminator" ["Arnold Schwarzenegger" "Linda Hamilton" "Michael Biehn"]]
   ["Rambo III" ["Richard Crenna" "Sylvester Stallone" "Marc de Jonge"]]
   ["Predator 2" ["Gary Busey" "Danny Glover" "Ruben Blades"]]
   ["Lethal Weapon" ["Gary Busey" "Mel Gibson" "Danny Glover"]]
   ["Lethal Weapon 2" ["Mel Gibson" "Joe Pesci" "Danny Glover"]]
   ["Lethal Weapon 3" ["Joe Pesci" "Danny Glover" "Mel Gibson"]]
   ["Alien" ["Tom Skerritt" "Veronica Cartwright" "Sigourney Weaver"]]
   ["Aliens" ["Carrie Henn" "Sigourney Weaver" "Michael Biehn"]]
   ["Die Hard" ["Alan Rickman" "Bruce Willis" "Alexander Godunov"]]
   ["Rambo: First Blood Part II" ["Richard Crenna" "Sylvester Stallone" "Charles Napier"]]
   ["Commando" ["Arnold Schwarzenegger" "Alyssa Milano" "Rae Dawn Chong"]]
   ["Mad Max 2" ["Bruce Spence" "Mel Gibson" "Michael Preston"]]
   ["Mad Max" ["Joanne Samuel" "Steve Bisley" "Mel Gibson"]]
   ["RoboCop" ["Nancy Allen" "Peter Weller" "Ronny Cox"]]
   ["Braveheart" ["Sophie Marceau" "Mel Gibson"]]
   ["Mad Max Beyond Thunderdome" ["Mel Gibson" "Tina Turner"]]
   ["Predator" ["Carl Weathers" "Elpidia Carrillo" "Arnold Schwarzenegger"]]
   ["Terminator 3: Rise of the Machines" ["Nick Stahl" "Arnold Schwarzenegger" "Claire Danes"]]])

(def conn (d/create-conn {:film/cast {:db/valueType :db.type/ref
                                      :db/cardinality :db.cardinality/many}
                          :film/name {:db/unique :db.unique/identity
                                      :db/cardinality :db.cardinality/one}
                          :actor/name {:db/unique :db.unique/identity
                                       :db/cardinality :db.cardinality/one}}))
(def all-datoms (mapcat (fn [[film actors]]
                          (into [{:film/name film}] 
                                (map #(hash-map :actor/name %) actors)))
                        data))
(def all-relations (mapv (fn [[film actors]]
                           {:db/id [:film/name film]
                            :film/cast (mapv #(vector :actor/name %) actors)}) data))

(d/transact! conn all-datoms)
(d/transact! conn all-relations)

描述简而言之，这个数据库中有两种实体 - 电影和演员（意图是不变的词） - 以及三种数据：

• 电影实体：:film/name（一个独特的字符串）
• 电影实体：:film/cast（多个参考）
• 演员实体：:actor/name（唯一字符串）

问题我想构建一个问题：哪些电影有这些N演员，而这些N演员单独出现，作为唯一的星星，N> = 2？

例如，RoboCop主演南希艾伦，彼得韦勒，罗尼考克斯，但没有任何一部电影只出演前两部分，艾伦和韦勒。因此，我希望以下查询生成空集：

(d/q '[:find ?film-name
       :where
       [?film :film/name ?film-name]
       [?film :film/cast ?actor-1]
       [?film :film/cast ?actor-2]
       [?actor-1 :actor/name "Nancy Allen"]
       [?actor-2 :actor/name "Peter Weller"]]
     @conn)
; => #{["RoboCop"]}

然而，查询是有缺陷的，因为我不知道如何表达任何比赛应该排除任何不是艾伦或韦勒的演员再次，我想找到只有艾伦和韦勒没有任何其他演员合作的电影，所以我想调整上面的查询来生成空集。如何调整此查询以强制执行此要求？

Answer 1

因为DataScript没有否定（截至2016年5月），我不相信在'纯'Datalog中使用一个静态查询是可能的。

我的出发点是：

1. 以编程方式构建查询以添加N个子句，这些子句声明强制转换必须包含N个actor
2. 添加一个谓词函数，给定一个电影，数据库和一组actor ID，使用EAVT索引来查找每个电影是否有一个不在集合中的actor。

这是一个基本的实现

(defn only-those-actors? [db movie actors]
  (->> (datoms db :eavt movie :film/cast) seq
    (every? (fn [[_ _ actor]]
                (contains? actors actor)))
    ))

(defn find-movies-with-exact-cast [db actors-names]
  (let [actors (set (d/q '[:find [?actor ...] :in $ [?name ...] ?only-those-actors :where
                           [?actor :actor/name ?name]]
                      db actors-names))
        query {:find '[[?movie ...]]
               :in '[$ ?actors ?db]
               :where
               (concat
                 (for [actor actors]
                   ['?movie :film/cast actor])
                 [['(only-those-actors? ?db ?movie ?actors)]])}]
    (d/q query db actors db only-those-actors?)))

Answer 2

您可以将谓词乐趣和d/entity一起用于通过实体的:film/cast字段过滤数据。在Datascript不支持否定（不是运算符等）之前，这种方法看起来更直接。

在Datascript (= a (:age (d/entity db e))的测试用例中查看行here

[{:db/id 1 :name "Ivan" :age 10}
 {:db/id 2 :name "Ivan" :age 20}
 {:db/id 3 :name "Oleg" :age 10}
 {:db/id 4 :name "Oleg" :age 20}]

...

(let [pred (fn [db e a]
             (= a (:age (d/entity db e))))]
  (is (= (q/q '[:find ?e
                :in $ ?pred
                :where [?e :age ?a]
                       [(?pred $ ?e 10)]]
              db pred)
         #{[1] [3]})))))

在你的情况下，谓词体可能看起来像这样

(clojure.set/subset? actors (:film/cast (d/entity db e))

关于性能，d/entity调用很快，因为它是按索引查找。