通过查找.BAT中使用的端口来终止进程

问题描述 投票：118回答：15

在Windows中，什么可以查找端口8080并尝试通过.BAT文件终止它正在使用的进程？

windows batch-file process kill-process
15个回答
135
投票

这是一个让你入门的命令：

FOR /F "tokens=4 delims= " %%P IN ('netstat -a -n -o ^| findstr :8080') DO @ECHO TaskKill.exe /PID %%P

如果您对批处理文件有信心，请删除@ECHO。

FOR /F "tokens=4 delims= " %%P IN ('netstat -a -n -o ^| findstr :8080') DO TaskKill.exe /PID %%P

请注意，对于不同的操作系统，您可能需要稍微更改一下。例如，在Windows 7上，您可能需要tokens=5而不是tokens=4。

这是如何工作的

FOR /F ... %variable IN ('command') DO otherCommand %variable...

这使您可以执行command，并循环其输出。每一行都将塞进%variable，无论你喜欢什么，都可以随意扩展到otherCommand。实际使用中的%variable只能有一个单字母的名称，例如%V。

"tokens=4 delims= "

这允许你按空格分割每一行，并获取该行中的第4个块，并将其填充到%variable（在我们的例子中，%%P）。 delims看起来很空，但这个额外的空间实际上很重要。

netstat -a -n -o

只需运行它就可以找到答案。根据命令行帮助，它“显示所有连接和侦听端口。”，“以数字形式显示地址和端口号。”和“显示与每个连接关联的拥有进程ID”。我只是使用这些选项，因为别人建议它，它碰巧工作:)

^|

这将获取第一个命令或程序（netstat）的输出并将其传递给第二个命令程序（findstr）。如果您直接在命令行上使用它，而不是在命令字符串中，您将使用|而不是^|。

findstr :8080

这会过滤传递给它的任何输出，只返回包含:8080的行。

TaskKill.exe /PID <value>

这会使用进程ID终止正在运行的任务。

%%P instead of %P

这在批处理文件中是必需的。如果您在命令提示符下执行此操作，则应使用%P。

1
投票

使用以下内容创建了一个bat文件，它接受端口号的输入

@ECHO ON
set /p portid=Enter the Port to be killed: 
echo %portid%                                                                              
FOR /F "tokens=5" %%T IN ('netstat -a -n -o ^| findstr %portid% ') DO (
SET /A ProcessId=%%T) &GOTO SkipLine                                                   
:SkipLine                                                                              
echo ProcessId to kill = %ProcessId%
taskkill /f /pid %ProcessId%
PAUSE

最后点击“Enter”退出。

0
投票

与Merlyn的回应类似，但这个也处理了这些情况：

  • 端口号实际上是您不想要的另一个较长端口号的左子串。您想要搜索确切的端口号，这样您就不会杀死随机，无辜的进程！
  • 脚本代码需要能够运行多次并且每次都是正确的，而不是显示较旧的错误答案。

这里是：

set serverPid=
for /F "tokens=5 delims= " %%P in ('netstat -a -n -o ^| findstr /E :8080 ') do set serverPid=%%P
if not "%serverPid%" == "" (
  taskkill /PID %serverPid%
) else (
  rem echo Server is not running.
)
0
投票

脚步：

  1. 转到apache tomcat服务器的conf文件夹。在我的情况下，它的apache-tomcat-7.0.61\conf因为我使用apache-tomcat-7.0.61
  2. 打开server.xml并根据需要将端口号从8080更改为任何其他端口。例如：8081,8082,8087等
  3. 现在去bin文件夹并运行shutdown.bat
  4. 现在通过eclipse重启服务器。

现在您的项目可以正常运行而不会中断。

0
投票

如果有人在寻找Powershell脚本：

function Search-And-Destroy
{
    param ( [Parameter(Mandatory=$true)][string]$port )
    $lines = netstat -a -o -n | findstr $port
    $ports = @()

    ForEach($line In $lines)
    {
        $res = $($lines -split '\s+')
        $ports += $res[5]
    }

    $ports = $ports | select -uniq

    ForEach($port In $ports)
    {
        echo $(taskkill /F /PID $port)
    }
}

