处理连接表键的通用方法

Question

如果我有一个 tabkey 值，例如：, DATA(lv_tabkey) = '1000041508773180000013000'.，它是一个条目的所有表键的连接值，我知道对应表的名称。

我怎样才能在不拆分的情况下得到它的表项？tabkey 手动 因此必须写出每个关键字段的顺序和长度？

完整的例子。

" The first 3 chars always belong to the 'mandt' field 
" which can't be filtered in the SELECT, therefore 
" I ignore it and start with key2
DATA(lv_tabkey) = '1000041508773180000013000'.

"ToDo - how to make this generic? - START
DATA(lv_key2) = lv_tabkey+3(12).
DATA(lv_key3) = lv_tabkey+15(3).
DATA(lv_key4) = lv_tabkey+18(4).
DATA(lv_key5) = lv_tabkey+22(3).
DATA(lv_where) =      'key2 = ' && lv_key2 && 
                 ' AND key3 = ' && lv_key3 && 
                 ' AND key4 = ' && lv_key4 && 
                 ' AND key5 = ' && lv_key5.
"ToDo - how to make this generic? - END

SELECT *
  FROM table_x
  INTO TABLE DATA(lt_results)
  WHERE (lv_where).

我想我必须以某种方式遍历表中的字段，找出键和它们的长度 - 但我不知道如何做。

Answer 1

你要找的语句是

ASSIGN tabkey TO < structure> CASTING TYPE HANDLE r_type_struct.

知道了(表键)结构的类型句柄，你就可以用通用的方式将其填入值，并使用该结构查询表。这里是如何操作的。

DATA: handle      TYPE REF TO data,
      lref_struct TYPE REF TO cl_abap_structdescr.

FIELD-SYMBOLS: <key_fld> TYPE abap_componentdescr.

SELECT * UP TO 5000 ROWS
  FROM cdpos
  INTO TABLE @DATA(t_cdpos)
  WHERE tabname NOT LIKE '/%'.

LOOP AT t_cdpos ASSIGNING FIELD-SYMBOL(<fs_cdpos>).
  lref_struct ?= cl_abap_structdescr=>describe_by_name( <fs_cdpos>-tabname ).

* get key fields
  DATA(key_fields) = VALUE ddfields( FOR line IN lref_struct->get_ddic_field_list( ) WHERE ( keyflag NE space ) ( line ) ).

* filling key field components
  DATA(key_table) = VALUE abap_component_tab( FOR ls_key IN key_fields
                                              ( name = ls_key-fieldname
                                                type = CAST #( cl_abap_datadescr=>describe_by_name( ls_key-domname ) )
                                               )
                                            ).
* create key fields type handle
  TRY.
      DATA(r_type_struct) = cl_abap_structdescr=>create( key_table ).
    CATCH cx_sy_struct_creation .
  ENDTRY.

* create key type
  CHECK r_type_struct IS NOT INITIAL.
  CREATE DATA handle TYPE HANDLE r_type_struct.
  ASSIGN handle->* TO FIELD-SYMBOL(<structure>).

* assigning final key structure
  ASSIGN <fs_cdpos>-tabkey TO <structure> CASTING TYPE HANDLE r_type_struct.

* filling values
  LOOP AT key_table ASSIGNING <key_fld>.
    ASSIGN COMPONENT <key_fld>-name OF STRUCTURE <structure> TO FIELD-SYMBOL(<val>).
    CHECK sy-subrc = 0.
    <key_fld>-suffix = <val>.
  ENDLOOP.

  DATA(where_cond) = REDUCE string( INIT where = ` ` FOR <field> IN key_table WHERE ( name <> 'MANDT' ) NEXT where = where && <field>-name && ` = '` && <field>-suffix && `' AND ` ).
  where_cond = substring( val = where_cond off = 0 len = strlen( where_cond ) - 4 ).

  IF <fs_cdpos>-tabname = 'BNKA'.
    SELECT *
    INTO TABLE @DATA(lt_bnka)
    FROM bnka
    WHERE (where_cond).
  ENDIF.

ENDLOOP.

这里我在表上建立了一个样本 CDPOS 含有表名和额外的字段中的连贯键值。tabkey换句话说，正是你想使用的东西。

在一个循环中，它检测表的类型，建立键并以一种通用的方式进行SQL查询。这里我使用了表 BNKA 为简单起见，但SQL SELECT也可以通过字段符号生成。另外，我还做了一个小技巧，将值填入到包含结构组件的同一个tab中，在 SUFFIX 字段。

P.S.在将where条件传递到查询中之前，请进行适当的数据类型验证，以避免出现以下错误 SAPSQL_DATA_LOSS因为新的语法会进行严格的检查。

Answer 2

你的用例让我想起了我是如何处理更改文档键的。（CDHDRCDPOS）。希望对你有所帮助

DATA:
  lv_tabkey  TYPE char50,
  ls_table   TYPE table_x.
FIELD-SYMBOLS:
  <ls_src_x> TYPE x,
  <ls_tgt_x> TYPE x.

"Add Client info the Table key if your table is Client dependent. 
CONCATENATE sy-mandt lv_tabkey INTO lv_tabkey.

ASSIGN lv_tab_key TO <ls_src_x> CASTING.
ASSIGN ls_table TO <ls_tgt_x> CASTING.
<ls_tgt_x> = <ls_src_x>.

"Now ls_table has the key info filled including MANDT if you have the MANDT in table key. 

SELECT *
  FROM table_x
    INTO TABLE DATA(lt_results)
    WHERE key2 = ls_table-key2 AND key3 = ls_table-key3
          AND key4 = ls_table-key4 AND key5 = ls_table_key5.