如何增加一条线之间的间距？

Question

当使用标准笔（PS_DOT）并用它绘制一条线时，结果如下图所示（放大）

对于我来说，这条线有两个问题，第一个是，它为一个点设置了多个像素。第二个是，点太靠近了我想要做的事情（绘制一条非常柔和的线条。）

我可以使用SetPixel，但性能留下了很大的欲望。

我的问题是：是否有一种相当快速的方法来绘制一条线，可以控制用于绘制点的像素数和点之间的间距？

从本质上讲，比使用SetPixel更快的方法（可以用来解决问题的方法不是那么慢。）

一段代码显示了如何在C，C ++或Delphi中完成它会很棒。

谢谢您的帮助。

编辑：我尝试了IInspectable使用ExtCreatePen的答案，它非常接近。似乎获取像素/点而不是破折号的唯一方法是使用PS_ALTERNATE但是，当使用它时，无法指定间距。

作为参考，如果我犯了一个错误，我没有看到，下面是我写的测试程序。我想要的是一个1点（不是破折号）的重复序列，后跟2个空格。我从测试程序得到的输出如下所示（放大）:(顶行使用PS_ALTERNATE获得，底线使用指定1点的数组，2个空格 - 给出2个点和2个空格。）

测试程序：

{$APPTYPE        GUI}

{$LONGSTRINGS    OFF}
{$WRITEABLECONST ON}

program _ExtCreatePen;

uses Windows, Messages;

const
  AppName  = 'ExtCreatePen';

{$ifdef VER90} { Delphi 2.0 }
type
  ptrint  = longint;        // NativeInt  for newer versions
  ptruint = dword;          // NativeUint  "    "      "
{$endif}

{-----------------------------------------------------------------------------}

function WndProc (Wnd : HWND; Msg : UINT; wParam, lParam : ptrint)
         : ptrint; stdcall;
const
  PenPattern   : packed array[1..4] of DWORD = (1, 2, 1, 2); { 1 dot, 2 spaces}

  PenBrush     : TLOGBRUSH = (lbStyle:BS_SOLID; lbColor:0; lbHatch:0);
  PenWidth     : DWORD     = 1;

  { !! this doesn't seem to work as expected, expected 1 dot, 2 spaces !!     }

  PenStyle     : DWORD     = PS_COSMETIC or PS_USERSTYLE;
  StyleCount   : DWORD     = high(PenPattern);
  StylePattern : PDWORD    = @PenPattern[low(PenPattern)];

  { this gives 1 dot, 1 space.                                                }

  //PenStyle     : DWORD     = PS_COSMETIC or PS_ALTERNATE;
  //StyleCount   : DWORD     = 0;
  //StylePattern : PDWORD    = nil;

  Pen          : HPEN      = 0;

var
  ps          : TPAINTSTRUCT;
  ClientRect  : TRECT;

begin
  WndProc := 0;

  case Msg of
    WM_CREATE:
    begin
      PenBrush.lbColor := RGB(255, 0, 0);

      Pen := ExtCreatePen(PenStyle,
                          PenWidth,
                          PenBrush,
                          StyleCount,
                          StylePattern);
      exit;
    end;

    WM_PAINT:
    begin
      BeginPaint(Wnd, ps);
        GetClientRect(Wnd, ClientRect);

        SelectObject(ps.hdc, Pen);  { use the pen we created    }

        MoveToEx(ps.hdc, 0, ClientRect.Bottom div 2, nil);
        LineTo(ps.hdc, ClientRect.Right, ClientRect.Bottom div 2);
      EndPaint(Wnd, ps);

      exit;
    end;

    WM_CLOSE: PostMessage(Wnd, WM_DESTROY, 0, 0);

    WM_DESTROY:
       begin
         if Pen <> 0 then DeleteObject(Pen);

         PostQuitMessage(0);

         exit;
       end; { WM_DESTROY }
  end; { case msg }

  WndProc := DefWindowProc (Wnd, Msg, wParam, lParam);
end;

{-----------------------------------------------------------------------------}

function InitAppClass: WordBool;
  { registers the application's window classes                                }
var
  cls : TWndClassEx;

begin
  cls.cbSize          := sizeof(TWndClassEx);           { must be initialized }

  if not GetClassInfoEx (hInstance, AppName, cls) then
  begin
    with cls do
    begin
      { cbSize has already been initialized as required above                 }

      style           := CS_BYTEALIGNCLIENT;
      lpfnWndProc     := @WndProc;                    { window class handler  }
      cbClsExtra      := 0;
      cbWndExtra      := 0;
      hInstance       := system.hInstance;
      hIcon           := LoadIcon (hInstance, IDI_APPLICATION);
      hCursor         := LoadCursor(0, IDC_ARROW);
      hbrBackground   := COLOR_WINDOW + 1;
      lpszMenuName    := nil;
      lpszClassName   := AppName;                     { Window Class name     }
      hIconSm         := 0;
    end; { with }

    InitAppClass := WordBool(RegisterClassEx(cls));
  end
  else InitAppClass := TRUE;
end;

{-----------------------------------------------------------------------------}

function WinMain : integer;
  { application entry point                                                   }
var
  Wnd : hWnd;
  Msg : TMsg;

begin
  if not InitAppClass then Halt (255);  { register application's class        }

  { Create the main application window                                        }

  Wnd := CreateWindowEx(WS_EX_CLIENTEDGE,
                        AppName,                { class name                  }
                        AppName,                { window caption text         }
                        ws_Overlapped       or  { window style                }
                        ws_SysMenu          or
                        ws_MinimizeBox      or
                        ws_ClipSiblings     or
                        ws_ClipChildren     or  { don't affect children       }
                        ws_visible,             { make showwindow unnecessary }
                        20,                     { x pos on screen             }
                        20,                     { y pos on screen             }
                        400,                    { window width                }
                        200,                    { window height               }
                        0,                      { parent window handle        }
                        0,                      { menu handle 0 = use class   }
                        hInstance,              { instance handle             }
                        nil);                   { parameter sent to WM_CREATE }

  if Wnd = 0 then Halt;                         { could not create the window }

  while GetMessage (Msg, 0, 0, 0) do            { wait for message            }
  begin
    TranslateMessage (Msg);                     { key conversions             }
    DispatchMessage  (Msg);                     { send to window procedure    }
  end;

  WinMain := Msg.wParam;                        { terminate with return code  }
end;

begin
  WinMain;
end.

Answer 1

您的代码没有任何问题。正如您所描述的那样，我花了一点时间来实现GDI自定义虚线。

在GDI中，自定义虚线以短划线绘制，如MSDN中所述。

如果dwPenStyle是PS_COSMETIC和PS_USERSTYLE，则lpStyle数组中的条目以样式单位指定短划线和空格的长度。样式单元由设备定义，其中笔用于绘制线条。

如果dwPenStyle是PS_GEOMETRIC和PS_USERSTYLE，则lpStyle数组中的条目以逻辑单位指定破折号和空格的长度。

这个功能可以在GDI +中实现，正如@Michael Chourdakis在开头所提到的那样

Answer 2

如果您需要控制一行中的破折号和空格的长度，请调用ExtCreatePen函数以创建一个PS_USERSTYLE笔。这允许您指定最多16个条目的数组，每个条目指定短划线或间隙的长度。