如何让 CMake 自动检测 CUDA_ARCHITECTURES 的值？

Question

较新版本的 CMake（3.18 及更高版本）“了解”CUDA 代码编译目标的 CUDA 架构的选择。目标有一个

CUDA_ARCHITECTURES

属性，设置后会为您生成适当的

-gencode arch=whatever,code=whatever

编译选项。如果您不设置此值，您甚至会收到警告：

CMake Error in CMakeLists.txt:
  CUDA_ARCHITECTURES is empty for target "my_cuda_app".

默认情况下，此目标属性初始化为

CMAKE_CUDA_ARCHITECTURES

。但是

CMAKE_CUDA_ARCHITECTURES

本身没有初始化为任何东西（！）

我们如何让 CMake 自动检测

CUDA_ARCHITECTURES

或全局

CMAKD_CUDA_ARCHITECTURES

的适当值？即使用系统上安装的GPU的架构？

Answer 1

在即将推出的 CMake 3.24 中，您将能够编写：

set_property(TARGET tgt PROPERTY CUDA_ARCHITECTURES native)

这将为配置时系统上可用的 GPU（具体）CUDA 架构构建目标

tgt

。

使用较新版本的 CUDA（11.5 及更高版本），将传递

native

到 nvcc 和其他可执行文件；对于旧版本，它将自动检测哪些架构是“本机”架构。

警告：这实际上并没有为您提供架构列表（例如，在您的 CMake 代码中进行迭代。）

Answer 2

CMake 实际上提供了这种自动检测功能，但是：

1. 它没有记录（并且可能会在将来的某个时候进行重构）。
2. 它是已弃用的 FindCUDA 机制的一部分，旨在直接操作

   CUDA_CMAKE_FLAGS

   （这不是我们想要的）。
3. 它不“表现得很好”，并且对我们隐藏了有用形式的内部变量。

不过，只要付出一点努力，我们就可以让它发挥作用。

首先，它的位置：它位于模块

FindCUDA/select_compute_arch

中（在 Linux 系统上，该模块将位于

/path/to/cmake/root/share/cmake-X.YY/Modules/FindCUDA/select_compute_arch.cmake

）。

现在介绍一下如何使用它：

include(FindCUDA/select_compute_arch)
CUDA_DETECT_INSTALLED_GPUS(INSTALLED_GPU_CCS_1)
string(STRIP "${INSTALLED_GPU_CCS_1}" INSTALLED_GPU_CCS_2)
string(REPLACE " " ";" INSTALLED_GPU_CCS_3 "${INSTALLED_GPU_CCS_2}")
string(REPLACE "." "" CUDA_ARCH_LIST "${INSTALLED_GPU_CCS_3}")
SET(CMAKE_CUDA_ARCHITECTURES ${CUDA_ARCH_LIST})

如果您只想将其用于单个目标，则可以将最后一行替换为：

set_property(TARGET my_target PROPERTY "${CUDA_ARCH_LIST}")

备注：

• 当您的系统上有没有 GPU 时，您可能会得到如下结果：

  3.5;5.0;5.3;6.0;6.1;7.0;7.5;7.5+PTX

  。

  这是一个 CMake 问题，无法解决，因为我们在这里使用的子模块不受官方支持。因此，如果您需要在没有 GPU 的系统上进行编译，请避免此调用或解析“+PTX”条目的结果。

• select_compute_arch

  子模块已经存在了很长时间，但在过去你会以不同的方式使用它，并且会通过

  include(FindCUDA)

  包含它。

• 我想知道

  LIST(APPEND CMAKE_CUDA_ARCHITECTURES

  是否会比

  SET(CMAKE_CUDA_ARCHITECTURES

  更合适。

• 请参阅 CMake 问题 22375 和 19199，了解 CMake 未来可能会用到的地方。警告：我提交了这些错误...

Answer 3

我在使用 CMake 3.13 的系统上使用其他解决方案时遇到问题，不确定它是什么，但我必须使用这个。

可能有更好的方法来做到这一点。

    if(${CMAKE_VERSION} VERSION_LESS_EQUAL "3.13.4")
      cuda_select_nvcc_arch_flags(ARCH_FLAGS "Auto") # optional argument for arch to add
      message("ARCH_FLAGS = ${ARCH_FLAGS}")
      string(REPLACE "-gencode;" "--generate-code=" ARCH_FLAGS "${ARCH_FLAGS}")
      string(APPEND CMAKE_CUDA_FLAGS "${ARCH_FLAGS}")
    else()
      include(FindCUDA/select_compute_arch)
      CUDA_DETECT_INSTALLED_GPUS(INSTALLED_GPU_CCS_1)
      string(STRIP "${INSTALLED_GPU_CCS_1}" INSTALLED_GPU_CCS_2)
      string(REPLACE " " ";" INSTALLED_GPU_CCS_3 "${INSTALLED_GPU_CCS_2}")
      string(REPLACE "." "" CUDA_ARCH_LIST "${INSTALLED_GPU_CCS_3}")
      SET(CMAKE_CUDA_ARCHITECTURES ${CUDA_ARCH_LIST})
      set_property(GLOBAL PROPERTY CUDA_ARCHITECTURES "${CUDA_ARCH_LIST}")
    endif()