使用元组进行IENUMERABLE的C＃到VB转换

Question

我希望我能正确地说出这个问题，原谅我对如果没有准确措辞的缺乏了解，如果你有一个如何更好地提出问题的建议请告诉我，我会改写它。

我正在遵循微软关于新的Microsoft.ML包的指南：https://docs.microsoft.com/en-us/dotnet/machine-learning/tutorials/sentiment-analysis

该指南是基于C＃构建的，我正在尝试转换为VB.NET。本指南的完整C＃代码位于：https://github.com/dotnet/samples/blob/master/machine-learning/tutorials/SentimentAnalysis/Program.cs

除了几行之外，我已经转换了所有内容，而我只是缺乏如何完成此转换的知识：

第220行：

IEnumerable<(SentimentData sentiment, SentimentPrediction prediction)> sentimentsAndPredictions = sentiments.Zip(predictedResults, (sentiment, prediction) => (sentiment, prediction));

接下来是＃224到＃228行：

foreach ((SentimentData sentiment, SentimentPrediction prediction) item in sentimentsAndPredictions)
            {
                Console.WriteLine($"Sentiment: {item.sentiment.SentimentText} | Prediction: {(Convert.ToBoolean(item.prediction.Prediction) ? "Positive" : "Negative")} | Probability: {item.prediction.Probability} ");

            }

我之前从未使用过这个，有没有人知道如何转换这段代码？

作为最后的手段，我还在converter.telerik.com上尝试了Telerik的转换工具，并收到以下错误：

