VBScript看门狗[关闭]

Question

我正在尝试创建一个脚本，它将查看本地计算机上的特定.txt文件，获取它的DateLastModified属性，并将其与上次检查时的上一个/上一个值进行比较（在一个循环中，每1-2秒一次） ）。

循环（每秒运行一次）会增加一个计数器，如果计数器达到一个限制（比如说10秒），一段代码就会执行“杀死/终止”特定进程/ .exe的任务，这可能会挂起，然后重新启动它。

我发现一些非常好的.vbs在线样本使用订阅事件，我不认为这是我想要/需要去的路线，因为脚本实际上需要连续运行而不是仅在特定文件时异步被修改了。

编辑：我正在寻找一个提供“看门狗”功能的VBScript，通过监视.txt文件进行修改。脚本应该每秒运行一个循环来检查修改，如果没有修改，则增加一个计数器。一旦计数器达到限制（10秒？），它将终止一个固定进程（硬编码为VBScript中的参数），然后重新启动进程（作为VBScript中参数的进程路径）。

到目前为止，我还没有找到一个很好的例子。我一直在玩其他使用objWMIService.ExecNotificationQuery(Query)的例子，这似乎很酷，因为使用了很少的开销（本质上是异步的） - 它似乎不符合我的需要，如上所述。

如果我必须分享我发现的并且一直在玩弄...好......这里是：

intInterval = "1"
strDrive = "C:"
strFolder = "\\Project\\"
strComputer = "."
intTmrVal = 0

Set objWMIService = GetObject( "winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2" )

strQuery = "Select * From __InstanceOperationEvent" _
    & " Within " & intInterval _
    & " Where Targetinstance Isa 'CIM_DataFile'" _
    & " And TargetInstance.Name='C:\\Project\\test.txt'"

Set colEvents = objWMIService.ExecNotificationQuery(strQuery)

Do
    Set objEvent = colEvents.NextEvent()
    Set objTargetInst = objEvent.TargetInstance

    Select Case objEvent.Path_.Class
        Case "__InstanceCreationEvent"
            WScript.Echo "Created: " & objTargetInst.Name
        Case "__InstanceDeletionEvent"
            WScript.Echo "Deleted: " & objTargetInst.Name
        Case "__InstanceModificationEvent"
            Set objPrevInst = objEvent.PreviousInstance

            For Each objProperty In objTargetInst.Properties_
                If objProperty.Value <> objPrevInst.Properties_(objProperty.Name) Then
                    WScript.Echo "Changed:        " & objTargetInst.Name
                    WScript.Echo "Property:       " & objProperty.Name
                    WScript.Echo "Previous value: " & objPrevInst.Properties_(objProperty.Name)
                    WScript.Echo "New value:      " & objProperty.Value
                End If
            Next
    End Select

    'Count how many times it has been modified // just playing with a counter
    If objEvent.TargetInstance.LastModified <> objEvent.PreviousInstance.LastModified Then
        intTmrVal = intTmrVal+1
        WScript.Echo "Changed:        " & intTmrVal & " times"
        WScript.Echo
    End If
Loop

Answer 1

一种简单的方法是直接在WMI请求中为下一个事件设置超时

Option Explicit

Const MONITOR_FILE = "c:\temp\test.txt"
Const MONITOR_LIMIT = 10

Dim wmi
    Set wmi  = GetObject( "winmgmts:" & "{impersonationLevel=impersonate}!\\.\root\cimv2" )

Dim query
    query = "SELECT * FROM __InstanceOperationEvent WITHIN 1 " _ 
            & " WHERE TargetInstance ISA 'CIM_DataFile' " _ 
            & " AND   TargetInstance.Name='" & Replace(MONITOR_FILE, "\", "\\") & "'"

Dim colEvents
    Set colEvents = wmi.ExecNotificationQuery( query )

Dim currentEvent
    Do
        ' Flag value 
        Set currentEvent = Nothing
        ' Try to get the next event with a timeout limit
        ' If a timeout happens we need to catch raised error
        On Error Resume Next 
        Set currentEvent = colEvents.NextEvent( MONITOR_LIMIT * 1000 )
        On Error GoTo 0
        ' If there is not an event there was a timeout
        If currentEvent Is Nothing Then 
            Exit Do
        End If 
    Loop 

    WScript.Echo "File has not been changed for " & MONITOR_LIMIT & " seconds."

Answer 2

事件观察者在事件发生时对事件作出反应。但是，您希望对未发生的事件（即未修改的文件）做出反应。出于显而易见的原因，您无法使用事件监视器。

您需要的是检查文件上次修改日期的代码

path = "C:\Project\test.txt"

Set fso = CreateObject("Scripting.FileSystemObject")
ts = fso.GetFile(path).DateLastModified

然后，如果该时间戳大于x秒/分钟，则终止给定进程

pname = "foo.exe"

wmi = GetObject("winmgmts://./root/cimv2")
qry = "SELECT * FROM Win32_Process WHERE Name='" & pname & "'"
If DateDiff("s", ts, Now) > 10 Then
    For Each p In wmi.ExecQuery(qry)
        p.Terminate
    Next
End If

但是，Windows任务计划程序不支持每秒（或每2秒）运行任务所需的粒度。即使它确实如此，每秒产生一个新进程对于系统性能起初并不是很好。您可以设置每日计划，然后指示任务计划程序在一天的持续时间内每5分钟重新运行一次任务。您需要在脚本中考虑的其余部分。

定义5分钟超时并在循环中重新运行检查，直到超时到期：

interval = 2 'seconds
timeout  = 5 'minutes

endtime   = DateAdd("n", timeout, Now)
sleeptime = interval * 1000 'milliseconds
Do
    'check and process handling go here
    WScript.Sleep sleeptime
Loop Until Now >= endtime

由于fso和wmi可以重复使用，因此不要通过在循环内反复重新定义它们来浪费资源。在脚本开头只定义一次。