子例程的名称可以是Fortran中的变量吗？ [重复]

Question

此问题已经在这里有了答案：

How to alias a function name in Fortran（2个答案）

关闭4年前。

我想知道Fortran中是否有类似的东西。当然，此示例不会编译，但我认为您可以理解。

program test
    character(1):: sub

    sub='A'
    call sub

    sub='B'
    call sub
end program

subroutine A
    print*,'OK! A'
end subroutine A

subroutine B
    print*,'OK! B'
end subroutine B

Answer 1

您无法通过设置字符变量来完成此操作，但是可以使用过程指针来完成此操作。我已经稍微修改了您的示例以实现这一点。参见：

program test
 implicit none

 abstract interface
    subroutine no_args
    end subroutine
 end interface

 procedure(no_args), pointer :: sub => null()

 sub => A
 call sub

 sub => B
 call sub

contains

subroutine A
 implicit none
 print *,"OK! A"
end subroutine

subroutine B
 implicit none
 print *,"OK! B"
end subroutine

end program

更改是：

• 为过程指针定义接口
• 将sub声明为该抽象接口的过程指针

然后您可以将sub分配给不带参数的子例程（因为这是接口所说的，然后按照您的设想通过sub进行调用。

Answer 2

您可以获得的最接近的是函数/过程指针，但这将是fortran-2003。通常，在给定输入“ A”或“ B”的情况下，将指针设置为指向subroutine A或subroutine B。 How to alias a function name in Fortran上的更多详细信息>