''' Cannot convert ForEachStatementSyntax, CONVERSION ERROR: Conversion for TupleType not implemented, please report this issue in '(SentimentData sentiment, S...'

Answer 1

我终于能够弄明白，而不是最好的转换，但它的工作原理。如果有人对完整代码感兴趣，请参阅下文。

    Dim sentimentsAndPredictions = sentiments.Zip(predictedResults, Function(sentiment As SentimentData, prediction As SentimentPrediction) (sentiment, prediction))

    For Each item In sentimentsAndPredictions
        Dim result = item.ToTuple
        Console.WriteLine("Sentiment: " & result.Item1.SentimentText & " | Prediction: " & If(Convert.ToBoolean(result.Item2.Prediction), "Positive", "Negative"))
    Next

请注意，在上面的代码中，我不得不通过

Function(sentiment As SentimentData, prediction As SentimentPrediction) (sentiment, prediction)

进入Zip函数，然后在For语句中使用.ToTuple函数将项目转换为元组。

完整代码：

Imports System
Imports System.Collections.Generic
Imports System.IO
Imports System.Linq
Imports Microsoft.Data.DataView
Imports Microsoft.ML
Imports Microsoft.ML.Data
Imports Microsoft.ML.Trainers
Imports Microsoft.ML.Transforms.Text

Module Module1

    Public _dataPath As String = Path.Combine(Environment.CurrentDirectory, "Data", "yelp_labelled.txt")
    Public _modelPath As String = Path.Combine(Environment.CurrentDirectory, "Data", "Model.zip")

    Sub Main()

        Dim mlcontext As MLContext = New MLContext()
        Dim splitDataView As TrainCatalogBase.TrainTestData = LoadData(mlcontext)
        Dim model As ITransformer = BuildAndTrainModel(mlcontext, splitDataView.TrainSet)
        Evaluate(mlcontext, model, splitDataView.TestSet)
        UseModelWithSingleItem(mlcontext, model)

        UseLoadedModelWithBatchItems(mlcontext)

        Console.WriteLine()
        Console.WriteLine("=============== End of process ===============")

        Console.ReadLine()

    End Sub

    Public Function LoadData(ByVal mlContext As MLContext) As TrainCatalogBase.TrainTestData
        Dim dataView As IDataView = mlContext.Data.LoadFromTextFile(Of SentimentData)(_dataPath, hasHeader:=False)
        Dim splitDataView As TrainCatalogBase.TrainTestData = mlContext.BinaryClassification.TrainTestSplit(dataView, testFraction:=0.2)
        Return splitDataView
    End Function

    Public Function BuildAndTrainModel(ByVal mlContext As MLContext, ByVal splitTrainSet As IDataView) As ITransformer
        Dim pipeline = mlContext.Transforms.Text.FeaturizeText(outputColumnName:=DefaultColumnNames.Features, inputColumnName:=NameOf(SentimentData.SentimentText)).Append(mlContext.BinaryClassification.Trainers.FastTree(numLeaves:=50, numTrees:=50, minDatapointsInLeaves:=20))
        Console.WriteLine("=============== Create and Train the Model ===============")
        Dim model = pipeline.Fit(splitTrainSet)
        Console.WriteLine("=============== End of training ===============")
        Console.WriteLine()
        Return model
    End Function

    Public Sub Evaluate(ByVal mlContext As MLContext, ByVal model As ITransformer, ByVal splitTestSet As IDataView)
        Console.WriteLine("=============== Evaluating Model accuracy with Test data===============")
        Dim predictions As IDataView = model.Transform(splitTestSet)
        Dim metrics As CalibratedBinaryClassificationMetrics = mlContext.BinaryClassification.Evaluate(predictions, "Label")
        Console.WriteLine()
        Console.WriteLine("Model quality metrics evaluation")
        Console.WriteLine("--------------------------------")
        Console.WriteLine($"Accuracy: {metrics.Accuracy}")
        Console.WriteLine($"Auc: {metrics.Auc}")
        Console.WriteLine($"F1Score: {metrics.F1Score}")
        Console.WriteLine("=============== End of model evaluation ===============")
        SaveModelAsFile(mlContext, model)
    End Sub

    Private Sub UseModelWithSingleItem(ByVal mlContext As MLContext, ByVal model As ITransformer)
        Dim predictionFunction As PredictionEngine(Of SentimentData, SentimentPrediction) = model.CreatePredictionEngine(Of SentimentData, SentimentPrediction)(mlContext)
        Dim sampleStatement As SentimentData = New SentimentData With {
            .SentimentText = "This was a very bad steak"
        }
        Dim resultprediction = predictionFunction.Predict(sampleStatement)
        Console.WriteLine()
        Console.WriteLine("=============== Prediction Test of model with a single sample and test dataset ===============")
        Console.WriteLine()
        Console.WriteLine($"Sentiment: {sampleStatement.SentimentText} | Prediction: {(If(Convert.ToBoolean(resultprediction.Prediction), "Positive", "Negative"))} | Probability: {resultprediction.Probability} ")
        Console.WriteLine("=============== End of Predictions ===============")
        Console.WriteLine()
    End Sub

    Public Sub UseLoadedModelWithBatchItems(ByVal mlContext As MLContext)
        Dim sentiments As IEnumerable(Of SentimentData) = {New SentimentData With {
            .SentimentText = "This was a horrible meal"
        }, New SentimentData With {
            .SentimentText = "I love this spaghetti."
        }}

        Dim loadedModel As ITransformer
        Using s1 As IO.FileStream = New FileStream(_modelPath, FileMode.Open, FileAccess.Read, FileShare.Read)
            loadedModel = mlContext.Model.Load(s1)
        End Using

        Dim sentimentStreamingDataView As IDataView = mlContext.Data.LoadFromEnumerable(sentiments)
        Dim predictions As IDataView = loadedModel.Transform(sentimentStreamingDataView)
        Dim predictedResults As IEnumerable(Of SentimentPrediction) = mlContext.Data.CreateEnumerable(Of SentimentPrediction)(predictions, reuseRowObject:=False)
        Console.WriteLine()

        Console.WriteLine("=============== Prediction Test of loaded model with a multiple samples ===============")

        Console.WriteLine()

        Dim sentimentsAndPredictions = sentiments.Zip(predictedResults, Function(sentiment As SentimentData, prediction As SentimentPrediction) (sentiment, prediction))

        For Each item In sentimentsAndPredictions
            Dim result = item.ToTuple
            Console.WriteLine("Sentiment: " & result.Item1.SentimentText & " | Prediction: " & If(Convert.ToBoolean(result.Item2.Prediction), "Positive", "Negative"))
        Next

    End Sub

    Private Sub SaveModelAsFile(ByVal mlContext As MLContext, ByVal model As ITransformer)
        Using fs = New FileStream(_modelPath, FileMode.Create, FileAccess.Write, FileShare.Write)
            mlContext.Model.Save(model, fs)
        End Using

        Console.WriteLine("The model is saved to {0}", _modelPath)
    End Sub

End Module