是否有一些已经为 ORG (emacs) 编码的东西可以帮助创建艾森豪威尔矩阵?
我知道可以在议程中创建 4 个不同的文件,或者进行一些工作,但可以使用 ORG 的议程将它们分成 4 个象限,如上图所示?
我想出了这个自定义议程命令,它将优先级为 A 的任何事情视为“重要”,并将截止日期在未来两天内的任何事情视为“紧急”:
(add-to-list 'org-agenda-custom-commands
'("e" "Eisenhower matrix"
((tags-todo
"+PRIORITY=\"A\"+DEADLINE<=\"<+2d>\""
((org-agenda-overriding-header "Urgent (within 2 days) and important")))
(tags-todo
"+PRIORITY=\"A\"+DEADLINE>\"<+2d>\"|+PRIORITY=\"A\"-DEADLINE={.}"
((org-agenda-overriding-header "Important but not urgent")))
(tags-todo
"-PRIORITY=\"A\"+DEADLINE<=\"<+2d>\""
((org-agenda-overriding-header "Urgent (within 2 days) but not important")))
(tags-todo
"-PRIORITY=\"A\"+DEADLINE>\"<+2d>\"|-PRIORITY=\"A\"-DEADLINE={.}"
((org-agenda-overriding-header "Neither important nor urgent"))))
nil))
使用以下组织模式文件:
* TODO [#A] This is important and urgent
DEADLINE: <2021-03-11 Thu>
* TODO [#A] This is important but not urgent
DEADLINE: <2021-03-13 Sat>
* TODO This has no priority but is urgent
DEADLINE: <2021-03-11 Thu>
* TODO [#B] This has medium priority but is urgent
DEADLINE: <2021-03-11 Thu>
* TODO [#C] This has low priority but is urgent
DEADLINE: <2021-03-11 Thu>
* TODO [#A] This is important but has no deadline
* TODO This has no priority and is not urgent
DEADLINE: <2021-03-13 Sat>
* TODO [#B] This has medium priority and is not urgent
DEADLINE: <2021-03-13 Sat>
* TODO [#C] This has low priority and is not urgent
DEADLINE: <2021-03-13 Sat>
* TODO This has no priority and no deadline
* TODO [#B] This has medium priority and no deadline
* TODO [#C] This has low priority and no deadline
看起来像这样:
Urgent (within 2 days) and important
test: TODO [#A] This is important and urgent
======================================================================================================================
Important but not urgent
test: TODO [#A] This is important but not urgent
test: TODO [#A] This is important but has no deadline
======================================================================================================================
Urgent (within 2 days) but not important
test: TODO This has no priority but is urgent
test: TODO [#B] This has medium priority but is urgent
test: TODO [#C] This has low priority but is urgent
======================================================================================================================
Neither important nor urgent
test: TODO This has no priority and is not urgent
test: TODO [#B] This has medium priority and is not urgent
test: TODO This has no priority and no deadline
test: TODO [#B] This has medium priority and no deadline
test: TODO [#C] This has low priority and is not urgent
test: TODO [#C] This has low priority and no deadline
只是为了提供一种仅根据优先级来组织任务的替代方法...我喜欢这个,因为让我决定何时更改任务类别(不是使用截止日期自动更改):
;About the 2 elisp lines below: If you want to send items without explicit
;priorities to the bottom of the list you have to set org-default-priority to the
;value of org-lowest-priority). I did this to make recognize that: PRIORITY=0 are
;items without explicit priorities (not A, B or C, but just TODO)
(setq org-lowest-priority ?E)
(setq org-default-priority ?E)
(add-to-list 'org-agenda-custom-commands
'("e" "Eisenhower matrix"
((tags-todo
"+PRIORITY=\"A\""
((org-agenda-overriding-header "Urgent and important")))
(tags-todo
"+PRIORITY=\"B\""
((org-agenda-overriding-header "Important but not urgent")))
(tags-todo
"+PRIORITY=\"C\""
((org-agenda-overriding-header "Urgent but not important")))
(tags-todo
"+PRIORITY=0-PRIORITY=\"A\"-PRIORITY=\"B\"-PRIORITY=\"C\""
((org-agenda-overriding-header "Neither important nor urgent"))))
nil))
使用以下组织模式文件:
* TODO [#A] This is important and urgent
DEADLINE: <2021-03-11 Thu>
* TODO [#A] This is important but not urgent
DEADLINE: <2021-03-13 Sat>
* TODO This has no priority but is urgent
DEADLINE: <2021-03-11 Thu>
* TODO [#B] This has medium priority but is urgent
DEADLINE: <2021-03-11 Thu>
* TODO [#C] This has low priority but is urgent
DEADLINE: <2021-03-11 Thu>
* TODO [#A] This is important but has no deadline
* TODO This has no priority and is not urgent
DEADLINE: <2021-03-13 Sat>
* TODO [#B] This has medium priority and is not urgent
DEADLINE: <2021-03-13 Sat>
* TODO [#C] This has low priority and is not urgent
DEADLINE: <2021-03-13 Sat>
* TODO This has no priority and no deadline
* TODO [#B] This has medium priority and no deadline
* TODO [#C] This has low priority and no deadline
看起来像这样:
Urgent and important
refile: TODO [#A] This is important and not urgent: ver como adicionar os aniversários no ORG
refile: TODO [#A] This is important and urgent
refile: TODO [#A] This is important but not urgent
refile: TODO [#A] This is important but has no deadline
=============================================================================================================================
Important but not urgent
refile: TODO [#B] This has medium priority but is urgent
refile: TODO [#B] This has medium priority and is not urgent
refile: TODO [#B] This has medium priority and no deadline
=============================================================================================================================
Urgent but not important
refile: TODO [#C] This has low priority but is urgent
refile: TODO [#C] This has low priority and is not urgent
refile: TODO [#C] This has low priority and no deadline
=============================================================================================================================
Neither important nor urgent
refile: TODO This has no priority but is urgent
refile: TODO This has no priority and is not urgent
refile: TODO This has no priority and no deadline
我喜欢卢卡斯的回答,但我更喜欢议程项目的内联优先级比 A、B、C 和 D 更明确,我认为 A、B、C 和 D 太抽象了。我希望他们是:
因此,将卢卡斯的答案合并到 Org Fancy Priorities 包的设置中,该包允许使用字符串来表示优先级。我设置了以下内容:
(use-package org-fancy-priorities
:ensure t
:hook
(org-mode . org-fancy-priorities-mode)
:config
(setq org-fancy-priorities-list
'((?A . "important✅ urgent✅")
(?B . "important✅ urgent❌")
(?C . "important❌ urgent✅")
(?D . "important❌ urgent❌")))
(setq org-priority-highest ?A
org-priority-lowest ?D
org-priority-default ?D)
(add-to-list 'org-agenda-custom-commands
'("e" "Eisenhower matrix"
((tags-todo
"+PRIORITY=\"A\""
((org-agenda-overriding-header "IMPORTANT AND URGENT")))
(tags-todo
"+PRIORITY=\"B\""
((org-agenda-overriding-header "IMPORTANT BUT NOT URGENT")))
(tags-todo
"+PRIORITY=\"C\""
((org-agenda-overriding-header "NOT IMPORTANT BUT URGENT")))
(tags-todo
"+PRIORITY=\"D\""
((org-agenda-overriding-header "NEITHER IMPORTANT NOR URGENT"))))
nil)))
现在除了可以选择艾森豪威尔矩阵之外,我的常规议程也是这样的……
todos: 17:00-18:30 TODO important✅ urgent✅ German course
todos: TODO important✅ urgent❌ Do Elisp exercises