gnuplot：交互式3D动画？

Question

使用gnuplot，您可以使用splot创建类似3D的绘图，并以交互方式更改视图。

您还可以使用带有set terminal gif animate的gnuplot创建动画。

### interactive animation?
reset session
set view equal
set border 0
unset tics

$Data <<EOD
1   1.000   0.000   0.000
2   0.500   0.866   0.000
3   -0.500  0.866   0.000
4   -1.000  0.000   0.000
5   -0.500  -0.866  0.000
6   0.500   -0.866  0.000
1   1.000   0.000   0.000
EOD

$Off <<EOD
1   0.00    0.00    0.1
2   0.00    0.00    -0.1
3   0.00    0.00    0.1
4   0.00    0.00    -0.1
5   0.00    0.00    0.1
6   0.00    0.00    -0.1
1   0.00    0.00    0.1
EOD

set xrange[-2:2]
set yrange[-2:2]
set zrange[-2:2]
set view 45,45
max=10.
Offset(n,axis,i) = real(word($Off[n+1],axis+1))*sin(2*pi*i/max)

set term gif animate delay 5 size 400,300
set output "Molecule.gif"

do for [i=0:max] {
    splot $Data u ($2+Offset($0,1,i)):($3+Offset($0,2,i)):($4+Offset($0,3,i)) \
    w lp pt 7 ps 2 lw 2 lc rgb "red" not
    unset autoscale
}

set term wxt size 400,300
set margin 0
splot $Data u 2:3:4 w lp pt 7 ps 2 lw 2 lc rgb "red" not
set output
### end of code

现在，我的问题是：是否有机会创建交互式动画？我希望在动画制作时旋转视图。这对gnuplot来说有点可能吗？有任何想法吗？

编辑：

@ Ethan的回答解决了这个问题。但是，是否有办法避免鼠标光标的闪烁？

Answer 1

将绘图命令放在循环中不会禁用鼠标交互。简单的答案应该有效：

set xrange[-2:2]
set yrange[-2:2]
set zrange[-2:2]
set view 45,45
Offset(n,axis,i) = real(word($Off[n+1],axis+1))*sin(2*pi*i/max)

# Loop forever
# but allow an explicit end condition triggered by a hot key
done = 0
bind "d" "done = 1"

while (!done) {
  do for [i=0:10] {
    splot $Data u ($2+Offset($0,1,i)):($3+Offset($0,2,i)):($4+Offset($0,3,i)) \
    w lp pt 7 ps 2 lw 2 lc rgb "red" not
    pause 0.1
  }
}