此函数基本上执行上述函数的功能，但它采用Powershell脚本格式，因此您可以将其添加到Powershell配置文件中。要查找您的个人资料的位置，请转到powershell并输入echo $profile

0
投票

将其粘贴到命令行中

FOR /F "tokens=5 delims= " %P IN ('netstat -ano ^| find "LISTENING" ^| find ":8080 "') DO (TASKKILL /PID %P)

如果你想在批量pu %%P而不是%P中使用它

0
投票

如果你是系统你不能结束它的任务。试试这个命令

x：> net stop http / y

192
投票

打开命令提示符并运行以下命令

 C:\Users\username>netstat -o -n -a | findstr 0.0:3000
   TCP    0.0.0.0:3000      0.0.0.0:0              LISTENING       3116

C:\Users\username>taskkill /F /PID 3116

，这里3116是进程ID

51
投票

要在命令行上查找特定进程，请使用以下命令：8080是进程使用的端口

netstat -ano | findstr 8080

杀死进程使用下面命令21424是进程ID

taskkill /pid 21424 /F
19
投票

使用Merlyn的解决方案导致其他应用程序像firefox一样被杀死。这些进程使用相同的端口，但不是作为监听器：

例如：

netstat -a -n -o | findstr :8085
  TCP    0.0.0.0:8085           0.0.0.0:0              LISTENING       6568
  TCP    127.0.0.1:49616        127.0.0.1:8085         TIME_WAIT       0
  TCP    127.0.0.1:49618        127.0.0.1:8085         TIME_WAIT       0

因此，可以通过向findstr添加“LISTENING”来排除这些，如下所示：

FOR /F "tokens=5 delims= " %%P IN ('netstat -a -n -o ^| findstr :8085.*LISTENING') DO TaskKill.exe /PID %%P
16
投票

要列出在端口8080上运行的所有进程，请执行以下操作。

netstat -ano |找到“8080”

TCP    0.0.0.0:8080           0.0.0.0:0              LISTENING       10612

TCP    [::]:8080              [::]:0                 LISTENING       10612

然后杀死进程运行以下命令

taskkill / F / PID 10612

13
投票

谢谢大家，只是添加一些进程不会关闭，除非/ F强制开关也与TaskKill一起发送。同时使用/ T开关，将关闭进程的所有辅助线程。

C:\>FOR /F "tokens=5 delims= " %P IN ('netstat -a -n -o ^|
 findstr :2002') DO TaskKill.exe /PID %P /T /F

对于服务，有必要获取服务的名称并执行：

sc停止ServiceName

3
投票

查看正在监听端口的进程：How can you find out which process is listening on a port on Windows?

杀了它：Any way to write a Windows .bat file to kill processes?

2
投票

刚完成：

我想杀死连接到特定端口但不是进程侦听的所有进程

端口9001的命令（在cmd shell中）是：

FOR /F "tokens=5 delims= " %P IN ('netstat -ano ^| findstr -rc:":9001[ ]*ESTA"') DO TaskKill /F /PID %P

FINDSTR：

  • r表示表达式，c表示精确链匹配。
  • [] *用于匹配空格

netstat的：

  • a - >全部
  • n - >不解决（更快）
  • o - > pid

它的工作原理是因为netstat打印出源端口然后打印出目标端口然后打开ESTABLISHED

1
投票

如果要杀死正在侦听端口8080的进程，可以使用PowerShell。只需将Get-NetTCPConnection cmdlet与Stop-Process结合使用。

经过测试，应该可以在Windows 10或Windows Server 2016上使用PowerShell 5.但是，我想它应该也适用于安装了PowerShell 5的旧版Windows。

这是一个例子：

PS C:\> Stop-Process -Id (Get-NetTCPConnection -LocalPort 8080).OwningProcess

Confirm
Are you sure you want to perform the Stop-Process operation on the following item: MyTestServer(9408)?
[Y] Yes  [A] Yes to All  [N] No  [L] No to All  [S] Suspend  [?] Help (default is "Y"):
最新问题
© www.soinside.com 2019 - 2024. All rights reserved.