从 GoogleFinance 获取特定日期的汇率

Question

我无法在特定日期停止 googlefinance 功能以使用“该”特定汇率将货币从英镑转换为欧元。

这是我的公式：

=Finance!B4*GOOGLEFINANCE("CURRENCY:GBPEUR","price",date(2017,15,11))

错误如下：

When evaluating GOOGLEFINANCE, the query for the symbol: 'CURRENCY:GBPEUR' returned no data.

我已经看过其他解决方案，但没有一个可用。实际上，我已将 “日期” 和 “价格” 添加到其他解决方案的公式中。就像这样：- 解决方案 1

Answer 1

首先，

date(2017,15,11)

表示一年中第15个月的第11天，因此您需要交换月份和日期。

其次，历史数据查询，比如

=GOOGLEFINANCE("CURRENCY:GBPEUR", "price", date(2017,11,15))

返回包含列和标题的表格。

Date                Close
11/15/2017 23:58:00 1.1163

从你使用这个公式的方式来看，我发现你只是想要汇率。将函数包装在

index(..., 2, 2)

中以获取第二行中的第二个单元格。

=index(GOOGLEFINANCE("CURRENCY:GBPEUR", "price", date(2017,11,15)), 2, 2)

Answer 2

为了确保众所周知，今天的 Google 表格中未使用

运算符，因此避免解析器错误的正确表达式是（在您的情况下）：

=index(GOOGLEFINANCE("CURRENCY:GBPEUR"; "price"; date(2017;11;15)); 2; 2)

Answer 3

在Google表格中，我已经这样做了，使用分号：

=index(googlefinance("currency:USDNOK";"price";G11);2;2)

G11 是我包含日期的单元格。它似乎为我做这项工作。我用 G11 中的今天日期进行了测试，得到了与今天货币汇率的简化版本相同的结果：

=googlefinance("currency:USDNOK")

Answer 4

这是我的这个公式的版本。

其中

B3

应该是有效日期。

=index(GOOGLEFINANCE("CURRENCY:USDCNY", "price", B3), 2, 2)

PS。我不知道为什么，但当我指定 2018 年 12 月 15 日时，公式显示错误。所有其他日期均正确。

Answer 5

您的问题是您试图强制提供不存在的第 15 个月的数据。

DATE

的语法是：

=DATE(YEAR(), MONTH(), DAY())

所以完整的公式应该是：

=Finance!B4*INDEX(GOOGLEFINANCE("CURRENCY:GBPEUR", "price", DATE(2017, 11, 15)), 2, 2)

替代方案是：

=Finance!B4*INDEX(GOOGLEFINANCE("CURRENCY:GBPEUR", "price", "15/11/2014"), 2, 2)

=Finance!B4*INDEX(GOOGLEFINANCE("CURRENCY:GBPEUR", "price", DATEVALUE("15/11/2014")), 2, 2)

=Finance!B4*INDEX(GOOGLEFINANCE("CURRENCY:GBPEUR", "price", A1), 2, 2)

其中 A1 包含有效日期

Answer 6

2018 年 12 月 15 日是星期日 - 因此出现错误。您可以添加 -2 或 +2，因为周六也会弹出该错误。我更喜欢-2

Answer 7

2024

在谷歌表格中，以下内容对我有用。

=GOOGLEFINANCE("CURRENCY:USDTRY")

按日期

=index(GOOGLEFINANCE("CURRENCY:USDTRY"; "price"; date(2023;1;15)); 2; 2)

或带栏的日期

=index(GOOGLEFINANCE("CURRENCY:USDTRY"; "price"; A6); 2; 2)

output:
32,2045
18,7947
29,4768

注意：它不适用于分号,