更改Excel中的日期格式

Question

我有一个 Excel 数据集，其日期格式如下： 20150102（年/日/月），

我想将其更改为格式 (dd/mm/yyyy) 我该怎么做？

Answer 1

这里有一些其他替代方法，您可能会发现有用，

• 单元格中使用的公式

B2

=--TEXT(A2,"0000\/00\/00")

• 单元格中使用的公式

B3

=TEXT(A2,"0000\-00\-00")*1

• 单元格中使用的公式

B4

=TEXT(A2,"0000\-00\-00")+0

• 单元格中使用的公式

B5

=TEXT(A2,"0000\-00\-00")/1

• 单元格中使用的公式

B6

=--TEXT(A2,"0000\-00\-00")

• 单元格中使用的公式

B7

=DATEVALUE(TEXT(A2,"0000-00-00"))

• 单元格中使用的公式

B8

=TEXT(CONCAT(MID(A2,{1,2,3,4,5,6,7,8},1)),"0000\/00\/00")+0

• 单元格中使用的公式

B9

=TEXT(CONCAT(MID(A2,{1,5,7},{4,2,2})),"0000\/00\/00")+0

• 单元格中使用的公式

B10

=TEXTJOIN("/",,MID(A2,{1,5,7},{4,2,2}))+0

• 单元格中使用的公式

B11

=TEXT(TEXT(A2,"0000\/00\/00")+0,"dd/mm/yyyy")+0

• 单元格中使用的公式

B12

=TEXT(A2,"0000-00-00")+0

注意：由于应用公式后日期在 Excel 中存储为数字，如果单元格未事先格式化为 Excel 日期，它将显示为数字。因此，如果未格式化，请选择单元格或范围，然后按

CTRL+1

-->

Format cells

对话框打开 -->

Number Tab

-->

Category

-->

Custom

--> 并通过删除

 进行键入General

为

dd/mm/yyyy

Answer 2

如果

20150102

存储为文本或数字，则尝试以下公式将其转换为日期值。然后使用正确的单元格格式。

=DATE(LEFT(A1,4),MID(A1,5,2),DAY(RIGHT(A1,2)))

或使用

TEXT()

函数直接获取所需的格式。尝试-

=TEXT(DATE(LEFT(A1,4),MID(A1,5,2),DAY(RIGHT(A1,2))),"dd/mm/yyyy")