我一直试图在装配中绘制一个盒子并在屏幕上水平移动它。打印广场本身的代码对我来说很有用,但是当我试图让它移动它时效果不佳。如果你明白我的话,我可以看到它在移动但不是一个完整的正方形。
我的代码:在Assembly Tasm中
STA SEGMENT STACK
DB 0FFFeH DUP(?)
STA ENDS
DATA SEGMENT
;-----------
;VARIABLES HERE
xpos dw 50h
ypos dw 50h
color db 9h
constat equ 0ffffh
siNum dw ?
diNum dw ?
numOFtime dw 0h
;-------------
DATA ENDS
CODE SEGMENT
ASSUME CS:CODE,DS:DATA,SS:STA
START :
MOV AX,DATA
MOV DS,AX
;start coding here:
mov ah, 0 ;Set display mode
mov al, 13h ;13h = 320x200, 256 colors
int 10H ;Video BIOS Services
mov cx,50h
mov dx,50h
mov si,25H
mov di,25H
PrintSquare:
;------------------------------------------------------------------------
;cx = xpos , dx = ypos, si = x-length, di = y-length, al = color
didi:
mov color,9h
mov bp,0h
do:
add cx,si
here:
mov bh,0h
mov al,color
mov ah, 0Ch ;write pixel at coordinate
int 10h ;draw pixel!
dec cx
cmp cx,xpos
ja here
inc dx
inc bp
cmp bp,25h
jbe do
call drawBlackBox
inc numOFtime
inc xpos;incrising to make the sqaure moving horizontically
mov cx,xpos;cx gets the xposition
mov dx,ypos
cmp numOFtime,constat
jb didi
mov ah,004Ch ;terminate program
int 21h
;
drawBlackBox proc
mov color,0h ;black color
mov bp,0h
mov cx,xpos
mov dx,ypos
do1:
add cx,si
here1:
mov bh,0h
mov al,color
mov ah, 0Ch ;write pixel at coordinate
int 10h ;draw pixel!
dec cx
cmp cx,xpos
ja here1
inc dx
inc bp
cmp bp,25h
jbe do1
mov cx,xpos
ret
drawBlackBox endp
CODE ENDS
END START
如果,由于移动不好,你的意思是边缘似乎在不同的时间移动,这是一个问题(撕裂)通常通过双缓冲解决。问题是由于您正在渲染到活动(可见)曲面,因此屏幕可能会显示半修改的帧。
插图可能会有所帮助。假设您正尝试从左侧图像更改为右侧:
~ ~ ^ ^
O O O O
^ ----> ^
|---| \___/
如果图像从左向右更新,并且数据在更新过程中途发送到屏幕,您将看到如下内容:
^ ~
O O
^
\_--|
这就是所谓的撕裂。
要解决这个问题,你可以在一个单独的内存块中构建下一帧(你可以使用rep stosb
在最短的时间内构建下一帧),然后使用rep movsb
或者同样快速的东西将它传输到视频内存。这会稍微降低你的帧速率,但应该减轻你可能看到的任何撕裂。
这是一个显示此操作的示例。它与你的功能类似,但使用双缓冲来解决撕裂问题,而且在执行特定操作的功能方面,它的结构也更好(我认为无论如何):
stacksg segment stack
db 0fffeh dup(?)
stacksg ends
datasg segment
buffer dw 32000 dup(0)
datasg ends
codesg segment
assume cs:codesg, es: datasg, ds:datasg, ss:stacksg
doline: ; ax = line, bx = column, cx = width
push di ; preserve
push ax
push dx ; imul hits this
push bx ; get byte offset to di
mov bx, 320
imul bx
pop bx
add ax, bx
mov di, ax
push cx ; blat line
mov al, 9
cld
rep stosb
pop cx
pop dx ; restore and return
pop ax
pop di
ret
dosquare: ; ax = line, bx = column, cx = width, dx = height
push ax ; preserve
push bx
push cx
push dx
push di ; clear buffer to black
push ax
push cx
xor di, di
xor ax, ax
mov cx, 32000
cld
rep stosw
pop cx
pop ax
pop di
makeline:
call doline
inc ax
dec dx
jnz makeline
push es ; blat double buffer to screen
push si
push di
xor si, si
mov ax, 0a000h
mov es, ax
xor di, di
mov cx, 32000
cld
rep movsw
pop di
pop si
pop es
pop dx ; restore and return
pop cx
pop bx
pop ax
ret
start:
mov ax, datasg
mov ds, ax
mov es, ax
mov ah, 0 ; set display mode 13h, 320x200, 8bbp
mov al, 13h
int 10h
mov ax, 10 ; line
mov bx, 10 ; start column
mov cx, 40 ; width
mov dx, 40 ; height
printSquare:
call dosquare ; do the square
inc bx ; move right but reset at end
cmp bx, 310 - 40
jne printSquare
mov bx, 10
jmp printSquare
codesg ends
end start
将其插入GNU Turbo Assembler并检查出来。我运行了你的原始(撕裂)代码和这个变体,后者是更平滑的动画。