^ Pchar的指针到PChar的数组

Question

当我从Delphi 6迁移到Delphi 10.2东京时，我试图将^ PChar的指针转换为PChar数组时出错

type
  PServEnt = ^TServEnt;
  TServEnt = packed record
    s_name: PChar;                 // official service name
    s_aliases: ^PChar;             // alias list
    s_port: Smallint;              // protocol to use
    s_proto: PChar;                // port #
  end;

function TIdStackWindows.WSGetServByPort(
  const APortNumber: Integer): TIdStrings;
var
  ps: PServEnt;
  i: integer;
  p: array of PChar;
begin
  Result := TIdStringList.Create;
  p := nil;
  try
    ps := GetServByPort(HToNs(APortNumber), nil);
    if ps <> nil then
    begin
      Result.Add(ps^.s_name);
      i := 0;
      p := Pointer(ps^.s_aliases); // get error Incompatible types: 'Dynamic array' and 'Pointer' 
      while p[i] <> nil do
      begin
        Result.Add(PChar(p[i]));
        inc(i);
      end;
    end;
  except
    Result.Free;
  end;
end;

这段代码在Delphi 2010上运行良好，如何在Delphi 10.2 Tokyo上正确使用它

Answer 1

错误消息是正确的，如果在早期版本的Delphi中编译的代码，那是因为那些早期版本的编译器不足。

动态数组不仅仅是指向第一个元素的指针。它还封装了存储数组长度和引用计数的元数据。因此，您的演员表无效。你没有使用这个无效的代码，因为你没有尝试访问这个元数据，但这是偶然的意图。

不要尝试强制转换为动态数组。而是使用指针算法。例如：

function TIdStackWindows.WSGetServByPort(
  const APortNumber: Integer): TIdStrings;
var
  ps: PServEnt;
  p: PPChar;
begin
  Result := TIdStringList.Create;
  try
    ps := GetServByPort(HToNs(APortNumber), nil);
    if ps <> nil then
    begin
      Result.Add(ps^.s_name);
      p := PPChar(ps^.s_aliases); // cast needed due to Indy record type's use of un-nameable type
      while p^ <> nil do
      begin
        Result.Add(p^);
        inc(p);
      end;
    end;
  except
    Result.Free;
    raise;
  end;
end;

我将别名列表的类型声明更改为PPChar，以避免在分配给该类型的局部变量时出现不兼容的类型错误。

另请注意，我已更正了以前吞噬异常并返回无效对象引用的异常处理。