从一组数字中获取一个数字

Question

要将数字拆分为给定基数中的数字，Julia具有digits()函数：

julia> digits(36, base = 4)
3-element Array{Int64,1}:
 0
 1
 2

反向操作是什么？如果你有一个数字和基数数组，有没有内置的方法将其转换为数字？我可以将数组打印到一个字符串并使用parse()，但这听起来效率低，而且对于大于10的基数也不起作用。

Answer 1

答案似乎直接写在digits的文档中：

help?> digits
search: digits digits! ndigits isdigit isxdigit disable_sigint

  digits([T<:Integer], n::Integer; base::T = 10, pad::Integer = 1)

  Return an array with element type T (default Int) of the digits of n in the given base,
  optionally padded with zeros to a specified size. More significant digits are at higher
  indices, such that n == sum([digits[k]*base^(k-1) for k=1:length(digits)]).

所以对于你的情况，这将工作：

julia> d = digits(36, base = 4);

julia> sum([d[k]*4^(k-1) for k=1:length(d)])
36

以上代码可以用点运算符缩短：

julia> sum(d.*4 .^(0:(length(d)-1)))
36

Answer 2

以前的答案是正确的，但也有效率的问题：

sum([x[k]*base^(k-1) for k=1:length(x)])

在求和之前将数字收集到数组中，这会导致不必要的分配。跳过括号以获得更好的性能：

sum(x[k]*base^(k-1) for k in 1:length(x))

这也是在求和之前分配一个数组：sum(d.*4 .^(0:(length(d)-1)))

但是，如果你真的想要良好的性能，写一个循环并避免重复取幂：

function undigit(d; base=10)
    s = zero(eltype(d))
    mult = one(eltype(d))
    for val in d
        s += val * mult
        mult *= base
    end
    return s
end

这有一个额外的不必要的乘法，你可以尝试找出一些跳过它的方法。但是在我的测试中，性能比其他方法好10-15倍，并且分配为零。

编辑：上面的类型处理实际上存在轻微风险。如果输入向量和base具有不同的整数类型，则可以获得类型不稳定性。此代码应该表现得更好：

function undigits(d; base=10)
    (s, b) = promote(zero(eltype(d)), base)
    mult = one(s)
    for val in d
        s += val * mult
        mult *= b
    end
    return s
end