如何使用OpenGL在Android智能手机上渲染玻璃/冰材料

Question

没有光线追踪的在Android设备上渲染玻璃/冰材料的最佳方法是什么？

我看过aplha +混合，但是即使在适当的光照下，结果看起来也只是“可塑性”。

我们能做得更好吗？

Answer 1

您需要适当的反射和折射才能绘制透明的透明材料。

您基本上需要环境纹理作为反射/折射的来源。我建议不使用透明材质渲染场景以制作环境源纹理。通常建议使用多维数据集映射。

访问此处，了解如何实现反射和折射。

• http://en.wikibooks.org/wiki/GLSL_Programming/Unity/Reflecting_Surfaces
• http://en.wikibooks.org/wiki/GLSL_Programming/Unity/Curved_Glass

Answer 2

要在Android（OpenGL ES 3.0）中创建简单的玻璃效果，可以使用：折射+光泽+透明度。

顶点着色器：

#version 300 es
precision lowp float;
uniform mat4 u_mvpMatrix;
uniform mat4 u_mvMatrix;

in vec4 a_position; 
in vec3 a_normal;

out vec3 v_normal;
out lowp float SpecularIntensity;

out vec3 v_eyeDirectModel;

float getSpecularIntensity(vec4 position, vec3 a_normal, vec3 eyeDirectModel) {
    float shininess = 30.0;
    vec3 lightPosition = vec3(-20.0, 0.0, 0.0);
    // We ignore that N dot L could be negative (light coming from behind the surface)
    mediump vec3 LightDirModel = normalize(lightPosition - position.xyz);
    mediump vec3 halfVector = normalize(LightDirModel + eyeDirectModel);
    lowp float NdotH = max(dot(a_normal, halfVector), 0.0);
    return pow(NdotH, shininess);
}

void main() {
    v_normal = a_normal;
    vec4 eyePositionModel = u_mvMatrix * a_position;
    // Eye direction in model space
    vec3 eyeDirectModel = normalize(- eyePositionModel.xyz);
    // specular lighting
    SpecularIntensity = getSpecularIntensity(a_position, a_normal, eyeDirectModel);
    v_eyeDirectModel = eyeDirectModel;
    gl_Position = u_mvpMatrix * a_position;
}

片段着色器：

#version 300 es
precision lowp float;
uniform mat4 u_mvpMatrix;

in vec3 v_normal;
in lowp float SpecularIntensity;
in vec3 v_eyeDirectModel;

out vec4 outColor; 
uniform samplerCube s_texture; // skybox

const float eta = 0.65;
void main() {
    // Calculate refraction direction in model space
    vec3 refractDirect = refract(v_eyeDirectModel, normalize(v_normal), eta);
    // Project refraction
    refractDirect = (u_mvpMatrix * vec4(refractDirect, 0.0)).xyw;
    // Map refraction direction to 2d coordinates
    vec2 refractCoord = 0.5 * (refractDirect.xy / refractDirect.z) + 0.5;

    vec4 glassColor = texture(s_texture, vec3(refractCoord, 1.0));
    outColor = glassColor + SpecularIntensity;
    outColor.a = 0.8; // transparent
}

结果：

该代码部分取自PVRShamanGUI。