在DOCTYPE XSLT 2.0 Saxon9he中插入ENTITY声明

Question

我的任务是将XML文档分解为单独的工作包。我唯一遇到麻烦的部分是在DOCTYPE中插入图形实体声明，如下所示：

<!DOCTYPE frntcover PUBLIC "-//USA-DOD//DTD TM Assembly REV C" "production.dtd" [
<!ENTITY IMAGE001.jpg SYSTEM "IMAGE001.jpg" NDATA jpg>
]>

（（不要在实体名称中使用扩展名，在这里就是这样做的方式。）无论如何，实体将由在主XML文件中找到的所有@boardno构造而成，这些XML文件可能位于<figure>或<graphic>即<graphic boardno="IMAGE001.jpg"/>

我一直在使用<xsl:result-document>写出doctype，但我不知道如何在其中获取实体。

[我尝试了LexEv，但是得到了net.sf.saxon.trans.XPathException: Failed to instantiate class com.andrewjwelch.lexev.LexEv (does it have a public zero-argument constructor?)，我联系了Andrew，他说，无论如何，不​​再支持LexEv而不是我不需要的工具，因为LexEv用于保存实体，而不是用于将其写入文件。

Answer 1

Saxon确实具有用于将DTD添加到输出文档的扩展名saxon:doctype：请参阅http://www.saxonica.com/documentation/index.html#!extensions/instructions/doctype

但是需要Saxon-PE或更高。

唯一的选择是“手动”构造它，并使用disable-output-escapeing将其输出。或者使用“纯文本”转换工具（例如Perl或awk）进行一些后处理。

Answer 2

[就像凯博士建议的那样，您可以使用DOE（禁用输出转义）来手工创建它。

这里与我过去使用的类似。我通常要做的是使用Python创建实体声明，然后将它们作为参数传递给样式表。

我使用xsl：key，所以不会得到重复的声明。

此外，您可能可以重构表示法数据的确定方式；特别是如果符号始终与文件扩展名相同。

示例...

XML输入

<frntcover>
    <graphic boardno="IMAGE001.jpg"/>
    <figure boardno="IMAGE001.jpg"/>
    <graphic boardno="IMAGE002.jpg"/>
    <graphic boardno="IMAGE003.jpg"/>
</frntcover>

XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:key name="_gd_gnbrs" match="*[@boardno]" use="@boardno"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="/*">
    <xsl:call-template name="generate_doctype">
      <xsl:with-param name="root" select="local-name()"/>
      <xsl:with-param name="pubid" select="'-//USA-DOD//DTD TM Assembly REV C'"/>
      <xsl:with-param name="sysid" select="'production.dtd'"/>
    </xsl:call-template>
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template name="generate_doctype">
    <xsl:param name="root"/>
    <xsl:param name="pubid"/>
    <xsl:param name="sysid"/>
    <xsl:text disable-output-escaping="yes">&#xA;<![CDATA[<!DOCTYPE ]]></xsl:text>
    <xsl:value-of select="$root"/>
    <xsl:choose>
      <xsl:when test="string($pubid)">
        <xsl:value-of select="concat(' PUBLIC &quot;',$pubid,'&quot;')" disable-output-escaping="yes"/>
      </xsl:when>
      <xsl:when test="string($sysid)">
        <xsl:text> SYSTEM</xsl:text>
      </xsl:when>
    </xsl:choose>
    <xsl:if test="string($sysid)">
      <xsl:value-of select="concat(' &quot;',$sysid,'&quot;')" disable-output-escaping="yes"/>
    </xsl:if>
    <xsl:text disable-output-escaping="yes"><![CDATA[ []]>&#xA;</xsl:text>
    <xsl:for-each select="//*[@boardno][count(.|key('_gd_gnbrs',@boardno)[1])=1]">
      <xsl:apply-templates select="." mode="ent_decs"/>
    </xsl:for-each>
    <xsl:text disable-output-escaping="yes"><![CDATA[]>]]>&#xA;</xsl:text>
  </xsl:template>

  <xsl:template match="*" mode="ent_decs">
    <xsl:text disable-output-escaping="yes"><![CDATA[<!ENTITY ]]></xsl:text>
    <xsl:value-of select="concat(@boardno,' SYSTEM &quot;',@boardno)" disable-output-escaping="yes"/>
    <xsl:choose>
      <xsl:when test="matches(@boardno,'\.tif','i')">
        <xsl:text disable-output-escaping="yes"><![CDATA[" NDATA ccitt4>]]>&#xA;</xsl:text>        
      </xsl:when>
      <xsl:when test="matches(@boardno,'\.cgm','i')">
        <xsl:text disable-output-escaping="yes"><![CDATA[" NDATA cgm>]]>&#xA;</xsl:text>
      </xsl:when>
      <xsl:when test="matches(@boardno,'\.jpe?g','i')">
        <xsl:text disable-output-escaping="yes"><![CDATA[" NDATA jpg>]]>&#xA;</xsl:text>
      </xsl:when>
      <xsl:otherwise>
        <xsl:message terminate="yes">UNKNOWN GRAPHIC EXTENSION: "<xsl:value-of select="@boardno"/>"</xsl:message>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

XML输出

<!DOCTYPE frntcover PUBLIC "-//USA-DOD//DTD TM Assembly REV C" "production.dtd" [
<!ENTITY IMAGE001.jpg SYSTEM "IMAGE001.jpg" NDATA jpg>
<!ENTITY IMAGE002.jpg SYSTEM "IMAGE002.jpg" NDATA jpg>
<!ENTITY IMAGE003.jpg SYSTEM "IMAGE003.jpg" NDATA jpg>
]>
<frntcover>
   <graphic boardno="IMAGE001.jpg"/>
   <figure boardno="IMAGE001.jpg"/>
   <graphic boardno="IMAGE002.jpg"/>
   <graphic boardno="IMAGE003.jpg"/>
</frntcover>

小提琴：http://xsltfiddle.liberty-development.net/gVhDDyQ