我如何访问汇编中的每个单词？

Question

给出：

.data
arr: .word 2,5,1,3,4
len: .word 5
sum: .word 0

我将如何访问“ arr”中的每个单词，例如2、3和4？

最终，我想做的是在“ arr”中找到所有值的总和，但是我很难遍历“ arr”。

谢谢您的时间！

附加信息：

1. 我正在使用eduMIPS64

Answer 1

首先将数组的地址加载到寄存器中，然后可以使用恒定偏移量访问这些项。 （为此，您的汇编程序可能支持lw $t0, arr+12之类的构造作为方便快捷方式。请参见您的手册。）要进行迭代，请增加地址寄存器或添加另一个包含偏移量的寄存器。请务必考虑商品尺寸。跟踪示例适用于32位mips，对于64位可根据需要进行调整：

.data
arr: .word 2,5,1,3,4
len: .word 5
sum: .word 0

.text
.globl main
main:
    la $t0, arr
    lw $t1, 12($t0)     # load arr[3] using byte offset
    li $t1, 3           # index
    sll $t1, $t1, 2     # multiply by item size
    addu $t1, $t1, $t0  # add base address
    lw $t1, ($t1)       # load arr[3]

# iteration type 1
# for(i=len, ptr=arr; i != 0; i -= 1, ptr += 1)
# ... use *ptr ...
    la $t0, arr
    lw $t1, len         # load length
loop1:
    lw $t2, ($t0)       # load item
    # process item here
    addi $t0, $t0, 4    # add item size to pointer
    addi $t1, $t1, -1   # decrement counter
    bne $t1, $0, loop1  # if counter != 0, repeat

# iteration type 2
# for(i=0, i != len; i += 1)
# ... use arr[i] ...
    la $t0, arr
    lw $t1, len         # load length
    li $t2, 0           # index
loop2:
    sll $t3, $t2, 2     # multiply by item size
    addu $t3, $t3, $t0  # add base address
    lw $t3, ($t3)       # load item
    # process item here
    addi $t2, $t2, 1    # increment index
    bne $t2, $t1, loop2 # if index != len, repeat

（（请注意，这些示例循环不处理零长度数组，如有必要，请添加检查）