gnuplot：如何获得正确的数量级？

Question

这个问题/问题可能与this topic有某种关联。

如果输入：

print log10(1e7)你会得到7.0。

print int(log10(1e7))你会得到7。

但是，如果你输入

print log10(1e6)你会得到6.0。

print int(log10(1e6))你会得到5。

这些可能是与log10相关的舍入错误，不能避免（？）。

因为如果你输入

print sprintf("%.20e",log10(1e6))给5.99999999999999911182e+00

print sprintf("%.20e",log10(1e7))给7.00000000000000000000e+00

您可以将其扩展和总结为一个图：代码：

### power problem in gnuplot
reset session
set colorsequence classic
set key left
set samples 41

set xrange[-20:20]
plot int(log10(10**x)) w lp pt 7,\
    x w lp pt 7
### end of code

结果：

您将看到，在不规则的距离中，预期结果和获得的结果之间存在差异。

所以，我仍然缺少一个能够始终保持正确数量级的函数。也许将所有数字首先舍入到15位小数？还有其他想法吗？

Answer 1

假设您没有处理超过12-15位数（或者说@Ethan说64位系统中超过15-16位数无论如何都是无意义的），以下函数应该给出正确的数量级作为整数。我刚刚测试了几个例子并将其与其他“直截了当”的方法进行了比较。请证明功能是对还是错。

### get the correct power of a number with gnuplot

CorrectPower(n) = floor(log10(n*(1+1e-15)))
IncorrectPower1(n) = floor(log10(n))
IncorrectPower2(n) = floor(gprintf("%T",n))

Numbers = "1e-6 1e-4 0.001 0.01 1e-2 1000 1000000 -1e-6 -1e-9 0.99 95 990"

print " Number    cP  icP1 icP2"
do for [i=1:words(Numbers)] {
    n = word(Numbers,i)
    print \
        sprintf("%7s:%5d%5d%5d", n, CorrectPower(n), IncorrectPower1(n), IncorrectPower2(n))
}
### end of code

结果：

 Number    cP  icP1 icP2
   1e-6:   -6   -5   -6
   1e-4:   -4   -3   -4
  0.001:   -3   -2   -3
   0.01:   -2   -1   -2
   1e-2:   -2   -1   -2
   1000:    3    2    3
1000000:    6    5    6
  -1e-6:   -6   -5   -6
  -1e-9:   -9   -8   -9
   0.99:   -1    0    0
     95:    1    1    2
    990:    2    2    3

增加：为了它的价值，另一个函数将正确的幂作为整数：

CorrectPower2(n) = int(sprintf("%.15e",n)[19:])