为什么我在Unity RayMarching着色器中出现for循环错误？

Question

这是我的第一个着色器，因此可能是一些愚蠢的小错误。我正在关注YouTube上的一个教程：https://www.youtube.com/watch?v=S8AWd66hoCo&t=83s&pbjreload=10

我受制于距离函数（对于球体），如果没有for循环出现一些奇怪的错误，就无法使其正常工作。在此之前，一切都运转良好。我重写了for循环，但是一遍又一遍地得到这个错误。

谢谢你！

（团结2019.2.19f1）

错误：

+Shader error in 'Unlit/RayMarchOne': syntax error: unexpected token ')' at line 58 (on d3d11)
+Shader error in 'Unlit/RayMarchOne': syntax error: unexpected token '=' at line 58 (on d3d11)
+Shader error in 'Unlit/RayMarchOne': 'GetDist': no matching 1 parameter function at line 60 (on d3d11)
+Shader error in 'Unlit/RayMarchOne': undeclared identifier 'p' at line 60 (on d3d11)

CODE：

Shader "Unlit/RayMarchOne"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            #define MAX_STEPS = 100
            #define MIN_DIST = .001
            #define MAX_DIST = 100.

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                return o;
            }

            float GetDist(float3 p)
            {
                float d = length(p) - .5;
                return d;
            }

            float RayMarch(float3 ro, float3 rd)
            {
                float dO = 0;
                float dS;
                for (int i = 0; i < MAX_STEPS; i++) {
                    float3 p = ro + dO * rd;
                    dS = GetDist(p);
                    dO += dS;
                    if (dS<MIN_DIST || dO>MAX_DIST) break;
                }

                return dO;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                float2 uv = i.uv-.5;
                float3 ro = float3(0,0,-3);
                float3 rd = normalize(float3(uv.x, uv.y, 1));

                float d = RayMarch(ro, rd);
                fixed4 col = 0;

                if (d < maxDist)
                {
                    col.r = 1;
                }
                return col;
            }
            ENDCG
        }
    }
}

Answer 1

从定义中删除=符号。

#define MAX_STEPS = 100
#define MIN_DIST = .001
#define MAX_DIST = 100.

应该是

#define MAX_STEPS 100
#define MIN_DIST .001
#define MAX_DIST 100.

还有一个maxDist而不是MAX_DIST，它会进行编译。

（有时我的定义中也有=。:-)）