如何计算包含多个值的单元格中的值？

Question

我有一个表格，其中包含以逗号分隔的多个值的单元格，如下所示：

+----------+
| Column A |
|----------|
| a, b     |
|----------|
| a, b, d  |
|----------|
| b, c     |
|----------|
| c, d, e  |
+----------+

我想得到一张表，其中计算a，b，...，e的数量如下：

 +-----------------------+
 | Column A  | Column B  |
 |-----------------------|
 |     a     |     2     |
 |-----------------------|
 |     b     |     3     |
 |-----------------------|
 |     c     |     2     |
 |-----------------------|
 |     d     |     2     |
 |-----------------------|
 |     e     |     1     |
 +-----------------------+

是否有Google表格或LibreOffice Calc电子表格公式来执行此操作？

Answer 1

• C1：=UNIQUE(TRANSPOSE(SPLIT(TEXTJOIN(" ,",1,A:A)," ,")))
• D1：=ARRAYFORMULA(IF(LEN(C:C),COUNTIF(A:A,"=*"&C:C&"*"),))

Answer 2

=QUERY(TRANSPOSE(SPLIT(TEXTJOIN(" ,",1,A:A)," ,")),
 "select Col1, count(Col1) 
  where Col1 is not null 
  group by Col1 
  label count(Col1) ''")

Answer 3

={UNIQUE(TRANSPOSE(SPLIT(TEXTJOIN(" ,",1,A:A)," ,"))),
 ARRAYFORMULA(IF(LEN(UNIQUE(TRANSPOSE(SPLIT(TEXTJOIN(" ,",1,A:A)," ,")))),
 COUNTIF(A:A,"=*"&UNIQUE(TRANSPOSE(SPLIT(TEXTJOIN(" ,",1,A:A)," ,")))&"*"),))}