如何在x86程序集中编写自己的atoi函数

Question

我在汇编中编写自己的atoi函数时遇到了一些麻烦。说明是

“更改函数，使其返回传递给函数的C字符串（指针）的等效整数。您可以假设第一个字符位于'0'和'9'之间，包括在内。atoish考虑所有字符从第一个字符到第一个不是十进制数字的字符。正如您所看到的，将atoias返回的值维护为退出代码（这只是从atoi访问输出的一种便宜方式，无需编写itoofunction。）As给你，atoireturns 1234.返回值是ANDedwith 0xFF以将其减少到一个字节。因此1234和255变为210.“

    # Useful constants 
    .equ    STDIN,0 
    .equ    STDOUT,1 
    .equ    READ,0 
    .equ    WRITE,1 
    .equ    EXIT,60 
# Stack frame 
    .equ    bufferSize, 32
    .equ    buffer,-bufferSize
    .equ    localSize,16 
    .equ    frameSize, bufferSize + localSize
# Read only data 
    .section    .rodata # the read-only data section 
prompt: 
    .string     "Enter an integer: " 
    .equ    promptSz,.-prompt-1 
msg: 
    .string     "You entered: " 
    .equ    msgSz,.-msg-1 

Code

    .text   # switch to text section 


    .globl  __start 
 __start: 
    pushq   %rbp    # save caller’s frame pointer 
    movq    %rsp, %rbp  # establish our frame pointer 
    subq    $frameSize, %rsp    # for local variables 

    movl    $promptSz, %edx # prompt size 
    movl    $prompt, %esi   # address of prompt text string 
    movl    $STDOUT, %edi   # standard out 
    movl    $WRITE, %eax 
    syscall     # request kernel service 

    movl    $bufferSize,%edx
    leaq    buffer(%rbp), %rsi  # load buffer address
    movl    $STDIN, %edi    # standard in 
    movl    $READ, %eax 
    syscall     # request kernel service 
    movl    %eax, (%rsp)    # store num chars read

    leaq    buffer(%rbp), %rsi  # load buffer address
    call    atoi    # our exit code will be the return from atoi

    movq    %rbp, %rsp  # delete local variables 
    popq    %rbp    # restore caller’s frame pointer 
    movl    %eax, %edi  # put exit status in %edi (will be ANDed with FF)
    movl    $EXIT, %eax # exit from this process 

    syscall

基本代码看起来像这样我只需要实现自己的atoi。到目前为止我所拥有的atoi功能是

atoi:
    pushq   %rbp    # save caller’s frame pointer 
    movq    %rsp, %rbp  # establish our frame pointer 
    subq    $16, %rsp   # for local variables

    movq    %rdi, -16(%rbp) #moving first argument to local variable
    movl    $0, -4(%rbp) #moving 0 to local variable
    movl    $10, -12(%rbp) #moving 10 to local variable

    movl    -16(%rbp), %rax
    movzbl  (%rax), %eax #getting value of rax
    movl    -4(%rbp), %eax

    imull   -12(%rbp), %eax
    movl    %eax,   -4(%rbp)

    movq    %rbp, %rsp  # delete local variables 
    popq    %rbp    # restore caller’s frame pointer 
    ret

我不知道下一步该去哪里。似乎任何我做的只是给我分段错误

Answer 1

你过度使用局部变量（和使用不足的寄存器）;将需要一个在找到无效字符时停止的循环;并且可能使用了错误的调用约定（系统调用看起来像Linux，这意味着System V AMD64 ABI，这意味着参数在寄存器中而不是在堆栈中传递）。

请注意，这可以在没有任何局部变量的情况下完成。例如（NASM语法，因为我不做AT＆T，未经测试）：

;Convert string to integer
;
;Input
; rdi = first parameter (address of string)
;
;Output
; rax = result

atoi:
    xor rax,rax               ;rax = 0 (this will become the returned result)
.nextChar:
    movzx rcx,byte [rdi]      ;rcx = next character
    sub rcx,'0'               ;rcx = value of next digit
    jb .done                  ;Invalid character (too low to be a decimal digit)
    cmp rcx,9                 ;Was it too high to be a decimal digit?
    ja .done                  ; yes, invalid

    lea rax,[rax*4+rax]       ;rax = result*5
    lea rax,[rax*2+rcx]       ;rax = result*5*2 + digit = result*10 + digit
    inc rdi                   ;rdi = address of next character
    jmp .nextChar
.done:
     ret

注意：此代码不适用于负值（例如，以'-'开头的字符串），如果/当结果溢出时，将不会返回错误条件。结果也将是64位（而int可能应该是32位）。大多数情况下，它是“转换为无符号长整型”（错误处理与atoi()一样糟糕）。