我如何将第二个书签添加到VBA中相同的是或否按钮上

Question

我已经创建了一个隐藏书签的“是”按钮，如何将第二个书签添加到相同的“是”按钮。我的书签名称是TextToShow。我只想在同一字段中添加另一个书签。

Private Sub CheckBoxNo_Change()
Call ShowHideBookmark
End Sub

Sub ShowHideBookmark()
Dim Sterilisation As Range
Set Sterilisation = ActiveDocument.Bookmarks("TextToShow").Range
If CheckBoxNo.Value = True Then
With Sterilisation.Font
  .Hidden = True
End With
With ActiveWindow.View
  .ShowHiddenText = False
  .ShowAll = False
End With
Else
With Sterilisation.Font
  .Hidden = False
End With
With ActiveWindow.View
  .ShowHiddenText = True
  .ShowAll = True
End With
End If
End Sub

Answer 1

Sub ShowHideBookmark()
    Dim Sterilisation As Range, Sterilisation2 As Range

    Set Sterilisation = ActiveDocument.Bookmarks("TextToShow").Range
    Set Sterilisation2 = ActiveDocument.Bookmarks("TextToShow2").Range

    If CheckBoxNo.value = True Then
        Sterilisation.Font.Hidden = True
        Sterilisation2.Font.Hidden = True
        With ActiveWindow.View
          .ShowHiddenText = False
          .ShowAll = False
        End With
    Else
        Sterilisation.Font.Hidden = False
        Sterilisation2.Font.Hidden = False
        With ActiveWindow.View
          .ShowHiddenText = True
          .ShowAll = True
        End With
    End If
End Sub

Answer 2

假设（按照JK的方法，您第二个加书签的范围名为'TextToShow2'，请尝试：

Private Sub CheckBoxNo_Change()
Application.ScreenUpdating = False
Dim bVal As Boolean: bVal = CheckBoxNo.Value
ActiveDocument.Bookmarks("TextToShow").Range.Font.Hidden = bVal
ActiveDocument.Bookmarks("TextToShow2").Range.Font.Hidden = bVal
ActiveWindow.View.ShowHiddenText = Not bVal
ActiveWindow.View.ShowAll = Not bVal
Application.ScreenUpdating = True
End Sub